Version bump

(Portage version: 2.1.11.62/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)

2 files changed, 94 insertions, 1 deletions

diff --git a/net-misc/rygel/ChangeLog b/net-misc/rygel/ChangeLog
index 0792ed62e68b..1e0d85c71de9 100644
--- a/net-misc/rygel/ChangeLog
+++ b/net-misc/rygel/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for net-misc/rygel
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/rygel/ChangeLog,v 1.35 2013/03/31 18:13:55 eva Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/rygel/ChangeLog,v 1.36 2013/04/23 19:35:41 pacho Exp $
+
+*rygel-0.18.1 (23 Apr 2013)
+
+  23 Apr 2013; Pacho Ramos <pacho@gentoo.org> +rygel-0.18.1.ebuild:
+  Version bump
 
   31 Mar 2013; Gilles Dartiguelongue <eva@gentoo.org> rygel-0.18.0.ebuild:
   QA fixes.
diff --git a/net-misc/rygel/rygel-0.18.1.ebuild b/net-misc/rygel/rygel-0.18.1.ebuild
new file mode 100644
index 000000000000..bdd5766fc02c
--- /dev/null
+++ b/net-misc/rygel/rygel-0.18.1.ebuild
@@ -0,0 +1,88 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-misc/rygel/rygel-0.18.1.ebuild,v 1.1 2013/04/23 19:35:41 pacho Exp $
+
+EAPI="5"
+GCONF_DEBUG="no"
+GNOME2_LA_PUNT="yes"
+
+inherit gnome2 virtualx
+
+DESCRIPTION="Rygel is an open source UPnP/DLNA MediaServer"
+HOMEPAGE="http://live.gnome.org/Rygel"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="X nls +sqlite tracker test transcode"
+
+# The deps for tracker? and transcode? are just the earliest available
+# version at the time of writing this ebuild
+RDEPEND="
+	>=dev-libs/glib-2.32:2
+	>=dev-libs/libgee-0.8:0.8
+	>=dev-libs/libxml2-2.7:2
+	>=media-libs/gupnp-dlna-0.9.4:2.0
+	media-libs/gstreamer:1.0
+	media-libs/gst-plugins-base:1.0
+	>=net-libs/gssdp-0.13
+	>=net-libs/gupnp-0.19
+	>=net-libs/gupnp-av-0.11.4
+	>=net-libs/libsoup-2.34:2.4
+	>=sys-apps/util-linux-2.20
+	x11-misc/shared-mime-info
+	sqlite? (
+		>=dev-db/sqlite-3.5:3
+		dev-libs/libunistring
+	)
+	tracker? ( >=app-misc/tracker-0.14:= )
+	transcode? (
+		>=media-libs/gst-plugins-bad-0.10.14:0.10
+		>=media-plugins/gst-plugins-twolame-0.10.12:0.10
+		>=media-plugins/gst-plugins-ffmpeg-0.10.5:0.10
+	)
+	X? ( >=x11-libs/gtk+-2.90.3:3 )
+"
+DEPEND="${RDEPEND}
+	dev-util/gtk-doc-am
+	>=dev-util/intltool-0.40
+	sys-devel/gettext
+	virtual/pkgconfig
+"
+# Maintainer only
+#	>=dev-lang/vala-0.18
+#   dev-libs/libxslt
+
+src_prepare() {
+	# runs gst-plugins-scanner on run with triggers sandbox violation
+	# trying to open dri
+	sed -e 's/rygel-media-engine-test$(EXEEXT)//' \
+		-e 's/rygel-playbin-renderer-test$(EXEEXT)//' \
+		-i tests/Makefile.in || die
+
+	gnome2_src_prepare
+}
+
+src_configure() {
+	# We defined xsltproc because man pages are provided by upstream
+	# and we do not want to regenerate them automagically.
+	gnome2_src_configure \
+		XSLTPROC=$(type -P false) \
+		--disable-valadoc \
+		--enable-gst-launch-plugin \
+		--enable-mediathek-plugin \
+		--with-media-engine=gstreamer \
+		$(use_enable nls) \
+		$(use_enable sqlite media-export-plugin) \
+		$(use_enable test tests) \
+		$(use_enable tracker tracker-plugin) \
+		$(use_with X ui)
+}
+
+src_install() {
+	gnome2_src_install
+	# Autostart file is not placed correctly, bug #402745
+	insinto /etc/xdg/autostart
+	doins "${D}"/usr/share/applications/rygel.desktop
+	rm "${D}"/usr/share/applications/rygel.desktop
+}