Bringing mplayer png usecheck up to pkg_setup, adding mplayer srt usecheck

to fix bug 235183. Adjusting description. Dropping old ~arch revisions.
(Portage version: 2.2_rc8/cvs/Linux 2.6.26-hh1 i686, RepoMan options: --force)

4 files changed, 161 insertions, 29 deletions

diff --git a/media-video/smplayer/ChangeLog b/media-video/smplayer/ChangeLog
index 50a3b18140ff..8dc0b2e6e298 100644
--- a/media-video/smplayer/ChangeLog
+++ b/media-video/smplayer/ChangeLog
@@ -1,13 +1,23 @@
 # ChangeLog for media-video/smplayer
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/smplayer/ChangeLog,v 1.29 2008/08/16 13:38:41 yngwin Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/smplayer/ChangeLog,v 1.30 2008/09/03 20:42:34 yngwin Exp $
+
+*smplayer-0.6.2-r1 (03 Sep 2008)
+*smplayer-0.6.1-r1 (03 Sep 2008)
+*smplayer-0.6.0-r1 (03 Sep 2008)
+
+  03 Sep 2008; Ben de Groot <yngwin@gentoo.org> +smplayer-0.6.0-r1.ebuild,
+  -smplayer-0.6.1.ebuild, +smplayer-0.6.1-r1.ebuild, -smplayer-0.6.2.ebuild,
+  +smplayer-0.6.2-r1.ebuild:
+  Bringing mplayer png usecheck up to pkg_setup, adding mplayer srt usecheck
+  to fix bug 235183. Adjusting description. Dropping old ~arch revisions.
 
 *smplayer-0.6.2 (16 Aug 2008)
 
   16 Aug 2008; Ben de Groot <yngwin@gentoo.org> -smplayer-0.6.0_rc3.ebuild,
   -smplayer-0.6.0_rc4.ebuild, +smplayer-0.6.2.ebuild:
   Version bump. Dropping qt3support check, as this is no longer needed
-  according to upstream (hopefully it's really true this time). 
+  according to upstream (hopefully it's really true this time).
   Dropping old RCs.
 
   16 Jun 2008; Ben de Groot <yngwin@gentoo.org> smplayer-0.6.0.ebuild,
@@ -100,7 +110,7 @@
   19 Feb 2008; Ben de Groot <yngwin@gentoo.org>
   -smplayer-0.5.62.ebuild, -smplayer-0.6.0_rc1.ebuild,
   smplayer-0.6.0_rc2.ebuild:
-  Removing old versions. Updating current ebuild with warning about 
+  Removing old versions. Updating current ebuild with warning about
   mplayer png support, fixes #209521.
 
 *smplayer-0.6.0_rc2 (17 Feb 2008)
diff --git a/media-video/smplayer/smplayer-0.6.0-r1.ebuild b/media-video/smplayer/smplayer-0.6.0-r1.ebuild
new file mode 100644
index 000000000000..2a9e73d94a73
--- /dev/null
+++ b/media-video/smplayer/smplayer-0.6.0-r1.ebuild
@@ -0,0 +1,108 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-video/smplayer/smplayer-0.6.0-r1.ebuild,v 1.1 2008/09/03 20:42:34 yngwin Exp $
+
+EAPI="1"
+inherit eutils qt4
+
+MY_P="${P}final"
+DESCRIPTION="Great Qt4 GUI front-end for mplayer"
+HOMEPAGE="http://smplayer.sourceforge.net"
+SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.bz2"
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="alpha amd64 hppa ppc ppc64 sparc x86 ~x86-fbsd"
+IUSE=""
+DEPEND="|| ( x11-libs/qt-gui:4
+			>=x11-libs/qt-4.3:4 )"
+RDEPEND="${DEPEND}
+	>media-video/mplayer-1.0_rc1"
+
+LANGS="bg cs de en_US es eu fi fr hu it ja ka ko mk nl pl pt_BR pt_PT sk sr sv tr zh_CN zh_TW"
+NOLONGLANGS="el_GR ro_RO ru_RU uk_UA"
+for X in ${LANGS}; do
+	IUSE="${IUSE} linguas_${X}"
+done
+for X in ${NOLONGLANGS}; do
+	IUSE="${IUSE} linguas_${X%_*}"
+done
+
+S=${WORKDIR}/${MY_P}
+
+pkg_setup() {
+	if has_version ">=x11-libs/qt-4.3:4"; then
+		QT4_BUILT_WITH_USE_CHECK="qt3support"
+	else
+		if ! built_with_use "x11-libs/qt-gui:4" qt3support; then
+			eerror "You have to built x11-libs/qt-gui:4 with qt3support."
+			die "qt3support in qt-gui disabled"
+		fi
+	fi
+	qt4_pkg_setup
+
+	if ! built_with_use media-video/mplayer srt ; then
+		echo
+		ewarn "SMPlayer needs MPlayer to be built with USE=srt for subtitle"
+		ewarn "support. Please enable the srt USE flag for mplayer and"
+		ewarn "re-emerge media-video/mplayer before emerging smplayer."
+		echo
+		die "media-video/mplayer needs USE=srt enabled"
+	fi
+	if ! built_with_use media-video/mplayer png; then
+		echo
+		ewarn "SMPlayer needs MPlayer built with USE=png for screenshot support."
+		ewarn "Please enable the png USE flag for mplayer and re-emerge"
+		ewarn "media-video/mplayer before emergeing smplayer."
+		echo
+		die "media-video/mplayer needs USE=png enabled"
+	fi
+}
+
+src_compile() {
+	local MY_SVNREV="1247"
+	echo "SVN-r${MY_SVNREV}" > svn_revision.txt
+	echo "#define SVN_REVISION \"SVN-r${MY_SVNREV}\"" > src/svn_revision.h
+
+	# Fix paths in Makefile and allow parallel building
+	sed -i -e "/^PREFIX=/s:/usr/local:/usr:" \
+		-e "/^CONF_PREFIX=/s:\$(PREFIX)::" \
+		-e "/^DOC_PATH=/s:packages/smplayer:${PF}:" \
+		-e '/get_svn_revision.sh/,+2c\
+	cd src && $(DEFS) $(MAKE)' \
+		"${S}"/Makefile || die "sed failed"
+
+	eqmake4 src/${PN}.pro -o src/Makefile
+	emake || die "emake failed"
+
+	# Generate translations
+	cd "${S}"/src/translations
+	local LANG=
+	for LANG in ${LINGUAS}; do
+		if has ${LANG} ${LANGS}; then
+			einfo "Generating ${LANG} translation ..."
+			lrelease ${PN}_${LANG}.ts || die "Failed to generate ${LANG} translation!"
+			continue
+		elif [[ " ${NOLONGLANGS} " == *" ${LANG}_"* ]]; then
+			local X=
+			for X in ${NOLONGLANGS}; do
+				if [[ "${LANG}" == "${X%_*}" ]]; then
+					einfo "Generating ${X} translation ..."
+					lrelease ${PN}_${X}.ts || die "Failed to generate ${X} translation!"
+					continue 2
+				fi
+			done
+		fi
+		ewarn "Sorry, but ${PN} does not support the ${LANG} LINGUA."
+	done
+}
+
+src_install() {
+	# remove unneeded copies of GPL
+	rm Copying.txt docs/en/gpl.html docs/ru/gpl.html
+	for i in de es ja ro ; do
+		rm -rf docs/$i
+	done
+
+	emake DESTDIR="${D}" install || die "emake install failed"
+	prepalldocs
+}
diff --git a/media-video/smplayer/smplayer-0.6.1.ebuild b/media-video/smplayer/smplayer-0.6.1-r1.ebuild
index c884628c7709..7895cba452ae 100644
--- a/media-video/smplayer/smplayer-0.6.1.ebuild
+++ b/media-video/smplayer/smplayer-0.6.1-r1.ebuild
@@ -1,11 +1,11 @@
 # Copyright 1999-2008 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/smplayer/smplayer-0.6.1.ebuild,v 1.2 2008/06/16 19:24:19 yngwin Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/smplayer/smplayer-0.6.1-r1.ebuild,v 1.1 2008/09/03 20:42:34 yngwin Exp $
 
 EAPI="1"
 inherit eutils qt4
 
-DESCRIPTION="Great front-end for mplayer written in Qt4"
+DESCRIPTION="Great Qt4 GUI front-end for mplayer"
 HOMEPAGE="http://smplayer.sourceforge.net"
 SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"
 LICENSE="GPL-2"
@@ -36,6 +36,23 @@ pkg_setup() {
 		fi
 	fi
 	qt4_pkg_setup
+
+	if ! built_with_use media-video/mplayer srt ; then
+		echo
+		ewarn "SMPlayer needs MPlayer to be built with USE=srt for subtitle"
+		ewarn "support. Please enable the srt USE flag for mplayer and"
+		ewarn "re-emerge media-video/mplayer before emerging smplayer."
+		echo
+		die "media-video/mplayer needs USE=srt enabled"
+	fi
+	if ! built_with_use media-video/mplayer png; then
+		echo
+		ewarn "SMPlayer needs MPlayer built with USE=png for screenshot support."
+		ewarn "Please enable the png USE flag for mplayer and re-emerge"
+		ewarn "media-video/mplayer before emergeing smplayer."
+		echo
+		die "media-video/mplayer needs USE=png enabled"
+	fi
 }
 
 src_compile() {
@@ -86,14 +103,3 @@ src_install() {
 	emake DESTDIR="${D}" install || die "emake install failed"
 	prepalldocs
 }
-
-pkg_postinst() {
-	if ! built_with_use media-video/mplayer png; then
-		echo
-		ewarn "SMPlayer needs the media-video/mplayer package built with USE=png."
-		ewarn "To prevent crashes, please rebuild mplayer with png support, or"
-		ewarn "alternatively, clear the Folder for storing screenshots field in"
-		ewarn "the Preferences dialog."
-		echo
-	fi
-}
diff --git a/media-video/smplayer/smplayer-0.6.2.ebuild b/media-video/smplayer/smplayer-0.6.2-r1.ebuild
index ea8544049ab9..9c1f96f98a14 100644
--- a/media-video/smplayer/smplayer-0.6.2.ebuild
+++ b/media-video/smplayer/smplayer-0.6.2-r1.ebuild
@@ -1,11 +1,11 @@
 # Copyright 1999-2008 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/smplayer/smplayer-0.6.2.ebuild,v 1.1 2008/08/16 13:38:41 yngwin Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/smplayer/smplayer-0.6.2-r1.ebuild,v 1.1 2008/09/03 20:42:34 yngwin Exp $
 
 EAPI="1"
 inherit eutils qt4
 
-DESCRIPTION="Great front-end for mplayer written in Qt4"
+DESCRIPTION="Great Qt4 GUI front-end for mplayer"
 HOMEPAGE="http://smplayer.sourceforge.net"
 SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"
 LICENSE="GPL-2"
@@ -26,6 +26,25 @@ for X in ${NOLONGLANGS}; do
 	IUSE="${IUSE} linguas_${X%_*}"
 done
 
+pkg_setup() {
+	if ! built_with_use media-video/mplayer srt ; then
+		echo
+		ewarn "SMPlayer needs MPlayer to be built with USE=srt for subtitle"
+		ewarn "support. Please enable the srt USE flag for mplayer and"
+		ewarn "re-emerge media-video/mplayer before emerging smplayer."
+		echo
+		die "media-video/mplayer needs USE=srt enabled"
+	fi
+	if ! built_with_use media-video/mplayer png; then
+		echo
+		ewarn "SMPlayer needs MPlayer built with USE=png for screenshot support."
+		ewarn "Please enable the png USE flag for mplayer and re-emerge"
+		ewarn "media-video/mplayer before emergeing smplayer."
+		echo
+		die "media-video/mplayer needs USE=png enabled"
+	fi
+}
+
 src_compile() {
 	local MY_SVNREV="1661"
 	echo "SVN-r${MY_SVNREV}" > svn_revision.txt
@@ -77,14 +96,3 @@ src_install() {
 	emake DESTDIR="${D}" install || die "emake install failed"
 	prepalldocs
 }
-
-pkg_postinst() {
-	if ! built_with_use media-video/mplayer png; then
-		echo
-		ewarn "SMPlayer needs the media-video/mplayer package built with USE=png."
-		ewarn "To prevent crashes, please rebuild mplayer with png support, or"
-		ewarn "alternatively, clear the Folder for storing screenshots field in"
-		ewarn "the Preferences dialog."
-		echo
-	fi
-}