Version bump.

(Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key 0BBEEA1FEA4843A4)

2 files changed, 82 insertions, 1 deletions

diff --git a/net-misc/flexget/ChangeLog b/net-misc/flexget/ChangeLog
index 8f806cc845bb..c217ce74217b 100644
--- a/net-misc/flexget/ChangeLog
+++ b/net-misc/flexget/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for net-misc/flexget
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/flexget/ChangeLog,v 1.60 2015/04/08 18:04:50 mgorny Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/flexget/ChangeLog,v 1.61 2015/05/31 04:29:37 floppym Exp $
+
+*flexget-1.2.315 (31 May 2015)
+
+  31 May 2015; Mike Gilbert <floppym@gentoo.org> +flexget-1.2.315.ebuild:
+  Version bump.
 
   08 Apr 2015; Michał Górny <mgorny@gentoo.org> flexget-1.2.141.ebuild:
   Drop old Python implementations
diff --git a/net-misc/flexget/flexget-1.2.315.ebuild b/net-misc/flexget/flexget-1.2.315.ebuild
new file mode 100644
index 000000000000..e8d7a4f617b1
--- /dev/null
+++ b/net-misc/flexget/flexget-1.2.315.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-misc/flexget/flexget-1.2.315.ebuild,v 1.1 2015/05/31 04:29:37 floppym Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 )
+
+inherit distutils-r1 eutils
+
+if [[ ${PV} != 9999 ]]; then
+	MY_P="FlexGet-${PV}"
+	SRC_URI="mirror://pypi/F/FlexGet/${MY_P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+else
+	inherit git-r3
+	EGIT_REPO_URI="git://github.com/Flexget/Flexget.git
+		https://github.com/Flexget/Flexget.git"
+fi
+
+DESCRIPTION="Multipurpose automation tool for content like torrents, nzbs, podcasts, comics"
+HOMEPAGE="http://flexget.com/"
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="test transmission"
+
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	>=dev-python/feedparser-5.1.3[${PYTHON_USEDEP}]
+	>=dev-python/sqlalchemy-0.7.5[${PYTHON_USEDEP}]
+	<dev-python/sqlalchemy-0.9.99
+	dev-python/pyyaml[${PYTHON_USEDEP}]
+	>=dev-python/beautifulsoup-4.1:4[${PYTHON_USEDEP}]
+	<dev-python/beautifulsoup-4.4:4[${PYTHON_USEDEP}]
+	!~dev-python/beautifulsoup-4.2.0
+	>=dev-python/html5lib-0.11[${PYTHON_USEDEP}]
+	dev-python/PyRSS2Gen[${PYTHON_USEDEP}]
+	dev-python/pynzb[${PYTHON_USEDEP}]
+	dev-python/progressbar[${PYTHON_USEDEP}]
+	dev-python/rpyc[${PYTHON_USEDEP}]
+	dev-python/jinja[${PYTHON_USEDEP}]
+	>=dev-python/requests-1.0[${PYTHON_USEDEP}]
+	<dev-python/requests-2.99[${PYTHON_USEDEP}]
+	>=dev-python/python-dateutil-2.1[${PYTHON_USEDEP}]
+	!~dev-python/python-dateutil-2.2
+	>=dev-python/jsonschema-2.0[${PYTHON_USEDEP}]
+	dev-python/python-tvrage[${PYTHON_USEDEP}]
+	dev-python/tmdb3[${PYTHON_USEDEP}]
+	dev-python/path-py[${PYTHON_USEDEP}]
+	>=dev-python/guessit-0.9.3[${PYTHON_USEDEP}]
+	dev-python/APScheduler[${PYTHON_USEDEP}]
+"
+RDEPEND="${DEPEND}
+	transmission? ( dev-python/transmissionrpc[${PYTHON_USEDEP}] )
+"
+DEPEND+=" test? ( dev-python/nose[${PYTHON_USEDEP}] )"
+
+if [[ ${PV} == 9999 ]]; then
+	DEPEND+=" dev-python/paver[${PYTHON_USEDEP}]"
+else
+	S="${WORKDIR}/${MY_P}"
+fi
+
+python_prepare_all() {
+	# Prevent setup from grabbing nose from pypi
+	sed -e /setup_requires/d -i pavement.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	cp -lr tests setup.cfg "${BUILD_DIR}" || die
+	run_in_build_dir nosetests -v --attr=!online > "${T}/tests-${EPYTHON}.log" \
+		|| die "Tests fail with ${EPYTHON}"
+}