Enable multilib support.

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key EFB4464E!)

3 files changed, 155 insertions, 15 deletions

diff --git a/dev-libs/libnl/ChangeLog b/dev-libs/libnl/ChangeLog
index f93c1750e87d..d891c258627a 100644
--- a/dev-libs/libnl/ChangeLog
+++ b/dev-libs/libnl/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-libs/libnl
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/libnl/ChangeLog,v 1.208 2014/05/03 21:00:23 floppym Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/libnl/ChangeLog,v 1.209 2014/05/25 11:29:04 mgorny Exp $
+
+*libnl-3.2.24-r1 (25 May 2014)
+
+  25 May 2014; Michał Górny <mgorny@gentoo.org> +libnl-3.2.24-r1.ebuild,
+  libnl-3.2.9999.ebuild:
+  Enable multilib support.
 
   03 May 2014; Mike Gilbert <floppym@gentoo.org> libnl-3.2.24.ebuild,
   libnl-3.2.9999.ebuild:
diff --git a/dev-libs/libnl/libnl-3.2.24-r1.ebuild b/dev-libs/libnl/libnl-3.2.24-r1.ebuild
new file mode 100644
index 000000000000..fcc0a184b925
--- /dev/null
+++ b/dev-libs/libnl/libnl-3.2.24-r1.ebuild
@@ -0,0 +1,102 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/libnl/libnl-3.2.24-r1.ebuild,v 1.1 2014/05/25 11:29:04 mgorny Exp $
+
+EAPI=5
+PYTHON_COMPAT=( python2_{6,7} python3_{2,3,4} )
+DISTUTILS_OPTIONAL=1
+inherit distutils-r1 eutils libtool multilib multilib-minimal
+
+NL_P=${P/_/-}
+
+DESCRIPTION="A collection of libraries providing APIs to netlink protocol based Linux kernel interfaces"
+HOMEPAGE="http://www.infradead.org/~tgr/libnl/"
+SRC_URI="
+	http://www.infradead.org/~tgr/${PN}/files/${NL_P}.tar.gz
+"
+LICENSE="LGPL-2.1 utils? ( GPL-2 )"
+SLOT="3"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-linux ~ia64-linux ~x86-linux"
+IUSE="static-libs python utils"
+
+RDEPEND="python? ( ${PYTHON_DEPS} )
+	abi_x86_32? (
+		!<=app-emulation/emul-linux-x86-baselibs-20140508-r5
+		!app-emulation/emul-linux-x86-baselibs[-abi_x86_32(-)]
+	)"
+DEPEND="${RDEPEND}
+	python? ( dev-lang/swig )
+	sys-devel/flex
+	sys-devel/bison
+"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+DOCS=( ChangeLog )
+
+S=${WORKDIR}/${NL_P}
+
+MULTILIB_WRAPPED_HEADERS=(
+	# we do not install CLI stuff for non-native
+	/usr/include/libnl3/netlink/cli/addr.h
+	/usr/include/libnl3/netlink/cli/class.h
+	/usr/include/libnl3/netlink/cli/cls.h
+	/usr/include/libnl3/netlink/cli/ct.h
+	/usr/include/libnl3/netlink/cli/exp.h
+	/usr/include/libnl3/netlink/cli/link.h
+	/usr/include/libnl3/netlink/cli/neigh.h
+	/usr/include/libnl3/netlink/cli/qdisc.h
+	/usr/include/libnl3/netlink/cli/route.h
+	/usr/include/libnl3/netlink/cli/rule.h
+	/usr/include/libnl3/netlink/cli/tc.h
+	/usr/include/libnl3/netlink/cli/utils.h
+)
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-1.1-vlan-header.patch
+	epatch "${FILESDIR}"/${PN}-3.2.20-rtnl_tc_get_ops.patch
+	epatch "${FILESDIR}"/${PN}-3.2.20-cache-api.patch
+
+	elibtoolize
+
+	if use python; then
+		cd "${S}"/python || die
+		distutils-r1_src_prepare
+	fi
+
+	# out-of-source build broken
+	# https://github.com/thom311/libnl/pull/58
+	multilib_copy_sources
+}
+
+multilib_src_configure() {
+	econf \
+		--disable-silent-rules \
+		$(use_enable static-libs static) \
+		$(multilib_native_use_enable utils cli)
+}
+
+multilib_src_compile() {
+	default
+
+	if multilib_is_native_abi && use python; then
+		cd python || die
+		distutils-r1_src_compile
+	fi
+}
+
+multilib_src_install() {
+	emake DESTDIR="${D}" install
+
+	if multilib_is_native_abi && use python; then
+		# Unset DOCS= since distutils-r1.eclass interferes
+		local DOCS=()
+		cd python || die
+		distutils-r1_src_install
+	fi
+}
+
+multilib_src_install_all() {
+	einstalldocs
+	prune_libtool_files --modules
+}
diff --git a/dev-libs/libnl/libnl-3.2.9999.ebuild b/dev-libs/libnl/libnl-3.2.9999.ebuild
index 234a0a75b12a..acfb781f56f1 100644
--- a/dev-libs/libnl/libnl-3.2.9999.ebuild
+++ b/dev-libs/libnl/libnl-3.2.9999.ebuild
@@ -1,11 +1,11 @@
 # Copyright 1999-2014 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/libnl/libnl-3.2.9999.ebuild,v 1.5 2014/05/03 21:00:23 floppym Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/libnl/libnl-3.2.9999.ebuild,v 1.6 2014/05/25 11:29:04 mgorny Exp $
 
 EAPI=5
 PYTHON_COMPAT=( python2_{6,7} python3_{2,3,4} )
 DISTUTILS_OPTIONAL=1
-inherit autotools distutils-r1 eutils git-r3 libtool multilib
+inherit autotools distutils-r1 eutils git-r3 libtool multilib multilib-minimal
 
 DESCRIPTION="A collection of libraries providing APIs to netlink protocol based Linux kernel interfaces"
 HOMEPAGE="http://www.infradead.org/~tgr/libnl/"
@@ -17,7 +17,11 @@ SLOT="3"
 KEYWORDS=""
 IUSE="static-libs python utils"
 
-RDEPEND="python? ( ${PYTHON_DEPS} )"
+RDEPEND="python? ( ${PYTHON_DEPS} )
+	abi_x86_32? (
+		!<=app-emulation/emul-linux-x86-baselibs-20140508-r5
+		!app-emulation/emul-linux-x86-baselibs[-abi_x86_32(-)]
+	)"
 DEPEND="${RDEPEND}
 	python? ( dev-lang/swig )
 	sys-devel/flex
@@ -28,39 +32,67 @@ REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
 
 DOCS=( ChangeLog )
 
+MULTILIB_WRAPPED_HEADERS=(
+	# we do not install CLI stuff for non-native
+	/usr/include/libnl3/netlink/cli/addr.h
+	/usr/include/libnl3/netlink/cli/class.h
+	/usr/include/libnl3/netlink/cli/cls.h
+	/usr/include/libnl3/netlink/cli/ct.h
+	/usr/include/libnl3/netlink/cli/exp.h
+	/usr/include/libnl3/netlink/cli/link.h
+	/usr/include/libnl3/netlink/cli/neigh.h
+	/usr/include/libnl3/netlink/cli/qdisc.h
+	/usr/include/libnl3/netlink/cli/route.h
+	/usr/include/libnl3/netlink/cli/rule.h
+	/usr/include/libnl3/netlink/cli/tc.h
+	/usr/include/libnl3/netlink/cli/utils.h
+)
+
 src_prepare() {
 	epatch "${FILESDIR}"/${PN}-1.1-vlan-header.patch
 	epatch "${FILESDIR}"/${PN}-3.2.20-rtnl_tc_get_ops.patch
 	epatch "${FILESDIR}"/${PN}-3.2.20-cache-api.patch
 
 	eautoreconf
+
+	if use python; then
+		cd "${S}"/python || die
+		distutils-r1_src_prepare
+	fi
+
+	# out-of-source build broken
+	# https://github.com/thom311/libnl/pull/58
+	multilib_copy_sources
 }
 
-src_configure() {
+multilib_src_configure() {
 	econf \
 		--disable-silent-rules \
 		$(use_enable static-libs static) \
-		$(use_enable utils cli)
+		$(multilib_native_use_enable utils cli)
 }
 
-src_compile() {
+multilib_src_compile() {
 	default
 
-	if use python; then
-		cd "${S}"/python || die
+	if multilib_is_native_abi && use python; then
+		cd python || die
 		distutils-r1_src_compile
 	fi
 }
 
-src_install() {
-	default
+multilib_src_install() {
+	emake DESTDIR="${D}" install
 
-	if use python; then
+	if multilib_is_native_abi && use python; then
 		# Unset DOCS= since distutils-r1.eclass interferes
-		DOCS=''
-		cd "${S}"/python || die
+		local DOCS=()
+		cd python || die
 		distutils-r1_src_install
 	fi
+}
 
-	prune_libtool_files $(usex static-libs --modules --all)
+multilib_src_install_all() {
+	einstalldocs
+	prune_libtool_files --modules
 }