Bump to 0.10.0 from the gnome overlay. Has significant API differences with version 0.8.x. Dropped alpha, arm, ia64, ppc, ppc64, sparc keywords due to new liboauth dependency. Keywording bug will be filed once all of gnome-3.2 is in portage.

(Portage version: 2.2.0_alpha71/cvs/Linux x86_64)

2 files changed, 75 insertions, 1 deletions

diff --git a/dev-libs/libgdata/ChangeLog b/dev-libs/libgdata/ChangeLog
index d2b02a563526..b0fe33de1143 100644
--- a/dev-libs/libgdata/ChangeLog
+++ b/dev-libs/libgdata/ChangeLog
@@ -1,6 +1,14 @@
 # ChangeLog for dev-libs/libgdata
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/libgdata/ChangeLog,v 1.35 2011/10/05 16:55:17 xarthisius Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/libgdata/ChangeLog,v 1.36 2011/10/30 06:15:19 tetromino Exp $
+
+*libgdata-0.10.0 (30 Oct 2011)
+
+  30 Oct 2011; Alexandre Rostovtsev <tetromino@gentoo.org>
+  +libgdata-0.10.0.ebuild:
+  Bump to 0.10.0 from the gnome overlay. Required for gnome-3.2. Has
+  significant API differences with version 0.8.x. Dropped alpha, arm, ia64,
+  ppc, ppc64, sparc keywords due to new liboauth dependency.
 
   05 Oct 2011; Kacper Kowalik <xarthisius@gentoo.org> libgdata-0.8.1.ebuild:
   ppc/ppc64 stable wrt #369909
diff --git a/dev-libs/libgdata/libgdata-0.10.0.ebuild b/dev-libs/libgdata/libgdata-0.10.0.ebuild
new file mode 100644
index 000000000000..943c75b025cc
--- /dev/null
+++ b/dev-libs/libgdata/libgdata-0.10.0.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/libgdata/libgdata-0.10.0.ebuild,v 1.1 2011/10/30 06:15:19 tetromino Exp $
+
+EAPI="4"
+GCONF_DEBUG="yes"
+GNOME2_LA_PUNT="yes"
+
+inherit eutils gnome2
+
+DESCRIPTION="GLib-based library for accessing online service APIs using the GData protocol"
+HOMEPAGE="http://live.gnome.org/libgdata"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+IUSE="doc gnome +introspection static-libs"
+KEYWORDS="~amd64 ~x86"
+
+# gtk+ is needed for gdk
+# configure checks for gtk:3, but only uses it for demos which are not installed
+RDEPEND=">=dev-libs/glib-2.19:2
+	|| (
+		>=x11-libs/gdk-pixbuf-2.14:2
+		>=x11-libs/gtk+-2.14:2 )
+	>=dev-libs/libxml2-2:2
+	>=net-libs/libsoup-2.26.1:2.4[introspection?]
+	>=net-libs/liboauth-0.9.4
+	gnome? ( >=net-libs/libsoup-gnome-2.26.1:2.4[introspection?] )
+	introspection? ( >=dev-libs/gobject-introspection-0.9.7 )"
+DEPEND="${RDEPEND}
+	>=dev-util/intltool-0.40
+	doc? ( >=dev-util/gtk-doc-1.14 )"
+
+pkg_setup() {
+	DOCS="AUTHORS ChangeLog HACKING NEWS README"
+	G2CONF="${G2CONF}
+		$(use_enable static-libs static)
+		$(use_enable gnome)
+		$(use_enable introspection)"
+}
+
+src_prepare() {
+	gnome2_src_prepare
+
+	# Disable tests requiring network access, bug #307725
+	sed -e '/^TEST_PROGS = / s:\(.*\):TEST_PROGS = general perf\nOLD_\1:' \
+		-i gdata/tests/Makefile.in || die "network test disable failed"
+}
+
+src_test() {
+	unset ORBIT_SOCKETDIR
+	unset DBUS_SESSION_BUS_ADDRESS
+	dbus-launch emake check || die "emake check failed"
+}
+
+pkg_preinst() {
+	gnome2_pkg_preinst
+	preserve_old_lib /usr/$(get_libdir)/libgdata.so.7
+	preserve_old_lib /usr/$(get_libdir)/libgdata.so.11
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+	preserve_old_lib_notify /usr/$(get_libdir)/libgdata.so.7
+	preserve_old_lib_notify /usr/$(get_libdir)/libgdata.so.11
+}