Version bump.

(Portage version: 2.2.0_alpha121/cvs/Linux x86_64)

1 files changed, 58 insertions, 0 deletions

diff --git a/net-analyzer/pmacct/pmacct-0.14.1.ebuild b/net-analyzer/pmacct/pmacct-0.14.1.ebuild
new file mode 100644
index 000000000000..3d48e13c4f02
--- /dev/null
+++ b/net-analyzer/pmacct/pmacct-0.14.1.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-analyzer/pmacct/pmacct-0.14.1.ebuild,v 1.1 2012/08/23 03:18:17 jer Exp $
+
+EAPI=4
+inherit eutils toolchain-funcs
+
+DESCRIPTION="A network tool to gather IP traffic information"
+HOMEPAGE="http://www.pmacct.net/"
+SRC_URI="http://www.pmacct.net/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="64bit debug ipv6 mysql postgres sqlite threads ulog"
+
+RDEPEND="net-libs/libpcap
+	mysql? ( virtual/mysql )
+	postgres? ( dev-db/postgresql-base )
+	sqlite? ( =dev-db/sqlite-3* )"
+DEPEND="${RDEPEND}"
+DOCS=(
+	CONFIG-KEYS ChangeLog FAQS KNOWN-BUGS README TODO TOOLS UPGRADE
+	docs/INTERNALS docs/PLUGINS docs/SIGNALS
+)
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-0.12.0-gentoo.patch
+}
+
+src_configure() {
+	tc-export CC
+	econf \
+		$(use_enable 64bit) \
+		$(use_enable debug) \
+		$(use_enable ipv6) \
+		$(use_enable mysql) \
+		$(use_enable postgres pgsql) \
+		$(use_enable sqlite sqlite3) \
+		$(use_enable threads) \
+		$(use_enable ulog) \
+		|| die "econf failed"
+}
+
+src_install() {
+	default
+
+	for dirname in examples sql; do
+		docinto ${dirname}
+		dodoc ${dirname}/*
+	done
+
+	newinitd "${FILESDIR}"/pmacctd-init.d pmacctd
+	newconfd "${FILESDIR}"/pmacctd-conf.d pmacctd
+
+	insinto /etc/pmacctd
+	newins examples/pmacctd-imt.conf.example pmacctd.conf
+}