Launch nautilus-classic, upstream bug #709016

(Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)

2 files changed, 83 insertions, 1 deletions

diff --git a/gnome-base/gnome-panel/ChangeLog b/gnome-base/gnome-panel/ChangeLog
index 457f20bab922..4c44ca714032 100644
--- a/gnome-base/gnome-panel/ChangeLog
+++ b/gnome-base/gnome-panel/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for gnome-base/gnome-panel
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-base/gnome-panel/ChangeLog,v 1.362 2013/09/28 20:01:06 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-base/gnome-panel/ChangeLog,v 1.363 2013/10/31 07:34:54 pacho Exp $
+
+*gnome-panel-3.8.0-r1 (31 Oct 2013)
+
+  31 Oct 2013; Pacho Ramos <pacho@gentoo.org> +gnome-panel-3.8.0-r1.ebuild:
+  Launch nautilus-classic, upstream bug #709016
 
 *gnome-panel-3.8.0 (28 Sep 2013)
 
diff --git a/gnome-base/gnome-panel/gnome-panel-3.8.0-r1.ebuild b/gnome-base/gnome-panel/gnome-panel-3.8.0-r1.ebuild
new file mode 100644
index 000000000000..7d3d9f902a88
--- /dev/null
+++ b/gnome-base/gnome-panel/gnome-panel-3.8.0-r1.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/gnome-base/gnome-panel/gnome-panel-3.8.0-r1.ebuild,v 1.1 2013/10/31 07:34:54 pacho Exp $
+
+EAPI="5"
+GCONF_DEBUG="no"
+GNOME2_LA_PUNT="yes"
+
+inherit gnome2
+
+DESCRIPTION="The GNOME panel"
+HOMEPAGE="https://git.gnome.org/browse/gnome-panel"
+
+LICENSE="GPL-2+ FDL-1.1+ LGPL-2+"
+SLOT="0"
+IUSE="eds +introspection networkmanager"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd ~x86-interix ~amd64-linux ~x86-linux ~x86-solaris"
+
+RDEPEND="
+	>=dev-libs/glib-2.31.14:2
+	>=dev-libs/libgweather-3.5.1:2=
+	dev-libs/libxml2:2
+	>=gnome-base/dconf-0.13.4
+	>=gnome-base/gconf-2.6.1:2[introspection?]
+	>=gnome-base/gnome-desktop-2.91:3=
+	>=gnome-base/gnome-menus-3.1.4:3
+	gnome-base/gsettings-desktop-schemas
+	gnome-base/librsvg:2
+	>=net-libs/telepathy-glib-0.14
+	sys-auth/polkit
+	>=x11-libs/cairo-1[X]
+	>=x11-libs/gdk-pixbuf-2.25.2:2
+	>=x11-libs/gtk+-3.3.8:3[introspection?]
+	x11-libs/libXau
+	x11-libs/libICE
+	x11-libs/libSM
+	>=x11-libs/libXrandr-1.2
+	>=x11-libs/libwnck-2.91:3
+	>=x11-libs/pango-1.15.4[introspection?]
+
+	eds? ( >=gnome-extra/evolution-data-server-3.5.3:= )
+	introspection? ( >=dev-libs/gobject-introspection-0.9.5 )
+	networkmanager? ( >=net-misc/networkmanager-0.6.7 )
+"
+DEPEND="${RDEPEND}
+	app-text/docbook-xml-dtd:4.1.2
+	app-text/yelp-tools
+	>=dev-lang/perl-5
+	dev-util/gtk-doc-am
+	>=dev-util/intltool-0.40
+	virtual/pkgconfig
+"
+# eautoreconf needs
+#	dev-libs/gobject-introspection-common
+#	gnome-base/gnome-common
+
+src_prepare() {
+	# Launch nautilus-classic, upstream bug #709016
+	sed -i '/RequiredComponents/ s|$|nautilus-classic;|' data/gnome-flashback.session.desktop.in || die
+	gnome2_src_prepare
+}
+
+src_configure() {
+	DOCS="AUTHORS ChangeLog HACKING NEWS README"
+
+	# XXX: Make presence/telepathy-glib support optional?
+	#      We can do that if we intend to support fallback-only as a setup
+	gnome2_src_configure \
+		--disable-deprecation-flags \
+		--disable-static \
+		--with-in-process-applets=clock,notification-area,wncklet \
+		--enable-telepathy-glib \
+		$(use_enable networkmanager network-manager) \
+		$(use_enable introspection) \
+		$(use_enable eds) \
+		ITSTOOL=$(type -P true)
+}