Version bump (bug #472784, thanks to Henrik Stokseth and Rafał Mużyło).

(Portage version: 2.2.0_alpha180/cvs/Linux x86_64, signed Manifest commit with key CF0ADD61)

2 files changed, 65 insertions, 1 deletions

diff --git a/app-cdr/cdemu/ChangeLog b/app-cdr/cdemu/ChangeLog
index e8b5d415a59e..3b1919d6181c 100644
--- a/app-cdr/cdemu/ChangeLog
+++ b/app-cdr/cdemu/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for app-cdr/cdemu
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-cdr/cdemu/ChangeLog,v 1.37 2013/01/28 00:22:41 tetromino Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-cdr/cdemu/ChangeLog,v 1.38 2013/06/17 04:19:18 tetromino Exp $
+
+*cdemu-2.1.0 (17 Jun 2013)
+
+  17 Jun 2013; Alexandre Rostovtsev <tetromino@gentoo.org> +cdemu-2.1.0.ebuild:
+  Version bump (bug #472784, thanks to Henrik Stokseth and Rafał Mużyło).
 
 *cdemu-2.0.0 (28 Jan 2013)
 
diff --git a/app-cdr/cdemu/cdemu-2.1.0.ebuild b/app-cdr/cdemu/cdemu-2.1.0.ebuild
new file mode 100644
index 000000000000..438b827b2bef
--- /dev/null
+++ b/app-cdr/cdemu/cdemu-2.1.0.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-cdr/cdemu/cdemu-2.1.0.ebuild,v 1.1 2013/06/17 04:19:18 tetromino Exp $
+
+EAPI="5"
+
+CMAKE_MIN_VERSION="2.8.5"
+PYTHON_COMPAT=( python2_6 python2_7 )
+PLOCALES="de fr no pl sl sv"
+
+inherit cmake-utils eutils fdo-mime l10n python-single-r1
+
+DESCRIPTION="Command-line tool for controlling cdemu-daemon"
+HOMEPAGE="http://cdemu.org"
+SRC_URI="mirror://sourceforge/cdemu/cdemu-client-${PV}.tar.bz2"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~hppa ~x86"
+IUSE="+cdemu-daemon"
+
+RDEPEND="${PYTHON_DEPS}
+	dev-python/dbus-python[${PYTHON_USEDEP}]
+	cdemu-daemon? ( app-cdr/cdemu-daemon:0/5 )"
+DEPEND="${RDEPEND}
+	dev-util/desktop-file-utils
+	>=dev-util/intltool-0.21
+	>=sys-devel/gettext-0.18"
+
+S=${WORKDIR}/cdemu-client-${PV}
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	python_fix_shebang src/cdemu
+	epatch "${FILESDIR}/${PN}-2.0.0-bash-completion-dir.patch"
+	# build system doesn't respect LINGUAS :/
+	l10n_find_plocales_changes po "" ".po"
+	rm_po() {
+		rm po/$1.po || die
+	}
+	l10n_for_each_disabled_locale_do rm_po
+}
+
+src_configure() {
+	DOCS="AUTHORS README"
+	local mycmakeargs=( -DPOST_INSTALL_HOOKS=OFF )
+	cmake-utils_src_configure
+}
+
+pkg_postinst() {
+	fdo-mime_desktop_database_update
+}
+
+pkg_postrm() {
+	fdo-mime_desktop_database_update
+}