Install within gems hierarchy, add tests support, ensure that svg is coordinated with the original cairo package.

(Portage version: 2.2_rc67/cvs/Linux x86_64)

3 files changed, 98 insertions, 4 deletions

diff --git a/dev-ruby/rcairo/ChangeLog b/dev-ruby/rcairo/ChangeLog
index b93c933eb1cf..0ac51a8f7382 100644
--- a/dev-ruby/rcairo/ChangeLog
+++ b/dev-ruby/rcairo/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for dev-ruby/rcairo
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-ruby/rcairo/ChangeLog,v 1.37 2010/07/26 13:43:13 fauli Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-ruby/rcairo/ChangeLog,v 1.38 2010/07/30 17:44:32 flameeyes Exp $
+
+*rcairo-1.8.1-r1 (30 Jul 2010)
+
+  30 Jul 2010; Diego E. Pettenò <flameeyes@gentoo.org> rcairo-1.8.1.ebuild,
+  +rcairo-1.8.1-r1.ebuild:
+  Install within gems hierarchy, add tests support, ensure that svg is
+  coordinated with the original cairo package.
 
   26 Jul 2010; Christian Faulhammer <fauli@gentoo.org> rcairo-1.8.1.ebuild:
   x86 stable, bug 329807
diff --git a/dev-ruby/rcairo/rcairo-1.8.1-r1.ebuild b/dev-ruby/rcairo/rcairo-1.8.1-r1.ebuild
new file mode 100644
index 000000000000..e0c386dcab1a
--- /dev/null
+++ b/dev-ruby/rcairo/rcairo-1.8.1-r1.ebuild
@@ -0,0 +1,85 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-ruby/rcairo/rcairo-1.8.1-r1.ebuild,v 1.1 2010/07/30 17:44:32 flameeyes Exp $
+
+EAPI=2
+
+# ruby19 → fails, and even crashes Ruby
+# jruby → cannot work, it's a compiled extension
+USE_RUBY="ruby18"
+
+# Documentation depends on files that are not distributed.
+RUBY_FAKEGEM_TASK_DOC=""
+
+# Depends on test-unit-2 which is currently masked.
+RUBY_FAKEGEM_TASK_TEST=""
+
+RUBY_FAKEGEM_DOCDIR="doc"
+
+RUBY_FAKEGEM_EXTRADOC="AUTHORS ChangeLog NEWS README"
+
+inherit ruby-fakegem
+
+IUSE="svg"
+
+DESCRIPTION="Ruby bindings for cairo"
+HOMEPAGE="http://cairographics.org/rcairo/"
+SRC_URI="mirror://rubygems/cairo-${PV}.gem"
+
+SLOT="0"
+LICENSE="|| ( Ruby GPL-2 )"
+KEYWORDS="~amd64 ~ia64 ~sparc ~x86"
+
+# force identical svg dependency between the two so that you're forced
+# to rebuild this when changing it on cairo, this is because we cannot
+# enable/disable svg, but it'll follow what the original cairo
+# supports.
+RDEPEND="${RDEPEND}
+	>=x11-libs/cairo-1.2.0[svg=]"
+DEPEND="${DEPEND}
+	>=x11-libs/cairo-1.2.0[svg=]
+	dev-util/pkgconfig"
+
+ruby_add_bdepend "test? ( >=dev-ruby/test-unit-2.1.0-r1:2 )"
+
+all_ruby_prepare() {
+	# it doesn't follow the usual gem tree hierarchy
+	ln -s src/lib lib || die
+
+	# it fails, badly, as it expects the .pc to be frozen in time,
+	# which it isn't...
+	rm test/test_pkg_config.rb || die
+
+	# fix two strange assert calls
+	sed -i \
+		-e 's:assert_true(:assert(:' \
+		-e 's:assert_false(:assert(!:' \
+		test/test_exception.rb \
+		test/test_constants.rb || die
+}
+
+each_ruby_configure() {
+	${RUBY} extconf.rb || die "extconf failed"
+}
+
+each_ruby_compile() {
+	emake || die "make failed"
+
+	# again, try to make it more standard, to install it more easily.
+	cp src/cairo.so lib || die
+}
+
+each_ruby_test() {
+	# don't rely on the Rakefile because it's a mess to load with
+	# their hierarchy, do it manually.
+	${RUBY} -Ilib -r ./test/cairo-test-utils.rb -S \
+		testrb-2 ./test/test_*.rb \
+		|| die "tests failed"
+}
+
+all_ruby_install() {
+	all_fakegem_install
+
+	insinto /usr/share/doc/${PF}/samples
+	doins -r samples/* || die "Cannot install sample files."
+}
diff --git a/dev-ruby/rcairo/rcairo-1.8.1.ebuild b/dev-ruby/rcairo/rcairo-1.8.1.ebuild
index 38822ff79be1..cf5faeb5fe29 100644
--- a/dev-ruby/rcairo/rcairo-1.8.1.ebuild
+++ b/dev-ruby/rcairo/rcairo-1.8.1.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2010 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-ruby/rcairo/rcairo-1.8.1.ebuild,v 1.2 2010/07/26 13:43:13 fauli Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-ruby/rcairo/rcairo-1.8.1.ebuild,v 1.3 2010/07/30 17:44:32 flameeyes Exp $
 
 EAPI=2
 USE_RUBY="ruby18"
@@ -25,8 +25,10 @@ SLOT="0"
 LICENSE="|| ( Ruby GPL-2 )"
 KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~sparc x86"
 
-RDEPEND=">=x11-libs/cairo-1.2.0[svg?]"
-DEPEND="${RDEPEND}
+RDEPEND="${RDEPEND}
+	>=x11-libs/cairo-1.2.0[svg?]"
+DEPEND="${DEPEND}
+	>=x11-libs/cairo-1.2.0[svg?]
 	dev-util/pkgconfig"
 
 each_ruby_configure() {