Version bump. Ebuild by Arfrever.

(Portage version: 2.2.0_alpha90/cvs/Linux x86_64)

2 files changed, 78 insertions, 1 deletions

diff --git a/dev-util/global/ChangeLog b/dev-util/global/ChangeLog
index bfeeb8580616..2dc059e794cf 100644
--- a/dev-util/global/ChangeLog
+++ b/dev-util/global/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-util/global
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/global/ChangeLog,v 1.95 2012/03/13 02:18:10 floppym Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/global/ChangeLog,v 1.96 2012/03/16 03:00:19 floppym Exp $
+
+*global-6.2.2 (16 Mar 2012)
+
+  16 Mar 2012; Mike Gilbert <floppym@gentoo.org> +global-6.2.2.ebuild:
+  Version bump. Ebuild by Arfrever.
 
 *global-6.2.1 (13 Mar 2012)
 
diff --git a/dev-util/global/global-6.2.2.ebuild b/dev-util/global/global-6.2.2.ebuild
new file mode 100644
index 000000000000..dc1984733c73
--- /dev/null
+++ b/dev-util/global/global-6.2.2.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-util/global/global-6.2.2.ebuild,v 1.1 2012/03/16 03:00:19 floppym Exp $
+
+EAPI="4"
+
+inherit elisp-common
+
+DESCRIPTION="GNU Global is a tag system to find the locations of a specified object in various sources."
+HOMEPAGE="http://www.gnu.org/software/global/global.html"
+SRC_URI="ftp://ftp.gnu.org/pub/gnu/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~sparc ~x86 ~x86-fbsd"
+IUSE="doc emacs vim"
+
+RDEPEND="emacs? ( virtual/emacs )
+	vim? ( || ( app-editors/vim app-editors/gvim ) )"
+DEPEND="${DEPEND}
+	doc? ( app-text/texi2html sys-apps/texinfo )"
+
+SITEFILE="50gtags-gentoo.el"
+
+src_configure() {
+	econf "$(use_with emacs lispdir "${SITELISP}/${PN}")"
+}
+
+src_compile() {
+	if use doc; then
+		texi2pdf -q -o doc/global.pdf doc/global.texi
+		texi2html -o doc/global.html doc/global.texi
+	fi
+
+	if use emacs; then
+		elisp-compile *.el || die "elisp-compile failed"
+	fi
+
+	emake
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+
+	if use doc; then
+		dohtml doc/global.html
+		[[ -f doc/global.pdf ]] && dodoc doc/global.pdf
+	fi
+
+	dodoc AUTHORS FAQ NEWS README THANKS
+
+	insinto /etc
+	doins gtags.conf
+
+	if use vim; then
+		insinto /usr/share/vim/vimfiles/plugin
+		doins gtags.vim
+	fi
+
+	if use emacs; then
+		elisp-install ${PN} *.{el,elc} || die "elisp-install failed"
+		elisp-site-file-install "${FILESDIR}/${SITEFILE}" || die "elisp-site-file-install failed"
+	fi
+}
+
+pkg_postinst() {
+	use emacs && elisp-site-regen
+}
+
+pkg_postrm() {
+	use emacs && elisp-site-regen
+}