Version bump. Fixed gssapi switch

(Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key 0x981CA6FC)

4 files changed, 95 insertions, 5 deletions

diff --git a/net-libs/libssh/ChangeLog b/net-libs/libssh/ChangeLog
index bb35f034add9..bea714b0354f 100644
--- a/net-libs/libssh/ChangeLog
+++ b/net-libs/libssh/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for net-libs/libssh
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-libs/libssh/ChangeLog,v 1.97 2014/01/09 07:56:12 polynomial-c Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-libs/libssh/ChangeLog,v 1.98 2014/02/11 10:23:20 polynomial-c Exp $
+
+*libssh-0.6.1 (11 Feb 2014)
+
+  11 Feb 2014; Lars Wendler <polynomial-c@gentoo.org> libssh-0.6.0.ebuild,
+  +libssh-0.6.1.ebuild, metadata.xml:
+  Version bump. Fixed gssapi switch.
 
   09 Jan 2014; Lars Wendler <polynomial-c@gentoo.org>
   -libssh-0.6.0_rc3-r1.ebuild, libssh-0.6.0.ebuild,
diff --git a/net-libs/libssh/libssh-0.6.0.ebuild b/net-libs/libssh/libssh-0.6.0.ebuild
index 97545d3a6be9..4b30c9956cff 100644
--- a/net-libs/libssh/libssh-0.6.0.ebuild
+++ b/net-libs/libssh/libssh-0.6.0.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2014 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-libs/libssh/libssh-0.6.0.ebuild,v 1.2 2014/01/09 07:56:12 polynomial-c Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-libs/libssh/libssh-0.6.0.ebuild,v 1.3 2014/02/11 10:23:20 polynomial-c Exp $
 
 EAPI=5
 
@@ -14,14 +14,14 @@ SRC_URI="https://red.libssh.org/attachments/download/71/${MY_P}.tar.xz -> ${P}.t
 LICENSE="LGPL-2.1"
 KEYWORDS="~amd64 ~arm ~hppa ~x86 ~amd64-linux ~x86-linux"
 SLOT="0/4" # subslot = soname major version
-IUSE="debug doc examples gcrypt kerberos pcap +sftp ssh1 server static-libs test zlib"
+IUSE="debug doc examples gcrypt gssapi pcap +sftp ssh1 server static-libs test zlib"
 # Maintainer: check IUSE-defaults at DefineOptions.cmake
 
 RDEPEND="
 	zlib? ( >=sys-libs/zlib-1.2 )
 	!gcrypt? ( >=dev-libs/openssl-0.9.8 )
 	gcrypt? ( >=dev-libs/libgcrypt-1.5 )
-	kerberos? ( virtual/krb5 )
+	gssapi? ( virtual/krb5 )
 "
 DEPEND="${RDEPEND}
 	doc? ( app-doc/doxygen )
@@ -51,7 +51,7 @@ src_configure() {
 		$(cmake-utils_use_with debug DEBUG_CALLTRACE)
 		$(cmake-utils_use_with debug DEBUG_CRYPTO)
 		$(cmake-utils_use_with gcrypt)
-		$(cmake-utils_use_with kerberos gssapi)
+		$(cmake-utils_use_with gssapi)
 		$(cmake-utils_use_with pcap)
 		$(cmake-utils_use_with server)
 		$(cmake-utils_use_with sftp)
diff --git a/net-libs/libssh/libssh-0.6.1.ebuild b/net-libs/libssh/libssh-0.6.1.ebuild
new file mode 100644
index 000000000000..6734475eac2b
--- /dev/null
+++ b/net-libs/libssh/libssh-0.6.1.ebuild
@@ -0,0 +1,83 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-libs/libssh/libssh-0.6.1.ebuild,v 1.1 2014/02/11 10:23:20 polynomial-c Exp $
+
+EAPI=5
+
+MY_P=${PN}-${PV/_rc/rc}
+inherit eutils cmake-utils multilib
+
+DESCRIPTION="Access a working SSH implementation by means of a library"
+HOMEPAGE="http://www.libssh.org/"
+SRC_URI="https://red.libssh.org/attachments/download/81/${MY_P}.tar.xz -> ${P}.tar.xz"
+
+LICENSE="LGPL-2.1"
+KEYWORDS="~amd64 ~arm ~hppa ~x86 ~amd64-linux ~x86-linux"
+SLOT="0/4" # subslot = soname major version
+IUSE="debug doc examples gcrypt gssapi pcap +sftp ssh1 server static-libs test zlib"
+# Maintainer: check IUSE-defaults at DefineOptions.cmake
+
+RDEPEND="
+	zlib? ( >=sys-libs/zlib-1.2 )
+	!gcrypt? ( >=dev-libs/openssl-0.9.8 )
+	gcrypt? ( >=dev-libs/libgcrypt-1.5 )
+	gssapi? ( virtual/krb5 )
+"
+DEPEND="${RDEPEND}
+	doc? ( app-doc/doxygen )
+	test? ( dev-util/cmocka )
+"
+
+DOCS=( AUTHORS README ChangeLog )
+
+S=${WORKDIR}/${MY_P}
+
+PATCHES=(
+	"${FILESDIR}/${PN}-0.5.0-tests.patch"
+)
+
+src_prepare() {
+	# just install the examples do not compile them
+	sed -i \
+		-e '/add_subdirectory(examples)/s/^/#DONOTWANT/' \
+		CMakeLists.txt || die
+
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_with debug DEBUG_CALLTRACE)
+		$(cmake-utils_use_with debug DEBUG_CRYPTO)
+		$(cmake-utils_use_with gcrypt)
+		$(cmake-utils_use_with gssapi)
+		$(cmake-utils_use_with pcap)
+		$(cmake-utils_use_with server)
+		$(cmake-utils_use_with sftp)
+		$(cmake-utils_use_with ssh1)
+		$(cmake-utils_use_with static-libs STATIC_LIB)
+		$(cmake-utils_use_with test STATIC_LIB)
+		$(cmake-utils_use_with test TESTING)
+		$(cmake-utils_use_with zlib)
+	)
+
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	cmake-utils_src_compile
+	use doc && cmake-utils_src_compile doc
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	use doc && dohtml -r "${CMAKE_BUILD_DIR}"/doc/html/*
+
+	use static-libs || rm -f "${D}"/usr/$(get_libdir)/libssh{,_threads}.a
+
+	if use examples; then
+		docinto examples
+		dodoc examples/*.{c,h,cpp}
+	fi
+}
diff --git a/net-libs/libssh/metadata.xml b/net-libs/libssh/metadata.xml
index c2c255c6361d..962cf0114398 100644
--- a/net-libs/libssh/metadata.xml
+++ b/net-libs/libssh/metadata.xml
@@ -7,6 +7,7 @@
 <use>
   <flag name='gcrypt'>Prefer <pkg>dev-libs/libgcrypt</pkg> over
     <pkg>dev-libs/openssl</pkg> for encryption</flag>
+  <flag name='gssapi'>Enable gssapi support</flag>
   <flag name='pcap'>Build with PCAP output support</flag>
   <flag name='sftp'>Build with SFTP support</flag>
   <flag name='ssh1'>Build with SSH1 support</flag>