version bump for bug #527288

(Portage version: 2.2.15/cvs/Linux x86_64, signed Manifest commit with key 0x0F9C590B7FF324F6!)

2 files changed, 74 insertions, 1 deletions

diff --git a/media-sound/gpodder/ChangeLog b/media-sound/gpodder/ChangeLog
index 5e95a5bb0c98..f5351e5f40f8 100644
--- a/media-sound/gpodder/ChangeLog
+++ b/media-sound/gpodder/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-sound/gpodder
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/gpodder/ChangeLog,v 1.36 2014/07/26 12:17:12 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/gpodder/ChangeLog,v 1.37 2014/12/13 09:16:58 yngwin Exp $
+
+*gpodder-3.8.3 (13 Dec 2014)
+
+  13 Dec 2014; Ben de Groot <yngwin@gentoo.org> +gpodder-3.8.3.ebuild:
+  version bump for bug #527288
 
 *gpodder-3.7.0 (26 Jul 2014)
 
diff --git a/media-sound/gpodder/gpodder-3.8.3.ebuild b/media-sound/gpodder/gpodder-3.8.3.ebuild
new file mode 100644
index 000000000000..8c9b92a73e65
--- /dev/null
+++ b/media-sound/gpodder/gpodder-3.8.3.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/gpodder/gpodder-3.8.3.ebuild,v 1.1 2014/12/13 09:16:58 yngwin Exp $
+
+EAPI=5
+PYTHON_COMPAT=( python2_7 )
+PYTHON_REQ_USE="sqlite"
+# Required for python_fix_shebang:
+DISTUTILS_SINGLE_IMPL=1
+
+inherit distutils-r1 gnome2-utils
+
+DESCRIPTION="A free cross-platform podcast aggregator"
+HOMEPAGE="http://gpodder.org/"
+SRC_URI="http://gpodder.org/src/${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux ~x86-solaris"
+IUSE="+dbus bluetooth gstreamer ipod kernel_linux mtp test webkit"
+
+#TODO: add QML UI deps (USE=qt4) and make pygtk optional, see README
+COMMON_DEPEND=">=dev-python/eyeD3-0.7
+	>=dev-python/feedparser-5.1.2
+	>=dev-python/mygpoclient-1.7
+	>=dev-python/pygtk-2.16:2
+	dbus? ( dev-python/dbus-python )
+	bluetooth? ( net-wireless/bluez )
+	gstreamer? ( dev-python/gst-python:0.10 )
+	ipod? ( media-libs/libgpod[python] )
+	mtp? ( >=media-libs/libmtp-1.0.0 )
+	webkit? ( dev-python/pywebkitgtk )"
+RDEPEND="${COMMON_DEPEND}
+	kernel_linux? ( sys-apps/iproute2 )"
+DEPEND="${COMMON_DEPEND}
+	dev-util/intltool
+	sys-apps/help2man
+	test? (
+		dev-python/minimock
+		dev-python/coverage
+	)"
+
+src_prepare() {
+	sed -i -e '/setup.py.*install/d' makefile || die
+	# Fix for "AttributeError: 'gPodder' object has no attribute 'toolbar'":
+	python_fix_shebang .
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+	distutils-r1_src_install
+}
+
+src_test() {
+	emake releasetest
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+}