version bump wrt #486498

(Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key E73C35B3)

3 files changed, 90 insertions, 1 deletions

diff --git a/net-libs/ortp/ChangeLog b/net-libs/ortp/ChangeLog
index e37083617667..8c819f09099c 100644
--- a/net-libs/ortp/ChangeLog
+++ b/net-libs/ortp/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for net-libs/ortp
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-libs/ortp/ChangeLog,v 1.82 2013/04/02 20:56:52 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-libs/ortp/ChangeLog,v 1.83 2013/10/09 15:09:05 hasufell Exp $
+
+*ortp-0.22.0 (09 Oct 2013)
+
+  09 Oct 2013; Julian Ospald <hasufell@gentoo.org> +ortp-0.22.0.ebuild,
+  metadata.xml:
+  version bump wrt #486498
 
   02 Apr 2013; Agostino Sarubbo <ago@gentoo.org> ortp-0.20.0.ebuild:
   Stable for ppc64, wrt bug #462890
diff --git a/net-libs/ortp/metadata.xml b/net-libs/ortp/metadata.xml
index d54c696e5433..d98424b06d1c 100644
--- a/net-libs/ortp/metadata.xml
+++ b/net-libs/ortp/metadata.xml
@@ -3,6 +3,7 @@
 <pkgmetadata>
 	<herd>voip</herd>
 	<use>
+		<flag name='ntp-timestamp'>Turn on NTP timestamping on received packet</flag>
 		<flag name='srtp'>Add support for Secure RTP</flag>
 		<!-- <flag name='zrtp'>Add support for ZRTP key negotiation</flag> -->
 	</use>
diff --git a/net-libs/ortp/ortp-0.22.0.ebuild b/net-libs/ortp/ortp-0.22.0.ebuild
new file mode 100644
index 000000000000..2adcbaabe16c
--- /dev/null
+++ b/net-libs/ortp/ortp-0.22.0.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-libs/ortp/ortp-0.22.0.ebuild,v 1.1 2013/10/09 15:09:05 hasufell Exp $
+
+EAPI=5
+
+inherit eutils
+
+DESCRIPTION="Open Real-time Transport Protocol (RTP, RFC3550) stack"
+HOMEPAGE="http://www.linphone.org/"
+SRC_URI="mirror://nongnu/linphone/${PN}/sources/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~ppc-macos ~x64-macos ~x86-macos"
+IUSE="debug doc examples ipv6 minimal ntp-timestamp ssl" # srtp zrtp"
+
+# Note:
+# This package supposedly requires libzrtpcpp-2.0.0
+# but it is incompatible with its API...
+#
+# This package supposedly requires libsrtp
+# but it is incompatible with its API...
+
+RDEPEND="ssl? ( dev-libs/openssl )"
+#	srtp? ( net-libs/libsrtp )
+#	zrtp? ( >=net-libs/libzrtpcpp-2.0.0 )"
+DEPEND="${RDEPEND}
+	doc? ( app-doc/doxygen )
+	virtual/pkgconfig"
+
+#REQUIRED_USE="zrtp? ( srtp )"
+
+src_prepare() {
+	# ${P} is added after ${docdir}
+	if use doc; then
+		sed -i -e 's/$(docdir)\/$(PACKAGE)-$(VERSION)/$(docdir)/' Makefile.in \
+			|| die "patching Makefile.in failed"
+	fi
+}
+
+src_configure() {
+	local myeconfargs=(
+		# memcheck is for HP-UX only
+		--disable-memcheck
+		# mode64bit adds +DA2.0W +DS2.0 CFLAGS wich are needed for HP-UX
+		--disable-mode64bit
+		# strict adds -Werror, don't want it
+		--disable-strict
+		# they seriously failed to understand AC_ARG_ENABLE...
+		--disable-tests_enabled
+		--enable-fast-install
+		--enable-libtool-lock
+
+		$(use_enable debug)
+		$(use_enable ipv6)
+		$(use_enable minimal perf)
+		$(use_enable ntp-timestamp)
+		$(use_enable ssl ssl-hmac)
+#		$(use_enable zrtp)
+		--disable-zrtp
+
+#		"--with-srtp=$(usex srtp "${EPREFIX}"/usr none)"
+		--with-srtp=none
+		$(use doc || echo ac_cv_path_DOXYGEN=false)
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	emake DESTDIR="${D}" pkgdocdir="${EPREFIX}"/usr/share/doc/${PF} \
+		install
+	dodoc AUTHORS ChangeLog NEWS README TODO
+
+	prune_libtool_files
+
+	if use examples; then
+		insinto /usr/share/doc/${PF}/examples
+		doins src/tests/*.c
+	fi
+}