Version bump.

(Portage version: 2.2_rc11/cvs/Linux 2.6.25-gentoo-r7 x86_64)

1 files changed, 64 insertions, 0 deletions

diff --git a/dev-java/zemberek/zemberek-2.1.1.ebuild b/dev-java/zemberek/zemberek-2.1.1.ebuild
new file mode 100644
index 000000000000..5f726df72b5b
--- /dev/null
+++ b/dev-java/zemberek/zemberek-2.1.1.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-java/zemberek/zemberek-2.1.1.ebuild,v 1.1 2008/10/01 19:17:42 serkan Exp $
+
+EAPI=1
+JAVA_PKG_IUSE="source doc test"
+
+inherit eutils java-pkg-2 java-ant-2
+
+DESCRIPTION="Zemberek NLP library"
+HOMEPAGE="http://code.google.com/p/zemberek/"
+SRC_URI="http://${PN}.googlecode.com/files/${P}-nolibs-src.zip"
+
+LICENSE="MPL-1.1"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+LANGS="tr tk"
+
+S=${WORKDIR}/${P}-nolibs-src
+
+IUSE="linguas_tk +linguas_tr"
+
+RDEPEND=">=virtual/jre-1.5"
+
+DEPEND=">=virtual/jdk-1.5
+	test?
+	(
+		dev-java/junit:4
+		dev-java/ant-junit4
+	)
+	app-arch/unzip"
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}" || die
+	use test && java-pkg_jarfrom --build-only --into lib/gelistirme junit-4 junit.jar
+}
+
+src_compile() {
+	strip-linguas ${LANGS}
+	local anttargs
+	for jar in cekirdek demo ${LINGUAS}; do
+		anttargs="${anttargs} jar-${jar}"
+	done
+	eant ${anttargs} $(use_doc javadocs)
+}
+
+src_install() {
+	strip-linguas ${LANGS}
+	local sourcetrees=""
+	for jar in cekirdek demo ${LINGUAS}; do
+		java-pkg_newjar dagitim/jar/zemberek-${jar}-${PV}.jar zemberek2-${jar}.jar
+		sourcetrees="${sourcetrees} src/${jar}/net"
+	done
+	use source && java-pkg_dosrc ${sourcetrees}
+	use doc && java-pkg_dojavadoc build/java-docs/api
+	java-pkg_dolauncher zemberek-demo --main net.zemberek.demo.DemoMain
+	dodoc dokuman/lisanslar/* || die
+	dodoc surumler.txt || die
+}
+
+src_test() {
+	ANT_TASKS="ant-junit4" eant unit-test
+}