Migrate to python-r1 (requested in bug #455378).

(Portage version: 2.2.0_alpha161/cvs/Linux x86_64, signed Manifest commit with key 42B9401D)

2 files changed, 136 insertions, 2 deletions

diff --git a/dev-python/pyside/ChangeLog b/dev-python/pyside/ChangeLog
index 66d4ff5f9cd3..4bf34fcd92d6 100644
--- a/dev-python/pyside/ChangeLog
+++ b/dev-python/pyside/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/pyside
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/pyside/ChangeLog,v 1.47 2012/12/26 06:29:30 pesa Exp $
+# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/pyside/ChangeLog,v 1.48 2013/02/04 14:02:36 mgorny Exp $
+
+*pyside-1.1.2-r1 (04 Feb 2013)
+
+  04 Feb 2013; Michał Górny <mgorny@gentoo.org> +pyside-1.1.2-r1.ebuild:
+  Migrate to python-r1 (requested in bug #455378).
 
   26 Dec 2012; Davide Pesavento <pesa@gentoo.org> pyside-1.1.2.ebuild:
   Cosmetics.
diff --git a/dev-python/pyside/pyside-1.1.2-r1.ebuild b/dev-python/pyside/pyside-1.1.2-r1.ebuild
new file mode 100644
index 000000000000..e84db0a8f8a8
--- /dev/null
+++ b/dev-python/pyside/pyside-1.1.2-r1.ebuild
@@ -0,0 +1,129 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/pyside/pyside-1.1.2-r1.ebuild,v 1.1 2013/02/04 14:02:36 mgorny Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_6,2_7,3_2} )
+
+inherit multilib cmake-utils python-r1 virtualx
+
+MY_P="${PN}-qt4.8+${PV}"
+
+DESCRIPTION="Python bindings for the Qt framework"
+HOMEPAGE="http://www.pyside.org/"
+SRC_URI="http://www.pyside.org/files/${MY_P}.tar.bz2"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86 ~amd64-linux ~x86-linux"
+IUSE="X declarative help kde multimedia opengl phonon script scripttools sql svg test webkit xmlpatterns"
+
+REQUIRED_USE="
+	declarative? ( X )
+	help? ( X )
+	multimedia? ( X )
+	opengl? ( X )
+	phonon? ( X )
+	scripttools? ( X script )
+	sql? ( X )
+	svg? ( X )
+	test? ( X )
+	webkit? ( X )
+"
+
+# Minimal supported version of Qt.
+QT_PV="4.7.0:4"
+
+RDEPEND="
+	>=dev-python/shiboken-${PV}[${PYTHON_USEDEP}]
+	>=x11-libs/qt-core-${QT_PV}
+	X? (
+		>=x11-libs/qt-gui-${QT_PV}[accessibility]
+		>=x11-libs/qt-test-${QT_PV}
+	)
+	declarative? ( >=x11-libs/qt-declarative-${QT_PV} )
+	help? ( >=x11-libs/qt-assistant-${QT_PV} )
+	multimedia? ( >=x11-libs/qt-multimedia-${QT_PV} )
+	opengl? ( >=x11-libs/qt-opengl-${QT_PV} )
+	phonon? (
+		kde? ( media-libs/phonon )
+		!kde? ( || ( >=x11-libs/qt-phonon-${QT_PV} media-libs/phonon ) )
+	)
+	script? ( >=x11-libs/qt-script-${QT_PV} )
+	sql? ( >=x11-libs/qt-sql-${QT_PV} )
+	svg? ( >=x11-libs/qt-svg-${QT_PV}[accessibility] )
+	webkit? ( >=x11-libs/qt-webkit-${QT_PV} )
+	xmlpatterns? ( >=x11-libs/qt-xmlpatterns-${QT_PV} )
+"
+DEPEND="${RDEPEND}
+	>=x11-libs/qt-gui-${QT_PV}
+"
+
+S=${WORKDIR}/${MY_P}
+
+DOCS=( ChangeLog )
+
+src_prepare() {
+	# Fix generated pkgconfig file to require the shiboken
+	# library suffixed with the correct python version.
+	sed -i -e '/^Requires:/ s/shiboken$/&@SHIBOKEN_PYTHON_SUFFIX@/' \
+		libpyside/pyside.pc.in || die
+
+	if use prefix; then
+		cp "${FILESDIR}"/rpath.cmake .
+		sed \
+			-i '1iinclude(rpath.cmake)' \
+			CMakeLists.txt || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_build test TESTS)
+		$(cmake-utils_use_disable X QtGui)
+		$(cmake-utils_use_disable X QtDesigner)
+		$(cmake-utils_use_disable X QtTest)
+		$(cmake-utils_use_disable X QtUiTools)
+		$(cmake-utils_use_disable declarative QtDeclarative)
+		$(cmake-utils_use_disable help QtHelp)
+		$(cmake-utils_use_disable multimedia QtMultimedia)
+		$(cmake-utils_use_disable opengl QtOpenGL)
+		$(cmake-utils_use_disable phonon)
+		$(cmake-utils_use_disable script QtScript)
+		$(cmake-utils_use_disable scripttools QtScriptTools)
+		$(cmake-utils_use_disable sql QtSql)
+		$(cmake-utils_use_disable svg QtSvg)
+		$(cmake-utils_use_disable webkit QtWebKit)
+		$(cmake-utils_use_disable xmlpatterns QtXmlPatterns)
+	)
+
+	configuration() {
+		local mycmakeargs=(
+			-DPYTHON_SUFFIX="-${EPYTHON}"
+			"${mycmakeargs[@]}"
+		)
+		cmake-utils_src_configure
+	}
+	python_foreach_impl configuration
+}
+
+src_compile() {
+	python_foreach_impl cmake-utils_src_make
+}
+
+src_test() {
+	local PYTHONDONTWRITEBYTECODE
+	export PYTHONDONTWRITEBYTECODE
+
+	local VIRTUALX_COMMAND="cmake-utils_src_test"
+	python_foreach_impl virtualmake
+}
+
+src_install() {
+	installation() {
+		cmake-utils_src_install
+		mv "${ED}"usr/$(get_libdir)/pkgconfig/${PN}{,-${EPYTHON}}.pc || die
+	}
+	python_foreach_impl installation
+}