Minor version bump.

(Portage version: 2.2.12/cvs/Linux x86_64, signed Manifest commit with key EFB4464E!)

3 files changed, 84 insertions, 3 deletions

diff --git a/net-libs/ortp/ChangeLog b/net-libs/ortp/ChangeLog
index 0a6032da5a57..efa6af200295 100644
--- a/net-libs/ortp/ChangeLog
+++ b/net-libs/ortp/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for net-libs/ortp
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-libs/ortp/ChangeLog,v 1.85 2013/10/27 09:44:34 pacho Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/net-libs/ortp/ChangeLog,v 1.86 2014/09/13 16:32:22 mgorny Exp $
+
+*ortp-0.23.0 (13 Sep 2014)
+
+  13 Sep 2014; Michał Górny <mgorny@gentoo.org> +ortp-0.23.0.ebuild,
+  metadata.xml:
+  Minor version bump.
 
   27 Oct 2013; Pacho Ramos <pacho@gentoo.org> metadata.xml:
   Voip herd is removed: http://article.gmane.org/gmane.linux.gentoo.devel/88434
diff --git a/net-libs/ortp/metadata.xml b/net-libs/ortp/metadata.xml
index 5fd43a9170f5..caea1a2964c9 100644
--- a/net-libs/ortp/metadata.xml
+++ b/net-libs/ortp/metadata.xml
@@ -5,6 +5,6 @@
 	<use>
 		<flag name='ntp-timestamp'>Turn on NTP timestamping on received packet</flag>
 		<flag name='srtp'>Add support for Secure RTP</flag>
-		<!-- <flag name='zrtp'>Add support for ZRTP key negotiation</flag> -->
+		<flag name='zrtp'>Add support for ZRTP key negotiation</flag>
 	</use>
 </pkgmetadata>
diff --git a/net-libs/ortp/ortp-0.23.0.ebuild b/net-libs/ortp/ortp-0.23.0.ebuild
new file mode 100644
index 000000000000..059b9bfde04f
--- /dev/null
+++ b/net-libs/ortp/ortp-0.23.0.ebuild
@@ -0,0 +1,75 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-libs/ortp/ortp-0.23.0.ebuild,v 1.1 2014/09/13 16:32:22 mgorny Exp $
+
+EAPI=5
+
+inherit eutils
+
+DESCRIPTION="Open Real-time Transport Protocol (RTP, RFC3550) stack"
+HOMEPAGE="http://www.linphone.org/"
+SRC_URI="mirror://nongnu/linphone/${PN}/sources/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0/9"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~x86-fbsd ~ppc-macos ~x64-macos ~x86-macos"
+IUSE="debug doc examples ipv6 minimal ntp-timestamp ssl srtp zrtp"
+
+RDEPEND="ssl? ( dev-libs/openssl:0= )
+	srtp? ( net-libs/libsrtp:0= )
+	zrtp? ( >=net-libs/libzrtpcpp-4.0.0:0= )"
+DEPEND="${RDEPEND}
+	doc? ( app-doc/doxygen )
+	virtual/pkgconfig"
+
+REQUIRED_USE="zrtp? ( srtp )"
+
+src_prepare() {
+	# ${P} is added after ${docdir}
+	if use doc; then
+		sed -i -e 's/$(docdir)\/$(PACKAGE)-$(VERSION)/$(docdir)/' Makefile.in \
+			|| die "patching Makefile.in failed"
+	fi
+}
+
+src_configure() {
+	local myeconfargs=(
+		# memcheck is for HP-UX only
+		--disable-memcheck
+		# mode64bit adds +DA2.0W +DS2.0 CFLAGS wich are needed for HP-UX
+		--disable-mode64bit
+		# strict adds -Werror, do not want it
+		--disable-strict
+		# they seriously failed to understand AC_ARG_ENABLE...
+		--disable-tests_enabled
+		--enable-fast-install
+		--enable-libtool-lock
+		# this is fine as long as we do not link to polarssl
+		--enable-broken-srtp
+
+		$(use_enable debug)
+		$(use_enable ipv6)
+		$(use_enable minimal perf)
+		$(use_enable ntp-timestamp)
+		$(use_enable ssl ssl-hmac)
+		$(use_enable zrtp)
+
+		--with-srtp=$(usex srtp "${EPREFIX}"/usr none)
+		$(use doc || echo ac_cv_path_DOXYGEN=false)
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	emake DESTDIR="${D}" pkgdocdir="${EPREFIX}"/usr/share/doc/${PF} \
+		install
+	dodoc AUTHORS ChangeLog NEWS README TODO
+
+	prune_libtool_files
+
+	if use examples; then
+		insinto /usr/share/doc/${PF}/examples
+		doins src/tests/*.c
+	fi
+}