revbump, migrate -> distutils-r1, add pypy support, doc build

(Portage version: 2.1.11.63/cvs/Linux x86_64, signed Manifest commit with key 0xB8072B0D)

2 files changed, 52 insertions, 1 deletions

diff --git a/dev-python/dulwich/ChangeLog b/dev-python/dulwich/ChangeLog
index 43053873e131..9443dff6dec0 100644
--- a/dev-python/dulwich/ChangeLog
+++ b/dev-python/dulwich/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/dulwich
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/dulwich/ChangeLog,v 1.62 2013/06/03 05:55:58 patrick Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/dulwich/ChangeLog,v 1.63 2013/06/04 06:46:39 idella4 Exp $
+
+*dulwich-0.8.7-r1 (04 Jun 2013)
+
+  04 Jun 2013; Ian Delaney <idella4@gentoo.org> +dulwich-0.8.7-r1.ebuild:
+  revbump, migrate -> distutils-r1, add pypy support, doc build
 
 *dulwich-0.9.0 (03 Jun 2013)
 
diff --git a/dev-python/dulwich/dulwich-0.8.7-r1.ebuild b/dev-python/dulwich/dulwich-0.8.7-r1.ebuild
new file mode 100644
index 000000000000..207a3ed6c828
--- /dev/null
+++ b/dev-python/dulwich/dulwich-0.8.7-r1.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/dulwich/dulwich-0.8.7-r1.ebuild,v 1.1 2013/06/04 06:46:39 idella4 Exp $
+
+EAPI=5
+PYTHON_COMPAT=( python{2_6,2_7} pypy2_0 )
+
+inherit distutils-r1
+
+DESCRIPTION="Dulwich is a pure-Python implementation of the Git file formats and protocols."
+HOMEPAGE="http://samba.org/~jelmer/dulwich/ http://pypi.python.org/pypi/dulwich"
+SRC_URI="http://samba.org/~jelmer/dulwich/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="doc test"
+
+DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
+	test? ( virtual/python-unittest2[${PYTHON_USEDEP}] )"
+RDEPEND=""
+
+python_prepare_all() {
+	sed -e "s/test_fetch_from_dulwich(/_&/" -i dulwich/tests/compat/server_utils.py
+	use test && DISTUTILS_IN_SOURCE_BUILD=1
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	pushd "${BUILD_DIR}"/../ &> /dev/null
+	local module
+	for module in _diff_tree _objects _pack; do
+		ln -fs "${BUILD_DIR}/lib/${PN}/${module}.so" "dulwich/${module}.so" \
+		|| die "Symlinking dulwich/${module}.so failed with $(python_get_implementation_and_version)"
+	done
+	nosetests || die
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/build/html/. )
+	distutils-r1_python_install_all
+}