New version

(Portage version: 2.1.1_pre5-r1)

4 files changed, 189 insertions, 3 deletions

diff --git a/media-video/ffmpeg/ChangeLog b/media-video/ffmpeg/ChangeLog
index f7a2a05625f7..b192ce2812f4 100644
--- a/media-video/ffmpeg/ChangeLog
+++ b/media-video/ffmpeg/ChangeLog
@@ -1,6 +1,9 @@
 # ChangeLog for media-video/ffmpeg
 # Copyright 2002-2006 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/ffmpeg/ChangeLog,v 1.151 2006/08/14 13:29:29 lu_zero Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/ffmpeg/ChangeLog,v 1.152 2006/08/17 06:02:13 lu_zero Exp $
+
+  16 Aug 2006; Luca Barbato <lu_zero@gentoo.org> ChangeLog:
+  New version
 
   14 Aug 2006; Luca Barbato <lu_zero@gentoo.org>
   +files/ffmpeg-0.4.9_p20060530-snow-mmx.patch,
diff --git a/media-video/ffmpeg/ffmpeg-0.4.9_p20060530.ebuild b/media-video/ffmpeg/ffmpeg-0.4.9_p20060530.ebuild
index e785eb97617f..7916bf5a4502 100644
--- a/media-video/ffmpeg/ffmpeg-0.4.9_p20060530.ebuild
+++ b/media-video/ffmpeg/ffmpeg-0.4.9_p20060530.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2006 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/ffmpeg/ffmpeg-0.4.9_p20060530.ebuild,v 1.11 2006/08/14 13:29:29 lu_zero Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/ffmpeg/ffmpeg-0.4.9_p20060530.ebuild,v 1.12 2006/08/17 06:02:13 lu_zero Exp $
 
 inherit eutils flag-o-matic multilib toolchain-funcs
 
@@ -18,7 +18,7 @@ SRC_URI="mirror://gentoo/${MY_P}.tar.bz2
 
 LICENSE="GPL-2"
 SLOT="0"
-KEYWORDS="-* ~amd64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd" #~alpha ~arm ~hppa ~ia64 ~ppc ~ppc-macos ~ppc64 
+KEYWORDS="-* ~amd64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd" #~alpha ~arm ~hppa ~ia64 ~ppc ~ppc-macos ~ppc64
 IUSE="aac altivec amr debug doc ieee1394 a52 encode imlib mmx ogg vorbis oss
 	test theora threads truetype v4l x264 xvid dts network zlib sdl"
 
diff --git a/media-video/ffmpeg/ffmpeg-0.4.9_p20060816.ebuild b/media-video/ffmpeg/ffmpeg-0.4.9_p20060816.ebuild
new file mode 100644
index 000000000000..6845e1673c8e
--- /dev/null
+++ b/media-video/ffmpeg/ffmpeg-0.4.9_p20060816.ebuild
@@ -0,0 +1,174 @@
+# Copyright 1999-2006 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-video/ffmpeg/ffmpeg-0.4.9_p20060816.ebuild,v 1.1 2006/08/17 06:02:13 lu_zero Exp $
+
+inherit eutils flag-o-matic multilib toolchain-funcs
+
+DESCRIPTION="Complete solution to record, convert and stream audio and video. Includes libavcodec."
+HOMEPAGE="http://ffmpeg.sourceforge.net/"
+MY_P=${P/_/-}
+S=${WORKDIR}/ffmpeg
+
+SRC_URI="mirror://gentoo/${MY_P}.tar.bz2
+	amr? ( http://www.3gpp.org/ftp/Specs/archive/26_series/26.104/26104-510.zip
+	       http://www.3gpp.org/ftp/Specs/archive/26_series/26.204/26204-510.zip )"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="-* ~amd64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+IUSE="aac altivec amr debug doc ieee1394 a52 encode imlib mmx ogg vorbis oss
+	test theora threads truetype v4l x264 xvid dts network zlib sdl"
+
+DEPEND="imlib? ( media-libs/imlib2 )
+	truetype? ( >=media-libs/freetype-2 )
+	sdl? ( >=media-libs/libsdl-1.2.1 )
+	doc? ( app-text/texi2html )
+	encode? ( media-sound/lame )
+	ogg? ( media-libs/libogg )
+	vorbis? ( media-libs/libvorbis )
+	aac? ( media-libs/faad2 media-libs/faac )
+	a52? ( >=media-libs/a52dec-0.7.4-r4 )
+	xvid? ( >=media-libs/xvid-1.1.0 )
+	zlib? ( sys-libs/zlib )
+	dts? ( media-libs/libdts )
+	ieee1394? ( =media-libs/libdc1394-1*
+	            sys-libs/libraw1394 )
+	test? ( net-misc/wget )
+	x264? ( >=media-libs/x264-svn-20060810 )
+	amr? ( app-arch/unzip )"
+
+src_unpack() {
+	unpack ${A} || die
+	cd ${S}
+
+	# amr (float) support
+	if use amr; then
+		einfo "Including amr wide and narrow band (float) support ... "
+
+		# narrow band codec
+		mkdir ${S}/libavcodec/amr_float
+		cd ${S}/libavcodec/amr_float
+		unzip -q ${WORKDIR}/26104-510_ANSI_C_source_code.zip
+
+		# wide band codec
+		mkdir ${S}/libavcodec/amrwb_float
+		cd ${S}/libavcodec/amrwb_float
+		unzip -q ${WORKDIR}/26204-510_ANSI-C_source_code.zip
+
+		# Patch if we're on 64-bit
+		if useq alpha || useq amd64 || useq ia64 || useq ppc64; then
+			cd ${S}
+			epatch "${FILESDIR}/ffmpeg-0.4.9_p20060302-amr-64bit.patch"
+		fi
+	fi
+
+	cd ${S}
+
+	#Append -fomit-frame-pointer to avoid some common issues
+	use debug || append-flags "-fomit-frame-pointer"
+
+	# for some reason it tries to #include <X11/Xlib.h>, but doesn't use it
+	sed -i s:\#define\ HAVE_X11:\#define\ HAVE_LINUX: ffplay.c
+
+	# .pc files contain wrong libdir path
+	epatch ${FILESDIR}/${PN}-libdir.patch
+	sed -i -e "s:GENTOOLIBDIR:$(get_libdir):" configure
+
+	# Make it use pic always since we don't need textrels
+	sed -i -e "s:LIBOBJFLAGS=\"\":LIBOBJFLAGS=\'\$\(PIC\)\':" configure
+
+	# To make sure the ffserver test will work
+	sed -i -e "s:-e debug=off::" tests/server-regression.sh
+
+	epatch "${FILESDIR}/${PN}-shared-gcc4.1.patch"
+}
+
+src_compile() {
+	replace-flags -O0 -O2
+
+	local myconf=""
+
+	#disable mmx accelerated code if not requested, or if PIC is required
+	# as the provided asm decidedly is not PIC.
+	if ( gcc-specs-pie || ! use mmx ) && ( ! use amd64 ); then
+		myconf="${myconf} --disable-mmx"
+	fi
+
+	# enabled by default
+	use altivec || myconf="${myconf} --disable-altivec"
+	use debug || myconf="${myconf} --disable-debug"
+	use oss || myconf="${myconf} --disable-audio-oss"
+	use v4l || myconf="${myconf} --disable-v4l --disable-v4l2"
+	use ieee1394 || myconf="${myconf} --disable-dv1394"
+	use network || myconf="${myconf} --disable-network"
+	use zlib || myconf="${myconf} --disable-zlib"
+	use sdl || myconf="${myconf} --disable-ffplay"
+
+	myconf="${myconf} --disable-opts"
+
+	# disabled by default
+	use encode && myconf="${myconf} --enable-mp3lame"
+	use a52 && myconf="${myconf} --enable-a52"
+	use ieee1394 && myconf="${myconf} --enable-dc1394"
+	use threads && myconf="${myconf} --enable-pthreads"
+	use xvid && myconf="${myconf} --enable-xvid"
+	if use vorbis
+	then
+		myconf="${myconf} --enable-vorbis --enable-libogg"
+	else
+		use ogg && myconf="${myconf} --enable-libogg"
+	fi
+	use dts && myconf="${myconf} --enable-dts"
+	use x264 && myconf="${myconf} --enable-x264"
+	use aac && myconf="${myconf} --enable-faad --enable-faac"
+	use amr && myconf="${myconf} --enable-amr_nb --enable-amr_wb"
+
+	myconf="${myconf} --enable-gpl --enable-pp --disable-strip"
+
+	# Specific workarounds for too-few-registers arch...
+	if [[ $(tc-arch) == "x86" ]]; then
+		filter-flags -fforce-addr -momit-leaf-frame-pointer
+		append-flags -fomit-frame-pointer
+		is-flag -O? || append-flags -O2
+		if (use debug); then
+			# no need to warn about debug if not using debug flag
+			ewarn ""
+			ewarn "Debug information will be almost useless as the frame pointer is omitted."
+			ewarn "This makes debugging harder, so crashes that has no fixed behavior are"
+			ewarn "difficult to fix. Please have that in mind."
+			ewarn ""
+		fi
+	fi
+
+	cd ${S}
+	./configure \
+		--prefix=/usr \
+		--mandir=/usr/share/man \
+		--enable-static --enable-shared \
+		"--cc=$(tc-getCC)" \
+		${myconf} || die "configure failed"
+
+	emake || die "make failed"
+}
+
+src_install() {
+	emake -j1 DESTDIR=${D} install || die "Install Failed"
+
+	use doc && make documentation
+	dodoc ChangeLog README INSTALL
+	dodoc doc/*
+}
+
+# Never die for now...
+src_test() {
+	cd ${S}/tests
+	for t in "codectest libavtest test-server" ; do
+		make ${t} || ewarn "Some tests in ${t} failed"
+	done
+}
+
+pkg_postinst() {
+	ewarn "ffmpeg may had ABI changes, if ffmpeg based programs"
+	ewarn "like xine-lib or vlc stop working as expected please"
+	ewarn "rebuild them."
+}
diff --git a/media-video/ffmpeg/files/digest-ffmpeg-0.4.9_p20060816 b/media-video/ffmpeg/files/digest-ffmpeg-0.4.9_p20060816
new file mode 100644
index 000000000000..683cb87a3dd3
--- /dev/null
+++ b/media-video/ffmpeg/files/digest-ffmpeg-0.4.9_p20060816
@@ -0,0 +1,9 @@
+MD5 9b575d01f94f50dd4dcf570cd8a14dda 26104-510.zip 291836
+RMD160 0ff97a27fe5d08dd43571fd1982ce0f07bce3bca 26104-510.zip 291836
+SHA256 75fdf6416950c155ccbfd7fae4ffd6529f162ad6b427ab242c3e00685e303f46 26104-510.zip 291836
+MD5 607a14d090898ffb0f72c1aa6aa6ce31 26204-510.zip 246663
+RMD160 1b68232bc40d84298b134c57697e29a842e63ffd 26204-510.zip 246663
+SHA256 069ebd6ed8ef846d99bdd13d6c47fdb99fe5583b0ed5f405e1392a1a21a1b991 26204-510.zip 246663
+MD5 7c1f20b488b4ca14b88b6e0a3484db3c ffmpeg-0.4.9-p20060816.tar.bz2 1948118
+RMD160 eb8e076f75c32b7a4874009451c7cb67c32f2fc2 ffmpeg-0.4.9-p20060816.tar.bz2 1948118
+SHA256 20e397ed778e23ae6eebe17d7b91839591512a3146629a2fcc68e0729b2b03bb ffmpeg-0.4.9-p20060816.tar.bz2 1948118