Bump to new soprano-2.2

(Portage version: 2.2_rc19/cvs/Linux 2.6.28-gentoo x86_64)

2 files changed, 98 insertions, 2 deletions

diff --git a/dev-libs/soprano/ChangeLog b/dev-libs/soprano/ChangeLog
index 365338299103..04e655012cba 100644
--- a/dev-libs/soprano/ChangeLog
+++ b/dev-libs/soprano/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-libs/soprano
-# Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/soprano/ChangeLog,v 1.13 2008/12/03 17:32:08 scarabeus Exp $
+# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/soprano/ChangeLog,v 1.14 2009/01/27 14:52:29 alexxy Exp $
+
+*soprano-2.2 (27 Jan 2009)
+
+  27 Jan 2009; Alexey Shvetsov <alexxy@gentoo.org> +soprano-2.2.ebuild:
+  Bump to new soprano-2.2
 
 *soprano-2.1.1 (03 Dec 2008)
 
diff --git a/dev-libs/soprano/soprano-2.2.ebuild b/dev-libs/soprano/soprano-2.2.ebuild
new file mode 100644
index 000000000000..5588a8209041
--- /dev/null
+++ b/dev-libs/soprano/soprano-2.2.ebuild
@@ -0,0 +1,91 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/soprano/soprano-2.2.ebuild,v 1.1 2009/01/27 14:52:29 alexxy Exp $
+
+EAPI="2"
+
+JAVA_PKG_OPT_USE=sesame2
+inherit cmake-utils eutils flag-o-matic java-pkg-opt-2
+
+DESCRIPTION="Soprano is a library which provides a nice QT interface to RDF storage solutions."
+HOMEPAGE="http://sourceforge.net/projects/soprano"
+SRC_URI="mirror://sourceforge/soprano/soprano-${PV}.tar.bz2"
+
+LICENSE="LGPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+clucene debug doc elibc_FreeBSD redland +sesame2"
+
+COMMON_DEPEND="
+	>=media-libs/raptor-1.4.16
+	x11-libs/qt-core:4[debug=]
+	x11-libs/qt-dbus:4[debug=]
+	clucene? ( >=dev-cpp/clucene-0.9.19 )
+	redland? ( >=dev-libs/rasqal-0.9.15
+		>=dev-libs/redland-1.0.6 )
+	sesame2? ( >=virtual/jdk-1.6.0 )
+	!redland? (
+		!sesame2? (
+			>=virtual/jdk-1.6.0
+		)
+	)
+"
+DEPEND="${COMMON_DEPEND}
+	doc? ( app-doc/doxygen )"
+RDEPEND="${COMMON_DEPEND}"
+
+src_configure() {
+	# Fix automagic dependencies / linking
+	if ! use clucene; then
+		sed -e '/find_package(CLucene)/s/^/#DONOTFIND /' \
+			-i "${S}/CMakeLists.txt" || die "Sed for CLucene automagic dependency failed."
+	fi
+
+	if ! use doc; then
+		sed -e '/find_package(Doxygen)/s/^/#DONOTFIND /' \
+			-i "${S}/CMakeLists.txt" || die "Sed to disable api-docs failed."
+	fi
+
+	if ! use redland; then
+		sed -e '/find_package(Redland)/ s:^:#DONOTWANT :' \
+			-i "${S}"/CMakeLists.txt || die "Deactivating redland backend failed."
+	fi
+
+	if ! use sesame2; then
+		sed -e '/find_package(JNI)/ s:^:#DONOTWANT :' \
+			-i "${S}"/CMakeLists.txt || die "Deactivating sesame backend failed."
+	fi
+
+	if ! use redland && ! use sesame2; then
+		sed -e '/find_package(JNI)/ s:^#DONOTWANT ::' \
+			-i "${S}"/CMakeLists.txt || die "Deactivating sesame backend failed."
+	fi
+
+	sed -e '/add_subdirectory(test)/s/^/#DONOTCOMPILE /' \
+		-e '/enable_testing/s/^/#DONOTENABLE /' \
+		-i "${S}"/CMakeLists.txt || die "Disabling of ${PN} tests failed."
+	einfo "Disabled building of ${PN} tests."
+
+	# Fix for missing pthread.h linking
+	# NOTE: temporarely fix until a better cmake files patch will be provided.
+	use elibc_FreeBSD && append-ldflags "-lpthread"
+
+	cmake-utils_src_configure
+}
+
+src_test() {
+	sed -e 's/#NOTESTS//' \
+		-i "${S}"/CMakeLists.txt || die "Enabling tests failed."
+	cmake-utils_src_compile
+	ctest --extra-verbose || die "Tests failed."
+}
+
+pkg_postinst() {
+	if ! use redland && ! use sesame2; then
+		elog "As you haven't chosen any of the available backends:"
+		elog "redland, sesame2"
+		elog "sesame2 support was silently installed."
+		elog "If you prefer another backend, be sure to reinstall soprano"
+		elog "and to enable that backend use flag"
+	fi
+}