Add upstream patches to prevent gnome-shell from crashing when certain .desktop files are updated.

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key CF0ADD61)

2 files changed, 64 insertions, 1 deletions

diff --git a/gnome-base/gnome-menus/ChangeLog b/gnome-base/gnome-menus/ChangeLog
index 0adeef4189bf..02cc93ae3af7 100644
--- a/gnome-base/gnome-menus/ChangeLog
+++ b/gnome-base/gnome-menus/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for gnome-base/gnome-menus
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-base/gnome-menus/ChangeLog,v 1.204 2014/04/26 18:18:25 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-base/gnome-menus/ChangeLog,v 1.205 2014/06/07 17:01:47 tetromino Exp $
+
+*gnome-menus-3.10.1-r1 (07 Jun 2014)
+
+  07 Jun 2014; Alexandre Rostovtsev <tetromino@gentoo.org>
+  +gnome-menus-3.10.1-r1.ebuild:
+  Add upstream patches to prevent gnome-shell from crashing when certain
+  .desktop files are updated.
 
   26 Apr 2014; Pacho Ramos <pacho@gentoo.org> -gnome-menus-3.8.1.ebuild:
   drop old
diff --git a/gnome-base/gnome-menus/gnome-menus-3.10.1-r1.ebuild b/gnome-base/gnome-menus/gnome-menus-3.10.1-r1.ebuild
new file mode 100644
index 000000000000..5f8f3a692279
--- /dev/null
+++ b/gnome-base/gnome-menus/gnome-menus-3.10.1-r1.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/gnome-base/gnome-menus/gnome-menus-3.10.1-r1.ebuild,v 1.1 2014/06/07 17:01:47 tetromino Exp $
+
+EAPI="5"
+GCONF_DEBUG="no"
+
+inherit eutils gnome2
+
+DESCRIPTION="Library for the Desktop Menu fd.o specification"
+HOMEPAGE="https://git.gnome.org/browse/gnome-menus"
+SRC_URI="${SRC_URI}
+	http://dev.gentoo.org/~tetromino/distfiles/${PN}/${PN}-3.10.1-patches.tar.xz"
+
+LICENSE="GPL-2+ LGPL-2+"
+SLOT="3"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~x86-solaris"
+
+IUSE="debug +introspection test"
+
+COMMON_DEPEND="
+	>=dev-libs/glib-2.29.15:2
+	introspection? ( >=dev-libs/gobject-introspection-0.9.5 )
+"
+# Older versions of slot 0 install the menu editor and the desktop directories
+
+RDEPEND="${COMMON_DEPEND}
+	!<gnome-base/gnome-menus-3.0.1-r1:0
+"
+DEPEND="${COMMON_DEPEND}
+	>=dev-util/intltool-0.40
+	sys-devel/gettext
+	virtual/pkgconfig
+	test? ( dev-libs/gjs )
+"
+
+src_prepare() {
+	# Don't show KDE standalone settings desktop files in GNOME others menu
+	epatch "${FILESDIR}/${PN}-3.8.0-ignore_kde_standalone.patch"
+
+	# Fixes for crashes and memory leaks from upstream git master
+	epatch ../"${PN}-3.10.1-patches"/*.patch
+
+	gnome2_src_prepare
+}
+
+src_configure() {
+	DOCS="AUTHORS ChangeLog HACKING NEWS README"
+
+	# Do NOT compile with --disable-debug/--enable-debug=no
+	# It disables api usage checks
+	gnome2_src_configure \
+		$(usex debug --enable-debug=yes --enable-debug=minimum) \
+		$(use_enable introspection) \
+		--disable-static
+}