bump; drop py2.6 support, drop IUSE doc, update deps

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 0xB8072B0D)

2 files changed, 68 insertions, 1 deletions

diff --git a/dev-python/python-ldap/ChangeLog b/dev-python/python-ldap/ChangeLog
index a9338a0a27b5..2286dcf5069f 100644
--- a/dev-python/python-ldap/ChangeLog
+++ b/dev-python/python-ldap/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-python/python-ldap
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/python-ldap/ChangeLog,v 1.131 2014/04/09 21:32:50 mgorny Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/python-ldap/ChangeLog,v 1.132 2014/05/14 08:31:55 idella4 Exp $
+
+*python-ldap-2.4.15 (14 May 2014)
+
+  14 May 2014; Ian Delaney <idella4@gentoo.org> +python-ldap-2.4.15.ebuild,
+  python-ldap-2.4.14.ebuild:
+  bump; drop py2.6 support, drop IUSE doc, update deps
 
   09 Apr 2014; Michał Górny <mgorny@gentoo.org> python-ldap-9999.ebuild:
   Remove python2.5 leftover.
diff --git a/dev-python/python-ldap/python-ldap-2.4.15.ebuild b/dev-python/python-ldap/python-ldap-2.4.15.ebuild
new file mode 100644
index 000000000000..512ba586540a
--- /dev/null
+++ b/dev-python/python-ldap/python-ldap-2.4.15.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/python-ldap/python-ldap-2.4.15.ebuild,v 1.1 2014/05/14 08:31:55 idella4 Exp $
+
+EAPI=5
+
+# pypy: bug #458558 (wrong linker options due to not respecting CC)
+PYTHON_COMPAT=( python2_7 )
+
+inherit distutils-r1 multilib
+
+DESCRIPTION="Various LDAP-related Python modules"
+HOMEPAGE="http://www.python-ldap.org http://pypi.python.org/pypi/python-ldap"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="PSF-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~x86-solaris"
+IUSE="examples sasl ssl"
+
+# If you need support for openldap-2.3.x, please use python-ldap-2.3.9.
+# python team: Please do not remove python-ldap-2.3.9 from the tree.
+# OpenSSL is an optional runtime dep.
+RDEPEND=">net-nds/openldap-2.4.11
+	dev-python/pyasn1[${PYTHON_USEDEP}]
+	sasl? ( >=dev-libs/cyrus-sasl-2.1 )"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]"
+
+python_prepare_all() {
+	sed -e "s:^library_dirs =.*:library_dirs = /usr/$(get_libdir) /usr/$(get_libdir)/sasl2:" \
+		-e "s:^include_dirs =.*:include_dirs = ${EPREFIX}/usr/include ${EPREFIX}/usr/include/sasl:" \
+		-i setup.cfg || die "error fixing setup.cfg"
+
+	local mylibs="ldap"
+	if use sasl; then
+		use ssl && mylibs="ldap_r"
+		mylibs="${mylibs} sasl2"
+	else
+		sed -e 's/HAVE_SASL//g' -i setup.cfg || die
+	fi
+	use ssl && mylibs="${mylibs} ssl crypto"
+	use elibc_glibc && mylibs="${mylibs} resolv"
+
+	sed -e "s:^libs = .*:libs = lber ${mylibs}:" \
+		-i setup.cfg || die "error setting up libs in setup.cfg"
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	# XXX: the tests supposedly can start local slapd
+	# but it requires some manual config, it seems.
+
+	"${PYTHON}" Tests/t_ldapurl.py || die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	use examples && local EXAMPLES=( Demo/. )
+	distutils-r1_python_install_all
+}