Version bump to avoid file collisions, bug #452234.

(Portage version: 2.1.11.50/cvs/Linux i686, signed Manifest commit with key 30427902)

2 files changed, 61 insertions, 1 deletions

diff --git a/dev-libs/jsoncpp/ChangeLog b/dev-libs/jsoncpp/ChangeLog
index 0648efaa2c1a..5085cf1aeaec 100644
--- a/dev-libs/jsoncpp/ChangeLog
+++ b/dev-libs/jsoncpp/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-libs/jsoncpp
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/jsoncpp/ChangeLog,v 1.5 2013/02/25 21:05:18 phajdan.jr Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/jsoncpp/ChangeLog,v 1.6 2013/02/28 20:04:34 phajdan.jr Exp $
+
+*jsoncpp-0.5.0-r1 (28 Feb 2013)
+
+  28 Feb 2013; Pawel Hajdan jr <phajdan.jr@gentoo.org>
+  +jsoncpp-0.5.0-r1.ebuild:
+  Version bump to avoid file collisions, bug #452234.
 
   25 Feb 2013; Pawel Hajdan jr <phajdan.jr@gentoo.org> jsoncpp-0.5.0.ebuild:
   Keyword ~arm
diff --git a/dev-libs/jsoncpp/jsoncpp-0.5.0-r1.ebuild b/dev-libs/jsoncpp/jsoncpp-0.5.0-r1.ebuild
new file mode 100644
index 000000000000..2b82fc1d5968
--- /dev/null
+++ b/dev-libs/jsoncpp/jsoncpp-0.5.0-r1.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/jsoncpp/jsoncpp-0.5.0-r1.ebuild,v 1.1 2013/02/28 20:04:34 phajdan.jr Exp $
+
+EAPI=5
+PYTHON_COMPAT=( python2_7 )
+
+inherit multilib toolchain-funcs python-any-r1
+
+MY_P="${PN}-src-${PV}"
+
+DESCRIPTION="C++ JSON reader and writer"
+HOMEPAGE="http://jsoncpp.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz"
+LICENSE="public-domain"
+
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="doc"
+
+DEPEND="
+	doc? (
+		app-doc/doxygen
+		${PYTHON_DEPS}
+	)"
+RDEPEND=""
+
+S="${WORKDIR}/${MY_P}"
+
+cxx_wrapper() {
+	set -- $(tc-getCXX) ${CXXFLAGS} ${LDFLAGS} "$@"
+	echo "$@"
+	"$@"
+}
+
+src_compile() {
+	soname=libjsoncpp.so.${PV}
+	cxx_wrapper src/lib_json/*.cpp -Iinclude -shared -fPIC \
+		-Wl,-soname,${soname} -o ${soname} || die
+}
+
+src_install() {
+	# Follow Debian, Ubuntu, Arch convention for headers location, bug #452234 .
+	insinto /usr/include/jsoncpp
+	doins -r include/json
+
+	dolib ${soname}
+	dosym ${soname} /usr/$(get_libdir)/libjsoncpp.so
+
+	if use doc; then
+		${EPYTHON} doxybuild.py --doxygen=/usr/bin/doxygen || die
+		dohtml dist/doxygen/jsoncpp*/*
+	fi
+}