Fix tcl/tk slotting; bump EAPI=5

(Portage version: 2.2.18/cvs/Linux x86_64, signed Manifest commit with key B9D4F231BD1558AB!)

3 files changed, 78 insertions, 7 deletions

diff --git a/app-office/ical/ChangeLog b/app-office/ical/ChangeLog
index 73e4e7e73520..85e157b0eb09 100644
--- a/app-office/ical/ChangeLog
+++ b/app-office/ical/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for app-office/ical
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-office/ical/ChangeLog,v 1.36 2013/03/30 15:08:04 ulm Exp $
+# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/app-office/ical/ChangeLog,v 1.37 2015/03/20 07:12:52 jlec Exp $
+
+*ical-3.0-r2 (20 Mar 2015)
+
+  20 Mar 2015; Justin Lecher <jlec@gentoo.org> +ical-3.0-r2.ebuild,
+  ical-3.0-r1.ebuild:
+  Fix tcl/tk slotting; bump EAPI=5
 
   30 Mar 2013; Ulrich Müller <ulm@gentoo.org> ical-3.0-r1.ebuild:
   Fix LICENSE, see README and COPYRIGHT files.
diff --git a/app-office/ical/ical-3.0-r1.ebuild b/app-office/ical/ical-3.0-r1.ebuild
index 9af3187bc962..6a7c8a9c6ebf 100644
--- a/app-office/ical/ical-3.0-r1.ebuild
+++ b/app-office/ical/ical-3.0-r1.ebuild
@@ -1,8 +1,9 @@
-# Copyright 1999-2013 Gentoo Foundation
+# Copyright 1999-2015 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-office/ical/ical-3.0-r1.ebuild,v 1.7 2013/03/30 15:08:04 ulm Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-office/ical/ical-3.0-r1.ebuild,v 1.8 2015/03/20 07:12:52 jlec Exp $
 
 EAPI=3
+
 inherit autotools eutils multilib virtualx
 
 DESCRIPTION="Tk-based Calendar program"
@@ -14,8 +15,10 @@ SLOT="0"
 KEYWORDS="amd64 ppc x86"
 IUSE=""
 
-RDEPEND="dev-lang/tcl
-	dev-lang/tk"
+RDEPEND="
+	dev-lang/tcl:0
+	dev-lang/tk:0
+	"
 DEPEND="${RDEPEND}"
 
 src_prepare() {
@@ -54,5 +57,5 @@ src_install() {
 	dodoc ANNOUNCE *README RWMJ-release-notes.txt TODO
 	dohtml {.,doc}/*.html
 
-	rm -f "${D}"/usr/$(get_libdir)/ical/v3.0/contrib/README
+	rm -f "${D}"/usr/$(get_libdir)/ical/v3.0/contrib/README || die
 }
diff --git a/app-office/ical/ical-3.0-r2.ebuild b/app-office/ical/ical-3.0-r2.ebuild
new file mode 100644
index 000000000000..18750e6392ab
--- /dev/null
+++ b/app-office/ical/ical-3.0-r2.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-office/ical/ical-3.0-r2.ebuild,v 1.1 2015/03/20 07:12:52 jlec Exp $
+
+EAPI=5
+
+inherit autotools eutils multilib virtualx
+
+DESCRIPTION="Tk-based Calendar program"
+HOMEPAGE="http://launchpad.net/ical-tcl"
+SRC_URI="http://launchpad.net/ical-tcl/3.x/${PV}/+download/${P}.tar.gz"
+
+LICENSE="HPND"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE=""
+
+RDEPEND="
+	dev-lang/tcl:0
+	dev-lang/tk:0
+	"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+	epatch \
+		"${FILESDIR}"/${P}-gcc44.patch \
+		"${FILESDIR}"/${P}-newtcl.patch \
+		"${FILESDIR}"/${P}-makefile.patch
+
+	sed -i \
+		-e 's:8.4 8.3:8.6 8.5 8.4 8.3:g' \
+		-e 's:sys/utsname.h limits.h::' \
+		configure.in || die
+
+	sed -i \
+		-e 's:mkdir:mkdir -p:' \
+		-e "/LIBDIR =/s:lib:$(get_libdir):" \
+		-e '/MANDIR =/s:man:share/man:' \
+		Makefile.in || die
+
+	mv configure.{in,ac} || die
+
+	eautoconf
+}
+
+src_compile() {
+	emake OPTF="${CFLAGS}" CXXFLAGS="${CXXFLAGS}"
+}
+
+src_test() {
+	[[ ${EUID} != 0 ]] && Xemake check
+}
+
+src_install() {
+	emake prefix="${D}/usr" install
+
+	DOCS=( ANNOUNCE *README RWMJ-release-notes.txt TODO )
+	HTML_DOCS=( {.,doc}/*.html )
+	einstalldocs
+
+	rm -f "${D}"/usr/$(get_libdir)/ical/v3.0/contrib/README || die
+}