version bump as per bug #259018 thanks to Arfrever

(Portage version: 2.2_rc23/cvs/Linux x86_64)

2 files changed, 91 insertions, 1 deletions

diff --git a/net-libs/gnutls/ChangeLog b/net-libs/gnutls/ChangeLog
index 4f1fd0e97e1e..62faecc88859 100644
--- a/net-libs/gnutls/ChangeLog
+++ b/net-libs/gnutls/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for net-libs/gnutls
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-libs/gnutls/ChangeLog,v 1.179 2009/02/28 23:16:47 dragonheart Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-libs/gnutls/ChangeLog,v 1.180 2009/03/01 20:01:43 dragonheart Exp $
+
+*gnutls-2.6.4 (01 Mar 2009)
+
+  01 Mar 2009; Daniel Black <dragonheart@gentoo.org> +gnutls-2.6.4.ebuild:
+  version bump as per bug #259018  thanks to Arfrever
 
 *gnutls-2.7.6 (28 Feb 2009)
 
diff --git a/net-libs/gnutls/gnutls-2.6.4.ebuild b/net-libs/gnutls/gnutls-2.6.4.ebuild
new file mode 100644
index 000000000000..be882e3b31a6
--- /dev/null
+++ b/net-libs/gnutls/gnutls-2.6.4.ebuild
@@ -0,0 +1,85 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-libs/gnutls/gnutls-2.6.4.ebuild,v 1.1 2009/03/01 20:01:43 dragonheart Exp $
+
+EAPI="2"
+inherit eutils libtool autotools
+
+DESCRIPTION="A TLS 1.0 and SSL 3.0 implementation for the GNU project"
+HOMEPAGE="http://www.gnutls.org/"
+
+MINOR_VERSION="${PV#*.}"
+MINOR_VERSION="${MINOR_VERSION%.*}"
+if [[ $((MINOR_VERSION % 2)) == 0 ]] ; then
+	#SRC_URI="ftp://ftp.gnu.org/pub/gnu/${PN}/${P}.tar.bz2"
+	SRC_URI="mirror://gnu/${PN}/${P}.tar.bz2"
+else
+	SRC_URI="ftp://alpha.gnu.org/gnu/${PN}/${P}.tar.bz2"
+fi
+unset MINOR_VERSION
+
+# GPL-3 for the gnutls-extras library and LGPL for the gnutls library.
+LICENSE="LGPL-2.1 GPL-3"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~sparc-fbsd ~x86 ~x86-fbsd"
+IUSE="bindist +cxx doc guile lzo nls zlib"
+
+RDEPEND="dev-libs/libgpg-error
+	>=dev-libs/libgcrypt-1.4.0
+	>=dev-libs/libtasn1-0.3.4
+	nls? ( virtual/libintl )
+	guile? ( dev-scheme/guile[networking] )
+	zlib? ( >=sys-libs/zlib-1.1 )
+	!bindist? ( lzo? ( >=dev-libs/lzo-2 ) )"
+DEPEND="${RDEPEND}
+	sys-devel/libtool
+	doc? ( dev-util/gtk-doc )
+	nls? ( sys-devel/gettext )"
+
+pkg_setup() {
+	if use lzo && use bindist; then
+		ewarn "lzo support was disabled for binary distribution of gnutls"
+		ewarn "due to licensing issues. See Bug 202381 for details."
+		epause 5
+	fi
+}
+
+src_prepare() {
+	for dir in m4 lib/m4 libextra/m4 ; do
+		rm -f ${dir}/lt* ${dir}/libtool.m4
+	done
+	find . -name ltmain.sh -exec rm {} \;
+
+	# the below patch is in 2.7.* as per
+	# https://savannah.gnu.org/support/?106542
+	epatch "${FILESDIR}"/gnutls-2.6.0-cxx-configure.in.patch
+	epatch "${FILESDIR}"/gnutls-2.6.0-openpgp-selftest.patch
+
+	eautoreconf
+
+	elibtoolize # for sane .so versioning on FreeBSD
+}
+
+src_configure() {
+	local myconf
+	use bindist && myconf="--without-lzo" || myconf="$(use_with lzo)"
+	econf  \
+		$(use_with zlib) \
+		$(use_enable nls) \
+		$(use_enable guile) \
+		$(use_enable cxx) \
+		$(use_enable doc gtk-doc) \
+		${myconf}
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "emake install failed"
+
+	dodoc AUTHORS ChangeLog NEWS README THANKS doc/TODO
+
+	if use doc ; then
+		dodoc doc/README.autoconf doc/tex/gnutls.ps
+		docinto examples
+		dodoc doc/examples/*.c
+	fi
+}