migrate to distutils-r1, respect FHS and gamesdirs, add amd64 keyword

(Portage version: 2.2.0_alpha149/cvs/Linux x86_64, signed Manifest commit with key E73C35B3)

2 files changed, 80 insertions, 2 deletions

diff --git a/games-action/slune/ChangeLog b/games-action/slune/ChangeLog
index 06bf5f749b64..95e0918c43b6 100644
--- a/games-action/slune/ChangeLog
+++ b/games-action/slune/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for games-action/slune
-# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-action/slune/ChangeLog,v 1.19 2011/04/06 19:56:01 arfrever Exp $
+# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/games-action/slune/ChangeLog,v 1.20 2013/01/11 18:22:02 hasufell Exp $
+
+*slune-1.0.15-r1 (11 Jan 2013)
+
+  11 Jan 2013; Julian Ospald <hasufell@gentoo.org> +slune-1.0.15-r1.ebuild:
+  migrate to distutils-r1, respect FHS and gamesdirs, add amd64 keyword
 
   06 Apr 2011; Arfrever Frehtes Taifersar Arahesis <arfrever@gentoo.org>
   slune-1.0.15.ebuild:
diff --git a/games-action/slune/slune-1.0.15-r1.ebuild b/games-action/slune/slune-1.0.15-r1.ebuild
new file mode 100644
index 000000000000..37ee422b408c
--- /dev/null
+++ b/games-action/slune/slune-1.0.15-r1.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/games-action/slune/slune-1.0.15-r1.ebuild,v 1.1 2013/01/11 18:22:02 hasufell Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_5 python2_6 python2_7 )
+
+# inherit base explicitly to avoid overrides on distutils-r1
+inherit base gnome2-utils python-utils-r1 distutils-r1 games
+
+DESCRIPTION="A 3D action game with multiplayer mode and amazing graphics"
+HOMEPAGE="http://oomadness.tuxfamily.org/en/slune/"
+SRC_URI="http://download.gna.org/slune/Slune-${PV}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+RDEPEND="virtual/opengl
+	>=media-libs/libsdl-1.2.6
+	>=dev-python/soya-0.9
+	>=dev-python/py2play-0.1.9
+	>=dev-python/pyopenal-0.1.3
+	>=dev-python/pyogg-1.1
+	>=dev-python/pyvorbis-1.1"
+DEPEND="${RDEPEND}"
+
+S=${WORKDIR}/Slune-${PV}
+
+python_install() {
+	distutils-r1_python_install \
+		--install-scripts="${GAMES_BINDIR}" \
+		--install-data="${GAMES_DATADIR}" \
+		--install-lib="$(python_get_sitedir)"
+
+	# FHS broke the logic, fix it
+	local i
+	for i in $(ls -I locale "${ED}${GAMES_DATADIR}"/${PN}) ; do
+		dosym "${GAMES_DATADIR}/${PN}/${i}" "$(python_get_sitedir)/${PN}/${i}"
+	done
+}
+
+src_compile() {
+	distutils-r1_src_compile
+}
+
+src_install() {
+	distutils-r1_src_install
+
+	# fix install dest of locales
+	mv "${ED}${GAMES_DATADIR}"/${PN}/locale "${ED}"/usr/share/locale || die
+
+	newicon -s 48 images/${PN}.48.png ${PN}.png
+	make_desktop_entry ${PN} "Slune"
+
+	prepgamesdirs
+}
+
+pkg_preinst() {
+	games_pkg_preinst
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	games_pkg_postinst
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+}