revbump; convert -> python-single-r1 and upgrade EAPI, consent by maintainer hwoarang

(Portage version: 2.2.14/cvs/Linux x86_64, signed Manifest commit with key 0xB8072B0D)

2 files changed, 97 insertions, 2 deletions

diff --git a/media-gfx/mypaint/ChangeLog b/media-gfx/mypaint/ChangeLog
index 36f248db92a0..4d460b1c0ad3 100644
--- a/media-gfx/mypaint/ChangeLog
+++ b/media-gfx/mypaint/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-gfx/mypaint
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/mypaint/ChangeLog,v 1.23 2013/10/11 21:07:13 hwoarang Exp $
+# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/mypaint/ChangeLog,v 1.24 2015/02/26 14:26:18 idella4 Exp $
+
+*mypaint-1.1.0-r2 (26 Feb 2015)
+
+  26 Feb 2015; Ian Delaney <idella4@gentoo.org> +mypaint-1.1.0-r2.ebuild:
+  revbump; convert -> python-single-r1 and upgrade EAPI, consent by maintainer
+  hwoarang
 
 *mypaint-1.1.0-r1 (11 Oct 2013)
 
diff --git a/media-gfx/mypaint/mypaint-1.1.0-r2.ebuild b/media-gfx/mypaint/mypaint-1.1.0-r2.ebuild
new file mode 100644
index 000000000000..a2db5af23b41
--- /dev/null
+++ b/media-gfx/mypaint/mypaint-1.1.0-r2.ebuild
@@ -0,0 +1,89 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/mypaint/mypaint-1.1.0-r2.ebuild,v 1.1 2015/02/26 14:26:18 idella4 Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 )
+
+inherit fdo-mime gnome2-utils multilib scons-utils toolchain-funcs python-single-r1
+
+DESCRIPTION="fast and easy graphics application for digital painters"
+HOMEPAGE="http://mypaint.intilinux.com/"
+SRC_URI="http://download.gna.org/${PN}/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+LANGS="cs de en_CA en_GB es fr hu id it ja ko nb nn_NO pl pt_BR ro ru sl sv uk zh_CN zh_TW"
+for x in ${LANGS}; do
+	IUSE+="linguas_${x} "
+done
+
+RDEPEND="
+	dev-python/pygtk:2[${PYTHON_USEDEP}]
+	dev-python/numpy[${PYTHON_USEDEP}]
+	>=dev-python/pycairo-1.4[${PYTHON_USEDEP}]
+	dev-libs/protobuf[python,${PYTHON_USEDEP}]
+	>=dev-libs/json-c-0.11:=
+	media-libs/lcms:2
+	media-libs/libpng:0=
+	${PYTHON_DEPS}
+"
+DEPEND="${RDEPEND}
+	dev-lang/swig
+	virtual/pkgconfig"
+
+REQUIRED_USE=${PYTHON_REQUIRED_USE}
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	# multilib support
+	sed -i -e "s:lib\/${PN}:$(get_libdir)\/${PN}:" \
+		SConstruct SConscript || die
+	# respect CXXFLAGS,CXX,LDFLAGS
+	epatch "${FILESDIR}"/${P}-build-env-vars.patch
+	# fix mypaint.desktop
+	epatch "${FILESDIR}"/${P}-desktop.patch
+	# pkgconfig patch for json-c-0.11. 467322
+	epatch "${FILESDIR}"/${P}-json-c-0.11.patch
+}
+
+src_compile() {
+	#workaround scons bug with locales. Bug #352700
+	export LANG="en_US.UTF-8"
+	tc-export CC CXX
+	escons
+}
+
+src_install () {
+	escons prefix="${D}/usr" install
+	newicon pixmaps/${PN}_logo.png ${PN}.png
+	for x in ${LANGS}; do
+		if ! has ${x} ${LINGUAS}; then
+			rm -rf "${ED}"/usr/share/locale/${x} || die
+		fi
+	done
+
+	python_optimize "${D}"usr/share/${PN}
+	# not used and broken
+	rm -rf "${ED}"/usr/{include/,lib/libmypaint.a,lib/pkgconfig/} || die
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	fdo-mime_desktop_database_update
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	fdo-mime_desktop_database_update
+}