initial import

(Portage version: 2.2.0_alpha188/cvs/Linux x86_64, signed Manifest commit with key E73C35B3)

4 files changed, 114 insertions, 0 deletions

diff --git a/games-misc/little-inferno/ChangeLog b/games-misc/little-inferno/ChangeLog
new file mode 100644
index 000000000000..39f23f4e7e5f
--- /dev/null
+++ b/games-misc/little-inferno/ChangeLog
@@ -0,0 +1,10 @@
+# ChangeLog for games-misc/little-inferno
+# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/games-misc/little-inferno/ChangeLog,v 1.1 2013/07/16 15:20:41 hasufell Exp $
+
+*little-inferno-20130509 (16 Jul 2013)
+
+  16 Jul 2013; Julian Ospald <hasufell@gentoo.org>
+  +little-inferno-20130509.ebuild, +metadata.xml:
+  initial import
+
diff --git a/games-misc/little-inferno/Manifest b/games-misc/little-inferno/Manifest
new file mode 100644
index 000000000000..95ed0b7623bd
--- /dev/null
+++ b/games-misc/little-inferno/Manifest
@@ -0,0 +1,4 @@
+DIST LittleInferno-20130509.sh 194304242 SHA256 3848f4037652699c162ebf3ae78f6dce81772394911483c9f1ef49cb51f6a198 SHA512 19e2e616b1b1a6e7f8974ba12756c4b54c1daa99c99056891c56f7ed578f20a15143d683960efbb69f3d680243dd219051fc0bdac60ab74dcddc1c69df7d00dd WHIRLPOOL 2a25aa0fd1103dca63fa422cc3573eefa8a7acc819735b591a44ce89c9f9581a75287dcae8dbd8d2be52c63782af97a3b36fc676ee98288d73b9d08f2b2b2ec4
+EBUILD little-inferno-20130509.ebuild 1677 SHA256 8d950e4965c50c0c508044c90f561c9d112093c9d205faca76d43a696975ece8 SHA512 7c299fc78dbba933e467904824eff1b0cf381ae6dd678ac99c17e8163c498eacff0910dab0695337f1c3744ae94324bf6249670811879afe3b7d210c2d452097 WHIRLPOOL 7afa2f738479349a5e3dfa8d1285d97725b24288a7dadaace3433a6ad6d8630e71baeaa2efc0cb8f74fc33081526a8eab95b798e465b007d8d25b5a706978da8
+MISC ChangeLog 285 SHA256 2bad3d856f53c0b6f978e027601351b7f1ec3b0a76b7b4824af4ab22ca8bfafd SHA512 98f0fcf76fa26283f399cde084814bf7dd53589e58e516a4717c8160d1904918bdc1287c409dda10ce45c260cdf2d616042c1822e611e9def26aade622f29acb WHIRLPOOL fb20feaed78539d0ea21a19db9badb1bd2e508b3fedefcb4dbb3659ed340d61791f67685eced4c23618d0b585ea09edcc353937f7a57b410b8232fec19bced50
+MISC metadata.xml 327 SHA256 e287a4047554ae759338428ac70927eee57aee6c18e9f176c8c2e4f57bf81a0c SHA512 2eb4638caebf5c66ad9e09c6e0e6446e01d3ff229a9292e1627fd325eaf66fb681e3cbacec85764bccd9bb801df6b78647d1adcc4ba1d5de6cae133aff5eabde WHIRLPOOL 313b05e878325d911600fc88367ded6d9942e58b4bce22e884eca21e67835108b75376bf3bd577be0200b553e3795facc462974fdef7bb8f9681039c70738f29
diff --git a/games-misc/little-inferno/little-inferno-20130509.ebuild b/games-misc/little-inferno/little-inferno-20130509.ebuild
new file mode 100644
index 000000000000..e086dd9641d6
--- /dev/null
+++ b/games-misc/little-inferno/little-inferno-20130509.ebuild
@@ -0,0 +1,88 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/games-misc/little-inferno/little-inferno-20130509.ebuild,v 1.1 2013/07/16 15:20:41 hasufell Exp $
+
+EAPI=5
+
+inherit eutils gnome2-utils unpacker games
+
+DESCRIPTION="Throw your toys into your fire, and play with them as they burn"
+HOMEPAGE="http://tomorrowcorporation.com/"
+SRC_URI="LittleInferno-${PV}.sh"
+
+LICENSE="Gameplay-Group-EULA"
+SLOT="0"
+KEYWORDS="-* ~amd64 ~x86"
+IUSE="bundled-libs"
+RESTRICT="bindist fetch splitdebug"
+
+MYGAMEDIR=${GAMES_PREFIX_OPT}/${PN}
+QA_PREBUILT="${MYGAMEDIR#/}/LittleInferno.bin.x86
+	${MYGAMEDIR#/}/lib/*"
+
+RDEPEND="
+	virtual/opengl
+	amd64? (
+		app-emulation/emul-linux-x86-baselibs
+		app-emulation/emul-linux-x86-xlibs
+		!bundled-libs? (
+			app-emulation/emul-linux-x86-sdl
+			app-emulation/emul-linux-x86-soundlibs
+		)
+	)
+	x86? (
+		net-misc/curl
+		x11-libs/libX11
+		!bundled-libs? (
+			media-libs/libogg
+			media-libs/libvorbis
+			media-libs/openal
+		)
+	)"
+DEPEND="app-arch/xz-utils"
+
+src_unpack() {
+	unpack_makeself ${A}
+
+	mkdir ${P} || die
+	cd ${P} || die
+
+	local i
+	for i in instarchive_{,linux_}all ; do
+		mv ../"${i}" ../"${i}".tar.xz || die
+		unpack ./../"${i}".tar.xz
+	done
+}
+
+src_prepare() {
+	if use !bundled-libs ; then
+		rm -rv lib || die
+	fi
+}
+
+src_install() {
+	insinto "${MYGAMEDIR}"
+	doins -r *
+
+	doicon -s 128 LittleInferno.png
+	make_desktop_entry ${PN} "Little Inferno" LittleInferno
+	games_make_wrapper ${PN} "./LittleInferno.bin.x86" "${MYGAMEDIR}" "${MYGAMEDIR}/lib"
+
+	fperms +x "${MYGAMEDIR}"/LittleInferno.bin.x86
+
+	prepgamesdirs
+}
+
+pkg_preinst() {
+	games_pkg_preinst
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	games_pkg_postinst
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+}
diff --git a/games-misc/little-inferno/metadata.xml b/games-misc/little-inferno/metadata.xml
new file mode 100644
index 000000000000..aca09d5ccfca
--- /dev/null
+++ b/games-misc/little-inferno/metadata.xml
@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<herd>games</herd>
+	<maintainer>
+		<email>hasufell@gentoo.org</email>
+		<name>Julian Ospald</name>
+	</maintainer>
+	<use>
+		<flag name='bundled-libs'>Use bundled libraries.</flag>
+	</use>
+</pkgmetadata>