Version bump (bug #500010), add ncurses and qt4 use flags, and add myself as a maintainer.

(Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key 4AB3E85B4F064CA3)

3 files changed, 74 insertions, 2 deletions

diff --git a/dev-vcs/hgview/ChangeLog b/dev-vcs/hgview/ChangeLog
index 60ffc9e9405c..de3e9ee4421f 100644
--- a/dev-vcs/hgview/ChangeLog
+++ b/dev-vcs/hgview/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for dev-vcs/hgview
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-vcs/hgview/ChangeLog,v 1.12 2014/01/16 09:58:46 kensington Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-vcs/hgview/ChangeLog,v 1.13 2014/02/03 04:15:24 radhermit Exp $
+
+*hgview-1.8.0 (03 Feb 2014)
+
+  03 Feb 2014; Tim Harder <radhermit@gentoo.org> +hgview-1.8.0.ebuild,
+  metadata.xml:
+  Version bump (bug #500010), add ncurses and qt4 use flags, and add myself as
+  a maintainer.
 
   16 Jan 2014; Michael Palimaka <kensington@gentoo.org> -hgview-1.6.2-r1.ebuild,
   -hgview-1.7.0.ebuild, -hgview-1.7.1.ebuild:
diff --git a/dev-vcs/hgview/hgview-1.8.0.ebuild b/dev-vcs/hgview/hgview-1.8.0.ebuild
new file mode 100644
index 000000000000..92fb7797e5ce
--- /dev/null
+++ b/dev-vcs/hgview/hgview-1.8.0.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-vcs/hgview/hgview-1.8.0.ebuild,v 1.1 2014/02/03 04:15:24 radhermit Exp $
+
+EAPI=5
+PYTHON_COMPAT=( python2_7 )
+DISTUTILS_IN_SOURCE_BUILD=1
+inherit distutils-r1
+
+DESCRIPTION="A Mercurial interactive history viewer"
+HOMEPAGE="http://www.logilab.org/project/hgview/ https://pypi.python.org/pypi/hgview/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc ncurses +qt4"
+REQUIRED_USE="|| ( ncurses qt4 )"
+
+RDEPEND="dev-vcs/mercurial[${PYTHON_USEDEP}]
+	ncurses? (
+		>=dev-python/urwid-1.0.0[${PYTHON_USEDEP}]
+		dev-python/pyinotify[${PYTHON_USEDEP}]
+		dev-python/pygments[${PYTHON_USEDEP}]
+	)
+	qt4? (
+		dev-python/docutils[${PYTHON_USEDEP}]
+		dev-python/PyQt4[X,${PYTHON_USEDEP}]
+		dev-python/qscintilla-python[${PYTHON_USEDEP}]
+	)"
+DEPEND="${RDEPEND}
+	doc? (
+		app-text/asciidoc
+		app-text/xmlto
+	)"
+
+python_configure_all() {
+	mydistutilsargs=(
+		build $(use doc || echo --no-doc)
+		build $(use ncurses || echo --no-curses)
+		build $(use qt4 || echo --no-qt)
+	)
+}
+
+src_prepare() {
+	# https://www.logilab.org/ticket/103668
+	sed -i \
+		-e 's:MANDIR=$(PREFIX)/man:MANDIR=$(PREFIX)/share/man:' \
+		-e 's:$(INSTALL) $$i:$(INSTALL) -m 644 $$i:' \
+		doc/Makefile || die
+
+	distutils-r1_src_prepare
+}
+
+src_install() {
+	distutils-r1_src_install
+
+	# Install Mercurial extension config file
+	insinto /etc/mercurial/hgrc.d
+	doins hgext/hgview.rc
+}
diff --git a/dev-vcs/hgview/metadata.xml b/dev-vcs/hgview/metadata.xml
index dc439f7e84f5..7e39f86a6005 100644
--- a/dev-vcs/hgview/metadata.xml
+++ b/dev-vcs/hgview/metadata.xml
@@ -1,5 +1,9 @@
 <?xml version="1.0" encoding="UTF-8"?>
 <!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
-<herd>qt</herd>
+	<herd>qt</herd>
+	<maintainer>
+		<email>radhermit@gentoo.org</email>
+		<name>Tim Harder</name>
+	</maintainer>
 </pkgmetadata>