Bump to 1.4.2 -- 4 bugfixes; 2 minor features

(Portage version: 2.1.7.13/cvs/Linux i686)

2 files changed, 106 insertions, 1 deletions

diff --git a/gnome-base/gvfs/ChangeLog b/gnome-base/gvfs/ChangeLog
index 1f8874b5c89a..28ad28611895 100644
--- a/gnome-base/gvfs/ChangeLog
+++ b/gnome-base/gvfs/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for gnome-base/gvfs
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-base/gvfs/ChangeLog,v 1.86 2009/12/03 17:10:10 ranger Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-base/gvfs/ChangeLog,v 1.87 2009/12/13 10:37:27 nirbheek Exp $
+
+*gvfs-1.4.2 (13 Dec 2009)
+
+  13 Dec 2009; Nirbheek Chauhan <nirbheek@gentoo.org> +gvfs-1.4.2.ebuild:
+  Bump to 1.4.2 -- 4 bugfixes; 2 minor features
 
   03 Dec 2009; Brent Baude <ranger@gentoo.org> gvfs-1.2.3.ebuild:
   Marking gvfs-1.2.3 ppc64 stable for bug 281427
diff --git a/gnome-base/gvfs/gvfs-1.4.2.ebuild b/gnome-base/gvfs/gvfs-1.4.2.ebuild
new file mode 100644
index 000000000000..47eef0625bd2
--- /dev/null
+++ b/gnome-base/gvfs/gvfs-1.4.2.ebuild
@@ -0,0 +1,100 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/gnome-base/gvfs/gvfs-1.4.2.ebuild,v 1.1 2009/12/13 10:37:27 nirbheek Exp $
+
+EAPI="2"
+GCONF_DEBUG="no"
+
+inherit autotools bash-completion gnome2 eutils
+
+DESCRIPTION="GNOME Virtual Filesystem Layer"
+HOMEPAGE="http://www.gnome.org"
+
+LICENSE="LGPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="archive avahi bluetooth cdda doc fuse gdu gnome gnome-keyring gphoto2 hal samba +udev"
+
+RDEPEND=">=dev-libs/glib-2.21.2
+	>=sys-apps/dbus-1.0
+	>=net-libs/libsoup-2.25.1[gnome]
+	dev-libs/libxml2
+	net-misc/openssh
+	>=sys-fs/udev-138
+	archive? ( app-arch/libarchive )
+	avahi? ( >=net-dns/avahi-0.6 )
+	bluetooth? (
+		dev-libs/dbus-glib
+		net-wireless/bluez
+		dev-libs/expat )
+	fuse? ( sys-fs/fuse )
+	gdu? ( >=sys-apps/gnome-disk-utility-2.28 )
+	gnome? ( >=gnome-base/gconf-2.0 )
+	gnome-keyring? ( >=gnome-base/gnome-keyring-1.0 )
+	gphoto2? ( >=media-libs/libgphoto2-2.4.7 )
+	udev? (
+		cdda? ( >=dev-libs/libcdio-0.78.2[-minimal] )
+		>=sys-fs/udev-145[extras] )
+	hal? (
+		cdda? ( >=dev-libs/libcdio-0.78.2[-minimal] )
+		>=sys-apps/hal-0.5.10 )
+	samba? ( >=net-fs/samba-3 )"
+DEPEND="${RDEPEND}
+	>=dev-util/intltool-0.40
+	>=dev-util/pkgconfig-0.19
+	dev-util/gtk-doc-am
+	doc? ( >=dev-util/gtk-doc-1 )"
+
+DOCS="AUTHORS ChangeLog NEWS README TODO"
+
+pkg_setup() {
+	if use cdda && ! use hal && ! use udev; then
+		ewarn "You have \"+cdda\", but you have \"-hal\" and \"-udev\""
+		ewarn "cdda support will NOT be built unless you enable EITHER hal OR udev"
+	fi
+
+	G2CONF="${G2CONF}
+		--enable-udev
+		--enable-http
+		--disable-bash-completion
+		$(use_enable archive)
+		$(use_enable avahi)
+		$(use_enable bluetooth obexftp)
+		$(use_enable cdda)
+		$(use_enable fuse)
+		$(use_enable gdu)
+		$(use_enable gnome gconf)
+		$(use_enable gphoto2)
+		$(use_enable udev gudev)
+		$(use_enable hal)
+		$(use_enable gnome-keyring keyring)
+		$(use_enable samba)"
+}
+
+src_prepare() {
+	gnome2_src_prepare
+
+	# Conditional patching purely to avoid eautoreconf
+	use gphoto2 && epatch "${FILESDIR}/${PN}-1.2.2-gphoto2-stricter-checks.patch"
+
+	if use archive; then
+		epatch "${FILESDIR}/${PN}-1.2.2-expose-archive-backend.patch"
+		echo "mount-archive.desktop.in" >> po/POTFILES.in
+		echo "mount-archive.desktop.in.in" >> po/POTFILES.in
+	fi
+
+	use gphoto2 || use archive && eautoreconf
+}
+
+src_install() {
+	gnome2_src_install
+	use bash-completion && \
+		dobashcompletion programs/gvfs-bash-completion.sh ${PN}
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+	use bash-completion && bash-completion_pkg_postinst
+
+	ewarn "In order to use the new gvfs services, please reload dbus configuration"
+}