Version bump wrt #448466 by "Coran", Iván Atienza and David Parrish

(Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key 4868F14D)

2 files changed, 73 insertions, 2 deletions

diff --git a/media-sound/gpodder/ChangeLog b/media-sound/gpodder/ChangeLog
index d2e9d81ce518..d3e481319280 100644
--- a/media-sound/gpodder/ChangeLog
+++ b/media-sound/gpodder/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-sound/gpodder
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/gpodder/ChangeLog,v 1.31 2013/05/28 06:33:08 ssuominen Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/gpodder/ChangeLog,v 1.32 2014/03/05 17:32:20 ssuominen Exp $
+
+*gpodder-3.6.0 (05 Mar 2014)
+
+  05 Mar 2014; Samuli Suominen <ssuominen@gentoo.org> +gpodder-3.6.0.ebuild:
+  Version bump wrt #448466 by "Coran", Iván Atienza and David Parrish
 
   28 May 2013; Samuli Suominen <ssuominen@gentoo.org> gpodder-3.2.0.ebuild:
   Punt unused dev-python/imaging dependency wrt #471570 by Arfrever Frehtes
diff --git a/media-sound/gpodder/gpodder-3.6.0.ebuild b/media-sound/gpodder/gpodder-3.6.0.ebuild
new file mode 100644
index 000000000000..44ccfc29672c
--- /dev/null
+++ b/media-sound/gpodder/gpodder-3.6.0.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/gpodder/gpodder-3.6.0.ebuild,v 1.1 2014/03/05 17:32:20 ssuominen Exp $
+
+EAPI=5
+PYTHON_COMPAT=( python2_7 )
+PYTHON_REQ_USE="sqlite"
+# Required for python_fix_shebang:
+DISTUTILS_SINGLE_IMPL=1
+
+inherit distutils-r1 gnome2-utils
+
+DESCRIPTION="A free cross-platform podcast aggregator"
+HOMEPAGE="http://gpodder.org/"
+SRC_URI="http://gpodder.org/src/${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux ~x86-solaris"
+IUSE="+dbus bluetooth gstreamer ipod mtp test webkit"
+
+#TODO: add QML UI deps (USE=qt4) and make pygtk optional, see README
+RDEPEND=">=dev-python/eyeD3-0.7
+	>=dev-python/feedparser-5.1.2
+	>=dev-python/mygpoclient-1.7
+	>=dev-python/pygtk-2.16:2
+	dbus? ( dev-python/dbus-python )
+	bluetooth? ( net-wireless/bluez )
+	gstreamer? ( dev-python/gst-python )
+	ipod? ( media-libs/libgpod[python] )
+	mtp? ( >=media-libs/libmtp-1.0.0 )
+	webkit? ( dev-python/pywebkitgtk )"
+DEPEND="${RDEPEND}
+	dev-util/intltool
+	sys-apps/help2man
+	test? (
+		dev-python/minimock
+		dev-python/coverage
+	)"
+
+src_prepare() {
+	sed -i -e '/setup.py.*install/d' makefile || die
+	# Fix for "AttributeError: 'gPodder' object has no attribute 'toolbar'":
+	python_fix_shebang .
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+	distutils-r1_src_install
+}
+
+src_test() {
+	emake releasetest
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+}