version bump

(Portage version: 2.1.6.13/cvs/Linux i686)

2 files changed, 137 insertions, 1 deletions

diff --git a/games-emulation/sdlmame/ChangeLog b/games-emulation/sdlmame/ChangeLog
index 3a5208a21783..8d404b717ba1 100644
--- a/games-emulation/sdlmame/ChangeLog
+++ b/games-emulation/sdlmame/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for games-emulation/sdlmame
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-emulation/sdlmame/ChangeLog,v 1.20 2009/06/10 17:06:11 mr_bones_ Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-emulation/sdlmame/ChangeLog,v 1.21 2009/07/21 02:35:53 mr_bones_ Exp $
+
+*sdlmame-0.133 (21 Jul 2009)
+
+  21 Jul 2009; Michael Sterrett <mr_bones_@gentoo.org>
+  +sdlmame-0.133.ebuild:
+  version bump
 
 *sdlmame-0.132 (10 Jun 2009)
 
diff --git a/games-emulation/sdlmame/sdlmame-0.133.ebuild b/games-emulation/sdlmame/sdlmame-0.133.ebuild
new file mode 100644
index 000000000000..a56e196a6857
--- /dev/null
+++ b/games-emulation/sdlmame/sdlmame-0.133.ebuild
@@ -0,0 +1,130 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/games-emulation/sdlmame/sdlmame-0.133.ebuild,v 1.1 2009/07/21 02:35:53 mr_bones_ Exp $
+
+EAPI=2
+inherit eutils flag-o-matic games
+
+MY_PV=${PV/.}
+MY_PV=${MY_PV/_p/u}
+MY_P=${PN}${MY_PV}
+DESCRIPTION="Multiple Arcade Machine Emulator (SDL)"
+HOMEPAGE="http://rbelmont.mameworld.info/?page_id=163"
+# Upstream doesn't allow fetching with unknown User-Agent such as wget
+SRC_URI="mirror://gentoo/${MY_P}.zip
+	mirror://gentoo/${PN}-manpages.tar.gz"
+
+LICENSE="XMAME"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="opengl"
+
+RDEPEND=">=media-libs/libsdl-1.2.10[opengl?]
+	dev-libs/expat
+	x11-libs/libXinerama
+	x11-libs/gtk+:2
+	gnome-base/gconf:2"
+DEPEND="${RDEPEND}
+	app-arch/unzip
+	x11-proto/xineramaproto"
+
+S=${WORKDIR}/${MY_P}
+
+# Function to disable a makefile option
+disable_feature() {
+	sed -i \
+		-e "/$1.*=/s:^:# :" \
+		"${S}"/makefile \
+		|| die "sed failed"
+}
+
+# Function to enable a makefile option
+enable_feature() {
+	sed -i \
+		-e "/^#.*$1.*=/s:^# ::"  \
+		"${S}"/makefile \
+		|| die "sed failed"
+}
+
+src_prepare() {
+	sed -i \
+		-e '/CFLAGS += -O$(OPTIMIZE)/s:^:# :' \
+		-e '/CFLAGS += -pipe/s:^:# :' \
+		-e '/LDFLAGS += -s/s:^:# :' \
+		-e 's:-Werror::' \
+		makefile \
+		|| die "sed failed"
+	# Don't compile zlib and expat
+	einfo "Disabling embedded libraries: zlib and expat"
+	disable_feature BUILD_ZLIB
+	disable_feature BUILD_EXPAT
+
+	if use amd64; then
+		einfo "Enabling 64-bit support"
+		enable_feature PTR64
+	fi
+
+	if use ppc; then
+		einfo "Enabling PPC support"
+		enable_feature BIGENDIAN
+	fi
+}
+
+src_compile() {
+	local make_opts
+
+	use opengl || make_opts="${make_opts} NO_OPENGL=1"
+
+	emake \
+		NAME="${PN}" \
+		OPT_FLAGS='-DINI_PATH=\"\$$HOME/.sdlmame\;'"${GAMES_SYSCONFDIR}/${PN}"'\"'" ${CFLAGS}" \
+		SUFFIX="" \
+		${make_opts} \
+		|| die "emake failed"
+}
+
+src_install() {
+	dogamesbin "${PN}" || die "dogamesbin "${PN}" failed"
+
+	# Follows xmame ebuild, avoiding collision on /usr/games/bin/jedutil
+	exeinto "$(games_get_libdir)/${PN}"
+	local f
+	for f in chdman ldverify jedutil romcmp testkeys; do
+		doexe "${f}" || die "doexe ${f} failed"
+	done
+
+	insinto "${GAMES_DATADIR}/${PN}"
+	doins ui.bdf || die "doins ui.bdf failed"
+	doins -r keymaps || die "doins -r keymaps failed"
+
+	insinto "${GAMES_SYSCONFDIR}/${PN}"
+	doins "${FILESDIR}"/{joymap.dat,vector.ini} || die "doins joymap.dat vector.ini failed"
+
+	sed \
+		-e "s:@GAMES_SYSCONFDIR@:${GAMES_SYSCONFDIR}:" \
+		-e "s:@GAMES_DATADIR@:${GAMES_DATADIR}:" \
+		"${FILESDIR}"/mame.ini.in > "${D}/${GAMES_SYSCONFDIR}/${PN}/"mame.ini \
+		|| die "sed failed"
+
+	dodoc docs/{config,mame,newvideo}.txt *.txt
+	doman "${WORKDIR}/${PN}-manpages"/*
+
+	keepdir \
+		"${GAMES_DATADIR}/${PN}"/{roms,samples,artwork} \
+		"${GAMES_SYSCONFDIR}/${PN}"/ctrlr
+
+	prepgamesdirs
+}
+
+pkg_postinst() {
+	games_pkg_postinst
+
+	elog "It's strongly recommended that you change either the system-wide"
+	elog "mame.ini at \"${GAMES_SYSCONFDIR}/${PN}\" or use a per-user setup at \$HOME/.${PN}"
+
+	if use opengl; then
+		echo
+		elog "You built ${PN} with opengl support and should set"
+		elog "\"video\" to \"opengl\" in mame.ini to take advantage of that"
+	fi
+}