Port to autotools-utils eclass, revbump for last changes, drop old revision

(Portage version: 2.2.0_alpha161/cvs/Linux x86_64, signed Manifest commit with key 0x1F357D42)

3 files changed, 73 insertions, 48 deletions

diff --git a/media-sound/nted/ChangeLog b/media-sound/nted/ChangeLog
index 233f9874167d..7285ee0a6954 100644
--- a/media-sound/nted/ChangeLog
+++ b/media-sound/nted/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-sound/nted
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/nted/ChangeLog,v 1.36 2013/02/18 13:23:30 pinkbyte Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/nted/ChangeLog,v 1.37 2013/02/18 13:41:33 pinkbyte Exp $
+
+*nted-1.10.18-r3 (18 Feb 2013)
+
+  18 Feb 2013; Sergey Popov <pinkbyte@gentoo.org> -nted-1.10.18.ebuild,
+  +nted-1.10.18-r3.ebuild:
+  Port to autotools-utils eclass, revbump for last changes, drop old revision
 
   18 Feb 2013; Sergey Popov <pinkbyte@gentoo.org> nted-1.10.18-r2.ebuild:
   Fix desktop file, wrt bug #458080. Thanks to Agostino Sarubbo for discovering
diff --git a/media-sound/nted/nted-1.10.18-r3.ebuild b/media-sound/nted/nted-1.10.18-r3.ebuild
new file mode 100644
index 000000000000..cbdd6cd8bdea
--- /dev/null
+++ b/media-sound/nted/nted-1.10.18-r3.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/nted/nted-1.10.18-r3.ebuild,v 1.1 2013/02/18 13:41:33 pinkbyte Exp $
+
+EAPI=5
+
+AUTOTOOLS_AUTORECONF=1
+inherit autotools-utils eutils toolchain-funcs
+
+DESCRIPTION="WYSIWYG score editor for GTK+"
+HOMEPAGE="http://vsr.informatik.tu-chemnitz.de/staff/jan/nted/nted.xhtml"
+SRC_URI="http://vsr.informatik.tu-chemnitz.de/staff/jan/${PN}/sources/${P}.tar.gz"
+
+LICENSE="GPL-2 FDL-1.2 NTED_FONT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc debug nls"
+
+RDEPEND=">=dev-libs/glib-2
+	media-libs/alsa-lib
+	>=media-libs/freetype-2
+	x11-libs/cairo
+	>=x11-libs/gdk-pixbuf-2
+	x11-libs/gtk+:2
+	x11-libs/libX11
+	x11-libs/pango"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	doc? ( app-text/xmlto )
+	nls? ( sys-devel/gettext )"
+
+DOCS=( ABOUT_THE_EXAMPLES.TXT AUTHORS FAQ README )
+PATCHES=(
+	"${FILESDIR}/${P}-gcc47.patch" # bug #424291
+	"${FILESDIR}/${P}-lilypond.patch" # bug #437540
+	"${FILESDIR}/${P}-lilypond-tremolo.patch" # bug #437540
+)
+
+src_prepare() {
+	# fix desktop file, wrt bug #458080
+	sed -i \
+		-e 's/nted.png/nted/' \
+		-e '/^Categories/s/Application;//' \
+		datafiles/applications/nted.desktop || die 'sed on desktop file failed'
+	# drop -g from CXXFLAGS, wrt bug #458086
+	sed -i -e '/CXXFLAGS/s/ -g//' configure.in || die 'sed on configure.in failed'
+
+	autotools-utils_src_prepare
+}
+
+src_configure() {
+	# Trick ./configure to believe we have gnome-extra/yelp installed.
+	has_version gnome-extra/yelp || export ac_cv_path_YELP="$(type -P true)"
+
+	local myeconfargs=(
+		$(use_enable debug)
+		$(use_enable nls)
+		$(use_with doc)
+	)
+	autotools-utils_src_configure
+}
+
+src_compile() {
+	# respect AR, wrt bug #458084
+	autotools-utils_src_compile AR="$(tc-getAR)"
+}
diff --git a/media-sound/nted/nted-1.10.18.ebuild b/media-sound/nted/nted-1.10.18.ebuild
deleted file mode 100644
index 9cccbcc9993a..000000000000
--- a/media-sound/nted/nted-1.10.18.ebuild
+++ /dev/null
@@ -1,47 +0,0 @@
-# Copyright 1999-2012 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/nted/nted-1.10.18.ebuild,v 1.7 2012/07/12 19:08:53 hwoarang Exp $
-
-EAPI=4
-
-inherit eutils
-
-DESCRIPTION="WYSIWYG score editor for GTK+"
-HOMEPAGE="http://vsr.informatik.tu-chemnitz.de/staff/jan/nted/nted.xhtml"
-SRC_URI="http://vsr.informatik.tu-chemnitz.de/staff/jan/${PN}/sources/${P}.tar.gz"
-
-LICENSE="GPL-2 FDL-1.2 NTED_FONT"
-SLOT="0"
-KEYWORDS="amd64 x86"
-IUSE="doc debug nls"
-
-RDEPEND=">=dev-libs/glib-2
-	media-libs/alsa-lib
-	>=media-libs/freetype-2
-	x11-libs/cairo
-	>=x11-libs/gdk-pixbuf-2
-	x11-libs/gtk+:2
-	x11-libs/libX11
-	x11-libs/pango"
-DEPEND="${RDEPEND}
-	virtual/pkgconfig
-	doc? ( app-text/xmlto )
-	nls? ( sys-devel/gettext )"
-
-DOCS="ABOUT_THE_EXAMPLES.TXT AUTHORS FAQ README"
-
-src_prepare() {
-	# bug #424291
-	epatch "${FILESDIR}"/${P}-gcc47.patch
-}
-
-src_configure() {
-	# Trick ./configure to believe we have gnome-extra/yelp installed.
-	has_version gnome-extra/yelp || export ac_cv_path_YELP="$(type -P true)"
-
-	econf \
-		--docdir=/usr/share/doc/${PF} \
-		$(use_enable debug) \
-		$(use_enable nls) \
-		$(use_with doc)
-}