[kde-base] KDE SC 4.7.3

(Portage version: 2.2.0_alpha72/cvs/Linux x86_64)

2 files changed, 75 insertions, 1 deletions

diff --git a/kde-base/kwin/ChangeLog b/kde-base/kwin/ChangeLog
index 87414bc425c3..488eb3c4745a 100644
--- a/kde-base/kwin/ChangeLog
+++ b/kde-base/kwin/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for kde-base/kwin
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/kde-base/kwin/ChangeLog,v 1.250 2011/10/28 19:03:31 dilfridge Exp $
+# $Header: /var/cvsroot/gentoo-x86/kde-base/kwin/ChangeLog,v 1.251 2011/11/02 20:48:12 alexxy Exp $
+
+*kwin-4.7.3 (02 Nov 2011)
+
+  02 Nov 2011; Alexey Shvetsov <alexxy@gentoo.org> +kwin-4.7.3.ebuild:
+  Version bump KDE SC 4.7.3
 
   28 Oct 2011; Andreas K. Huettel <dilfridge@gentoo.org> -kwin-4.7.1-r1.ebuild:
   Drop KDEpim 4.6.1 and KDE 4.7.1
diff --git a/kde-base/kwin/kwin-4.7.3.ebuild b/kde-base/kwin/kwin-4.7.3.ebuild
new file mode 100644
index 000000000000..68a21562fc57
--- /dev/null
+++ b/kde-base/kwin/kwin-4.7.3.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/kde-base/kwin/kwin-4.7.3.ebuild,v 1.1 2011/11/02 20:48:12 alexxy Exp $
+
+EAPI=4
+
+KMNAME="kde-workspace"
+OPENGL_REQUIRED="optional"
+inherit kde4-meta
+
+DESCRIPTION="KDE window manager"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="debug gles xinerama"
+
+COMMONDEPEND="
+	$(add_kdebase_dep kephal)
+	$(add_kdebase_dep libkworkspace)
+	$(add_kdebase_dep liboxygenstyle)
+	x11-libs/libXcomposite
+	x11-libs/libXdamage
+	x11-libs/libXfixes
+	>=x11-libs/libXrandr-1.2.1
+	x11-libs/libXrender
+	opengl? ( >=media-libs/mesa-7.10 )
+	gles? (
+		|| (  ( >=media-libs/mesa-7.10[egl(+),gles] <media-libs/mesa-7.12[egl(+),gles] )
+			>=media-libs/mesa-7.12[egl(+),gles2] )
+	)
+	xinerama? ( x11-libs/libXinerama )
+"
+DEPEND="${COMMONDEPEND}
+	x11-proto/compositeproto
+	x11-proto/damageproto
+	x11-proto/fixesproto
+	x11-proto/randrproto
+	x11-proto/renderproto
+	xinerama? ( x11-proto/xineramaproto )
+"
+RDEPEND="${COMMONDEPEND}
+	x11-apps/scripts
+"
+
+KMEXTRACTONLY="
+	ksmserver/
+	libs/kephal/
+	libs/oxygen/
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-4.4.2-xinerama_cmake_automagic.patch"
+)
+
+# you can use just gles or opengl or none
+REQUIRED_USE="opengl? ( !gles ) gles? ( !opengl )"
+
+src_configure() {
+	# FIXME Remove when activity API moved away from libkworkspace
+	append-cppflags "-I${EPREFIX}/usr/include/kworkspace"
+
+	mycmakeargs=(
+		$(cmake-utils_use_with gles OpenGLES)
+		$(cmake-utils_use gles KWIN_BUILD_WITH_OPENGLES)
+		$(cmake-utils_use_with opengl OpenGL)
+		$(cmake-utils_use_with xinerama X11_Xinerama)
+		-DWITH_X11_Xcomposite=ON
+	)
+
+	kde4-meta_src_configure
+}