Version bump

(Portage version: 2.2.0/cvs/Linux x86_64, signed Manifest commit with key 62EEF090)

4 files changed, 97 insertions, 5 deletions

diff --git a/app-text/llpp/ChangeLog b/app-text/llpp/ChangeLog
index 073138ebe130..53a88be056e5 100644
--- a/app-text/llpp/ChangeLog
+++ b/app-text/llpp/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for app-text/llpp
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-text/llpp/ChangeLog,v 1.49 2013/08/28 09:56:16 xmw Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-text/llpp/ChangeLog,v 1.50 2013/08/29 05:54:07 xmw Exp $
+
+*llpp-16 (29 Aug 2013)
+
+  29 Aug 2013; Michael Weber <xmw@gentoo.org> +llpp-16.ebuild, llpp-15.ebuild,
+  llpp-9999.ebuild:
+  Version bump
 
   28 Aug 2013; Michael Weber <xmw@gentoo.org> llpp-15.ebuild:
   Adjust depend to =app-text/mupdf-1.2*
diff --git a/app-text/llpp/llpp-15.ebuild b/app-text/llpp/llpp-15.ebuild
index e2eb45b1918d..a51458dc49b9 100644
--- a/app-text/llpp/llpp-15.ebuild
+++ b/app-text/llpp/llpp-15.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-text/llpp/llpp-15.ebuild,v 1.9 2013/08/28 09:56:16 xmw Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-text/llpp/llpp-15.ebuild,v 1.10 2013/08/29 05:54:07 xmw Exp $
 
 EAPI=5
 
@@ -15,7 +15,7 @@ SLOT="0"
 KEYWORDS="~amd64 ~ppc ~x86"
 IUSE="+ocamlopt static"
 
-LIB_DEPEND="=app-text/mupdf-1.2*:=[static-libs]
+LIB_DEPEND="~app-text/mupdf-1.2:=[static-libs]
 	media-libs/openjpeg:0[static-libs]
 	media-libs/freetype:2[static-libs]
 	media-libs/jbig2dec[static-libs]
diff --git a/app-text/llpp/llpp-16.ebuild b/app-text/llpp/llpp-16.ebuild
new file mode 100644
index 000000000000..6bbda5617e2b
--- /dev/null
+++ b/app-text/llpp/llpp-16.ebuild
@@ -0,0 +1,86 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-text/llpp/llpp-16.ebuild,v 1.1 2013/08/29 05:54:07 xmw Exp $
+
+EAPI=5
+
+inherit eutils multilib toolchain-funcs vcs-snapshot
+
+DESCRIPTION="a graphical PDF viewer which aims to superficially resemble less(1)"
+HOMEPAGE="http://repo.or.cz/w/llpp.git"
+SRC_URI="http://repo.or.cz/w/llpp.git/snapshot/8855b8a50acf02257773469578c5ddaaf12eff9f.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="+ocamlopt static"
+
+LIB_DEPEND="~app-text/mupdf-1.3_pre20130704:=[static-libs]
+	media-libs/openjpeg:2[static-libs]
+	media-libs/freetype:2[static-libs]
+	media-libs/jbig2dec[static-libs]
+	sys-libs/zlib[static-libs]
+	virtual/jpeg:0[static-libs]
+	x11-libs/libX11[static-libs]"
+RDEPEND="x11-misc/xsel
+	!static? ( ${LIB_DEPEND//\[static-libs]} )"
+DEPEND="${RDEPEND}
+	static? ( ${LIB_DEPEND}
+		app-arch/bzip2[static-libs]
+		media-libs/libXcm[static-libs]
+		x11-libs/libXau[static-libs]
+		x11-libs/libXdmcp[static-libs]
+		x11-libs/libXmu[static-libs] )
+	dev-lang/ocaml[ocamlopt?]
+	dev-ml/lablgl[glut,ocamlopt?]"
+
+RESTRICT="!ocamlopt? ( strip )"
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-11-WM_CLASS.patch
+}
+
+src_compile() {
+	local ocaml=$(usex ocamlopt ocamlopt.opt ocamlc.opt)
+	local cmo=$(usex ocamlopt cmx cmo)
+	local cma=$(usex ocamlopt cmxa cma)
+	local ccopt="$(freetype-config --cflags ) -O -include ft2build.h -D_GNU_SOURCE"
+	if use static ; then
+		local cclib=""
+		local slib=""
+		local spath=( ${EROOT}usr/$(get_libdir) $($(tc-getPKG_CONFIG) --libs-only-L --static mupdf x11 | sed 's:-L::g') )
+		for slib in $($(tc-getPKG_CONFIG) --libs-only-l --static mupdf x11) -ljpeg -ljbig2dec ; do
+			case ${slib} in
+				-lm|-ldl|-lpthread)
+					einfo "${slib}: shared"
+					cclib+="${slib} " ;;
+				*)
+					local ccnew=$(find ${spath} -name "lib${slib/-l}.a")
+					einfo "${slib}: use ${ccnew}"
+					cclib+="${ccnew} " ;;
+			esac
+		done
+	else
+		local cclib="$($(tc-getPKG_CONFIG) --libs mupdf x11) -lpthread"
+	fi
+
+	verbose() { echo "$@" >&2 ; "$@" || die ; }
+	verbose ocaml str.cma keystoml.ml < KEYS > help.ml
+	verbose printf 'let version ="%s";;\n' ${PV} >> help.ml
+	verbose ${ocaml} -c -o link.o -ccopt "${ccopt}" link.c
+	verbose ${ocaml} -c -o help.${cmo} help.ml
+	verbose ${ocaml} -c -o utils.${cmo} utils.ml
+	verbose ${ocaml} -c -o wsi.cmi wsi.mli
+	verbose ${ocaml} -c -o wsi.${cmo} wsi.ml
+	verbose ${ocaml} -c -o parser.${cmo} parser.ml
+	verbose ${ocaml} -c -o main.${cmo} -I +lablGL main.ml
+	verbose ${ocaml} $(usex ocamlopt "" -custom) -o llpp -I +lablGL\
+		str.${cma} unix.${cma} lablgl.${cma} link.o \
+	    -cclib "${cclib}" \
+		help.${cmo} utils.${cmo} parser.${cmo} wsi.${cmo} main.${cmo}
+}
+
+src_install() {
+	dobin ${PN}
+	dodoc KEYS README Thanks fixme
+}
diff --git a/app-text/llpp/llpp-9999.ebuild b/app-text/llpp/llpp-9999.ebuild
index e21743431a29..8fb12234c9d6 100644
--- a/app-text/llpp/llpp-9999.ebuild
+++ b/app-text/llpp/llpp-9999.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-text/llpp/llpp-9999.ebuild,v 1.26 2013/07/13 23:16:59 xmw Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-text/llpp/llpp-9999.ebuild,v 1.27 2013/08/29 05:54:07 xmw Exp $
 
 EAPI=5
 
@@ -15,7 +15,7 @@ SLOT="0"
 KEYWORDS=""
 IUSE="+ocamlopt static"
 
-LIB_DEPEND=">=app-text/mupdf-9999:=[static-libs]
+LIB_DEPEND=">=app-text/mupdf-1.3:=[static-libs]
 	media-libs/openjpeg:2[static-libs]
 	media-libs/freetype:2[static-libs]
 	media-libs/jbig2dec[static-libs]