Remove *.la files

(Portage version: -svn/cvs/Linux i686)

2 files changed, 88 insertions, 1 deletions

diff --git a/dev-util/schroot/ChangeLog b/dev-util/schroot/ChangeLog
index 201333d20cb7..175e68da0ea3 100644
--- a/dev-util/schroot/ChangeLog
+++ b/dev-util/schroot/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-util/schroot
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/schroot/ChangeLog,v 1.4 2009/09/14 08:35:25 abcd Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/schroot/ChangeLog,v 1.5 2009/10/02 02:52:08 abcd Exp $
+
+*schroot-1.2.3-r2 (02 Oct 2009)
+
+  02 Oct 2009; Jonathan Callen <abcd@gentoo.org> +schroot-1.2.3-r2.ebuild:
+  Remove *.la files
 
   14 Sep 2009; Jonathan Callen <abcd@gentoo.org> schroot-1.2.3-r1.ebuild:
   Fix build error with FEATURES=-test (bug 284773). Thanks to Andy Kittner
diff --git a/dev-util/schroot/schroot-1.2.3-r2.ebuild b/dev-util/schroot/schroot-1.2.3-r2.ebuild
new file mode 100644
index 000000000000..543b3ea84318
--- /dev/null
+++ b/dev-util/schroot/schroot-1.2.3-r2.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-util/schroot/schroot-1.2.3-r2.ebuild,v 1.1 2009/10/02 02:52:08 abcd Exp $
+
+EAPI="2"
+
+inherit autotools base
+
+DESCRIPTION="Utility to execute commands in a chroot environment"
+HOMEPAGE="http://packages.debian.org/source/sid/schroot"
+SRC_URI="mirror://debian/pool/main/${PN:0:1}/${PN}/${PN}_${PV}.orig.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+dchroot debug doc nls test"
+
+COMMON_DEPEND="
+	>=dev-libs/boost-1.34.0
+	dev-libs/lockdev
+	sys-libs/pam
+"
+
+DEPEND="${COMMON_DEPEND}
+	nls? ( sys-devel/gettext )
+	test? ( >=dev-util/cppunit-1.10.0 )
+"
+RDEPEND="${COMMON_DEPEND}
+	sys-apps/debianutils
+	dchroot? ( !dev-util/dchroot )
+	nls? ( virtual/libintl )
+"
+
+PATCHES=(
+	"${FILESDIR}/${P}-autotools.patch"
+	"${FILESDIR}/${P}-pam.patch"
+	"${FILESDIR}/${P}-tests.patch"
+)
+
+src_prepare() {
+	base_src_prepare
+
+	if use test; then
+		# Fix bug where aclocal doesn't find cppunit.m4 from the system...
+		ln -s /usr/share/aclocal/cppunit.m4 m4/
+	else
+		# Don't depend on cppunit unless we are testing
+		sed -i '/AM_PATH_CPPUNIT/s/^.*$/:/' configure.ac
+	fi
+
+	export AT_M4DIR=m4
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		$(use_enable dchroot) \
+		$(use_enable dchroot dchroot-dsa) \
+		$(use_enable debug) \
+		$(use_enable nls) \
+		--enable-shared \
+		--disable-static \
+		--localstatedir=/var
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "emake install failed"
+
+	newinitd "${FILESDIR}"/schroot.initd schroot || die "installation of init.d script failed"
+	newconfd "${FILESDIR}"/schroot.confd schroot || die "installation of conf.d file failed"
+
+	dodoc AUTHORS ChangeLog NEWS README THANKS TODO || die "installation of docs failed"
+	if use doc; then
+		insinto /usr/share/doc/${PF}/html/sbuild
+		doins doc/sbuild/html/* || die "installation of html docs failed"
+		insinto /usr/share/doc/${PF}/html/schroot
+		doins doc/schroot/html/* || die "installation of html docs failed"
+	fi
+
+	# Remove *.la files
+	find "${D}" -name "*.la" -exec rm {} + || die "removal of *.la files failed"
+}