New upstream version 0.9.4

(Portage version: 2.2.18/cvs/Linux x86_64, signed Manifest commit with key 0x250B7AFED6379D85!)

2 files changed, 91 insertions, 1 deletions

diff --git a/app-crypt/pinentry/ChangeLog b/app-crypt/pinentry/ChangeLog
index b2da310d440c..642bd9523ca6 100644
--- a/app-crypt/pinentry/ChangeLog
+++ b/app-crypt/pinentry/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for app-crypt/pinentry
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-crypt/pinentry/ChangeLog,v 1.173 2015/05/14 15:18:15 k_f Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-crypt/pinentry/ChangeLog,v 1.174 2015/06/07 11:02:09 k_f Exp $
+
+*pinentry-0.9.4 (07 Jun 2015)
+
+  07 Jun 2015; Kristian Fiskerstrand <k_f@gentoo.org> +pinentry-0.9.4.ebuild:
+  New upstream version 0.9.4
 
   14 May 2015; Kristian Fiskerstrand <k_f@gentoo.org> -pinentry-0.9.0-r1.ebuild,
   -pinentry-0.9.0-r2.ebuild:
diff --git a/app-crypt/pinentry/pinentry-0.9.4.ebuild b/app-crypt/pinentry/pinentry-0.9.4.ebuild
new file mode 100644
index 000000000000..de849bfbbf2d
--- /dev/null
+++ b/app-crypt/pinentry/pinentry-0.9.4.ebuild
@@ -0,0 +1,85 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-crypt/pinentry/pinentry-0.9.4.ebuild,v 1.1 2015/06/07 11:02:09 k_f Exp $
+
+EAPI=5
+
+inherit qmake-utils autotools multilib eutils flag-o-matic toolchain-funcs
+
+DESCRIPTION="Collection of simple PIN or passphrase entry dialogs which utilize the Assuan protocol"
+HOMEPAGE="http://gnupg.org/aegypten2/index.html"
+SRC_URI="mirror://gnupg/${PN}/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~amd64-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~x86-interix ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="clipboard gtk ncurses qt4 caps gnome-keyring static"
+
+RDEPEND="
+	app-eselect/eselect-pinentry
+	caps? ( sys-libs/libcap )
+	gtk? ( x11-libs/gtk+:2 )
+	ncurses? ( sys-libs/ncurses )
+	qt4? ( >=dev-qt/qtgui-4.4.1:4 )
+	static? ( >=sys-libs/ncurses-5.7-r5[static-libs,-gpm] )
+"
+DEPEND="${RDEPEND}
+	sys-devel/gettext
+	gtk? ( virtual/pkgconfig )
+	qt4? ( virtual/pkgconfig )
+	gnome-keyring? ( app-crypt/libsecret )
+"
+REQUIRED_USE="
+	|| ( ncurses gtk qt4 )
+	gtk? ( !static )
+	qt4? ( !static )
+	static? ( ncurses )
+"
+
+DOCS=( AUTHORS ChangeLog NEWS README THANKS TODO )
+
+src_prepare() {
+	epatch "${FILESDIR}/${PN}-0.8.2-ncurses.patch"
+}
+
+src_configure() {
+	use static && append-ldflags -static
+	[[ "$(gcc-major-version)" -ge 5 ]] && append-cxxflags -std=gnu++11
+
+	# Issues finding qt on multilib systems
+	export QTLIB="${QTDIR}/$(get_libdir)"
+
+	econf \
+		--enable-pinentry-tty \
+		$(use_enable gtk pinentry-gtk2) \
+		$(use_enable ncurses pinentry-curses) \
+		$(use_enable ncurses fallback-curses) \
+		$(use_enable qt4 pinentry-qt4) \
+		$(use qt4 && use_enable clipboard pinentry-qt4-clipboard) \
+		$(use_with caps libcap) \
+		$(use_enable gnome-keyring libsecret) \
+		$(use_enable gnome-keyring pinentry-gnome3) \
+		MOC="$(qt4_get_bindir)"/moc
+}
+
+src_install() {
+	default
+	rm -f "${ED}"/usr/bin/pinentry || die
+}
+
+pkg_postinst() {
+	if ! has_version 'app-crypt/pinentry' || has_version '<app-crypt/pinentry-0.7.3'; then
+		elog "We no longer install pinentry-curses and pinentry-qt SUID root by default."
+		elog "Linux kernels >=2.6.9 support memory locking for unprivileged processes."
+		elog "The soft resource limit for memory locking specifies the limit an"
+		elog "unprivileged process may lock into memory. You can also use POSIX"
+		elog "capabilities to allow pinentry to lock memory. To do so activate the caps"
+		elog "USE flag and add the CAP_IPC_LOCK capability to the permitted set of"
+		elog "your users."
+	fi
+	eselect pinentry update ifunset
+}
+
+pkg_postrm() {
+	eselect pinentry update ifunset
+}