Version bump.

(Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key 4868F14D)

2 files changed, 79 insertions, 2 deletions

diff --git a/dev-libs/libusb/ChangeLog b/dev-libs/libusb/ChangeLog
index 53f99523adf1..d7feb4001eb7 100644
--- a/dev-libs/libusb/ChangeLog
+++ b/dev-libs/libusb/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-libs/libusb
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/libusb/ChangeLog,v 1.151 2013/08/08 12:40:30 ssuominen Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/libusb/ChangeLog,v 1.152 2014/01/31 16:20:56 ssuominen Exp $
+
+*libusb-1.0.18 (31 Jan 2014)
+
+  31 Jan 2014; Samuli Suominen <ssuominen@gentoo.org> +libusb-1.0.18.ebuild:
+  Version bump.
 
   08 Aug 2013; Samuli Suominen <ssuominen@gentoo.org> libusb-1.0.9-r2.ebuild:
   Block revision of emul-linux-x86-baselibs that dropped the colliding files.
diff --git a/dev-libs/libusb/libusb-1.0.18.ebuild b/dev-libs/libusb/libusb-1.0.18.ebuild
new file mode 100644
index 000000000000..0f89abcea2b3
--- /dev/null
+++ b/dev-libs/libusb/libusb-1.0.18.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/libusb/libusb-1.0.18.ebuild,v 1.1 2014/01/31 16:20:56 ssuominen Exp $
+
+EAPI=5
+inherit eutils toolchain-funcs multilib-minimal
+
+DESCRIPTION="Userspace access to USB devices"
+HOMEPAGE="http://libusb.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"
+
+LICENSE="LGPL-2.1"
+SLOT="1"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 -x86-fbsd ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
+IUSE="debug doc examples static-libs test udev"
+
+RDEPEND="udev? ( >=virtual/udev-200[${MULTILIB_USEDEP}] )
+	!dev-libs/libusb:1
+	abi_x86_32? (
+		!<=app-emulation/emul-linux-x86-baselibs-20130224-r7
+		!app-emulation/emul-linux-x86-baselibs[-abi_x86_32(-)]
+	)"
+DEPEND="${RDEPEND}
+	doc? ( app-doc/doxygen )
+	!udev? ( virtual/os-headers )"
+
+multilib_src_configure() {
+	ECONF_SOURCE=${S} \
+	econf \
+		$(use_enable static-libs static) \
+		$(use_enable udev) \
+		$(use_enable debug debug-log) \
+		$(use_enable test tests-build)
+}
+
+multilib_src_compile() {
+	emake
+
+	if multilib_is_native_abi; then
+		use doc && emake -C doc docs
+	fi
+}
+
+multilib_src_test() {
+	emake check
+
+	# noinst_PROGRAMS from tests/Makefile.am
+	tests/stress || die
+}
+
+multilib_src_install() {
+	emake DESTDIR="${D}" install
+
+	if multilib_is_native_abi; then
+		gen_usr_ldscript -a usb-1.0
+
+		use doc && dohtml doc/html/*
+	fi
+}
+
+multilib_src_install_all() {
+	prune_libtool_files
+
+	dodoc AUTHORS ChangeLog NEWS PORTING README TODO
+
+	if use examples; then
+		insinto /usr/share/doc/${PF}/examples
+		doins examples/*.{c,h}
+		insinto /usr/share/doc/${PF}/examples/getopt
+		doins examples/getopt/*.{c,h}
+	fi
+}