New snapshot of NM stable tree (0.7.1)

New snapshot of NM dev tree (0.8)
(Portage version: 2.1.6.13/cvs/Linux x86_64)

3 files changed, 269 insertions, 1 deletions

diff --git a/net-misc/networkmanager/ChangeLog b/net-misc/networkmanager/ChangeLog
index db204fe1ce8d..f99f6a4f55d4 100644
--- a/net-misc/networkmanager/ChangeLog
+++ b/net-misc/networkmanager/ChangeLog
@@ -1,6 +1,15 @@
 # ChangeLog for net-misc/networkmanager
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/networkmanager/ChangeLog,v 1.50 2009/07/12 14:43:32 rbu Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/networkmanager/ChangeLog,v 1.51 2009/08/24 13:11:44 dagger Exp $
+
+*networkmanager-0.8.0_pre20090824 (24 Aug 2009)
+*networkmanager-0.7.1_p20090824 (24 Aug 2009)
+
+  24 Aug 2009; Robert Piasek <dagger@gentoo.org>
+  +networkmanager-0.7.1_p20090824.ebuild,
+  +networkmanager-0.8.0_pre20090824.ebuild:
+  New stable snapshot of NetworkManager (0.7.1)
+  New dev snapshot of NetworkManager (0.8)
 
   12 Jul 2009; Robert Buchholz <rbu@gentoo.org>
   networkmanager-0.7.1-r3.ebuild, networkmanager-0.7.1-r6.ebuild:
diff --git a/net-misc/networkmanager/networkmanager-0.7.1_p20090824.ebuild b/net-misc/networkmanager/networkmanager-0.7.1_p20090824.ebuild
new file mode 100644
index 000000000000..5263cd9960c6
--- /dev/null
+++ b/net-misc/networkmanager/networkmanager-0.7.1_p20090824.ebuild
@@ -0,0 +1,135 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-misc/networkmanager/networkmanager-0.7.1_p20090824.ebuild,v 1.1 2009/08/24 13:11:44 dagger Exp $
+
+EAPI="2"
+inherit eutils
+# autotools
+
+#PATCH_VERSION="1b"
+
+# NetworkManager likes itself with capital letters
+MY_PN=${PN/networkmanager/NetworkManager}
+MY_P=${MY_PN}-${PV}
+
+#PATCHNAME="${MY_P}-gentoo-patches-${PATCH_VERSION}"
+
+DESCRIPTION="Network configuration and management in an easy way. Desktop environment independent."
+HOMEPAGE="http://www.gnome.org/projects/NetworkManager/"
+SRC_URI="http://dev.gentoo.org/~dagger/files/${MY_P}.tar.bz2"
+#	http://dev.gentoo.org/~dagger/files/${PATCHNAME}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~arm ~amd64 ~ppc ~x86"
+IUSE="avahi doc nss gnutls dhclient dhcpcd resolvconf connection-sharing"
+# modemmanager"
+
+RDEPEND=">=sys-apps/dbus-1.2
+	>=dev-libs/dbus-glib-0.75
+	>=sys-apps/hal-0.5.10
+	>=net-wireless/wireless-tools-28_pre9
+	>=dev-libs/glib-2.16
+	<sys-auth/policykit-0.92
+	>=dev-libs/libnl-1.1
+	>=net-wireless/wpa_supplicant-0.5.10[dbus]
+	|| ( sys-libs/e2fsprogs-libs <sys-fs/e2fsprogs-1.41.0 )
+	avahi? ( net-dns/avahi[autoipd] )
+	gnutls? (
+		nss? ( >=dev-libs/nss-3.11 )
+		!nss? ( dev-libs/libgcrypt
+			net-libs/gnutls ) )
+	!gnutls? ( >=dev-libs/nss-3.11 )
+	dhclient? (
+		dhcpcd? ( >=net-misc/dhcpcd-4.0.0_rc3 )
+		!dhcpcd? ( >=net-misc/dhcp-3.0.0 ) )
+	!dhclient? ( >=net-misc/dhcpcd-4.0.0_rc3 )
+	resolvconf? ( net-dns/openresolv )
+	connection-sharing? (
+		net-dns/dnsmasq
+		net-firewall/iptables )"
+
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig
+	dev-util/intltool
+	net-dialup/ppp
+	doc? ( >=dev-util/gtk-doc-1.8 )"
+
+#PDEPEND="modemmanager? ( >=net-misc/modemmanager-0.2 )"
+
+S=${WORKDIR}/${MY_P}
+
+src_prepare() {
+
+	# Fix up the dbus conf file to use plugdev group
+	epatch "${FILESDIR}/${PN}-0.7.1-confchanges.patch"
+
+#	EPATCH_SOURCE="${WORKDIR}/nm_0.7.1_patchset_${PATCH_VERSION}"
+#	EPATCH_SUFFIX="patch"
+#	epatch && eautoreconf
+
+}
+
+src_configure() {
+	ECONF="--disable-more-warnings
+		--localstatedir=/var
+		--with-distro=gentoo
+		--with-dbus-sys-dir=/etc/dbus-1/system.d
+		$(use_enable doc gtk-doc)
+		$(use_with doc docs)
+		$(use_with resolvconf)"
+
+	# default is dhcpcd (if none or both are specified), ISC dchclient otherwise
+	if use dhclient ; then
+		if use dhcpcd ; then
+			ECONF="${ECONF} --with-dhcp-client=dhcpcd"
+		else
+			ECONF="${ECONF} --with-dhcp-client=dhclient"
+		fi
+	else
+		ECONF="${ECONF} --with-dhcp-client=dhcpcd"
+	fi
+
+	# default is NSS (if none or both are specified), GnuTLS otherwise
+	if use gnutls ; then
+		if use nss ; then
+			ECONF="${ECONF} --with-crypto=nss"
+		else
+			ECONF="${ECONF} --with-crypto=gnutls"
+		fi
+	else
+		ECONF="${ECONF} --with-crypto=nss"
+	fi
+
+	econf ${ECONF}
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "emake install failed"
+
+	# Need to keep the /var/run/NetworkManager directory
+	keepdir /var/run/NetworkManager
+
+	# Need to keep the /etc/NetworkManager/dispatched.d for dispatcher scripts
+	keepdir /etc/NetworkManager/dispatcher.d
+
+	dodoc AUTHORS ChangeLog NEWS README TODO || die "dodoc failed"
+
+	# Add keyfile plugin support
+	keepdir /etc/NetworkManager/system-connections
+	insinto /etc/NetworkManager
+	newins "${FILESDIR}/nm-system-settings.conf" nm-system-settings.conf \
+		|| die "newins failed"
+	insinto /etc/udev/rules.d
+	newins callouts/77-nm-probe-modem-capabilities.rules 77-nm-probe-modem-capabilities.rules
+	rm -rf "${D}"/lib/udev/rules.d
+}
+
+pkg_postinst() {
+	elog "You will need to restart DBUS if this is your first time"
+	elog "installing NetworkManager."
+	elog ""
+	elog "To save system-wide settings as a user, that user needs to have the"
+	elog "right policykit privileges. You can add them by running:"
+	elog 'polkit-auth --grant org.freedesktop.network-manager-settings.system.modify --user "USERNAME"'
+}
diff --git a/net-misc/networkmanager/networkmanager-0.8.0_pre20090824.ebuild b/net-misc/networkmanager/networkmanager-0.8.0_pre20090824.ebuild
new file mode 100644
index 000000000000..a35fb4b512a7
--- /dev/null
+++ b/net-misc/networkmanager/networkmanager-0.8.0_pre20090824.ebuild
@@ -0,0 +1,124 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-misc/networkmanager/networkmanager-0.8.0_pre20090824.ebuild,v 1.1 2009/08/24 13:11:44 dagger Exp $
+
+EAPI="2"
+inherit eutils
+
+# NetworkManager likes itself with capital letters
+MY_PN=${PN/networkmanager/NetworkManager}
+MY_P=${MY_PN}-${PV}
+
+DESCRIPTION="Network configuration and management in an easy way. Desktop environment independent."
+HOMEPAGE="http://www.gnome.org/projects/NetworkManager/"
+SRC_URI="http://dev.gentoo.org/~dagger/files/${MY_P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS=""
+IUSE="avahi bluetooth doc nss gnutls dhclient dhcpcd resolvconf connection-sharing"
+
+RDEPEND=">=sys-apps/dbus-1.2
+	>=dev-libs/dbus-glib-0.75
+	>=net-wireless/wireless-tools-28_pre9
+	>=sys-fs/udev-145[extras]
+	>=dev-libs/glib-2.16
+	<sys-auth/policykit-0.92
+	>=dev-libs/libnl-1.1
+	>=net-misc/modemmanager-0.2
+	>=net-wireless/wpa_supplicant-0.5.10[dbus]
+	bluetooth? ( net-wireless/bluez )
+	|| ( sys-libs/e2fsprogs-libs <sys-fs/e2fsprogs-1.41.0 )
+	avahi? ( net-dns/avahi[autoipd] )
+	gnutls? (
+		nss? ( >=dev-libs/nss-3.11 )
+		!nss? ( dev-libs/libgcrypt
+			net-libs/gnutls ) )
+	!gnutls? ( >=dev-libs/nss-3.11 )
+	dhclient? (
+		dhcpcd? ( >=net-misc/dhcpcd-4.0.0_rc3 )
+		!dhcpcd? ( >=net-misc/dhcp-3.0.0 ) )
+	!dhclient? ( >=net-misc/dhcpcd-4.0.0_rc3 )
+	resolvconf? ( net-dns/openresolv )
+	connection-sharing? (
+		net-dns/dnsmasq
+		net-firewall/iptables )"
+
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig
+	dev-util/intltool
+	net-dialup/ppp
+	doc? ( >=dev-util/gtk-doc-1.8 )"
+
+S=${WORKDIR}/${MY_P}
+
+src_prepare() {
+
+	# Fix up the dbus conf file to use plugdev group
+	epatch "${FILESDIR}/${PN}-0.7.1-confchanges.patch"
+
+}
+
+src_configure() {
+	ECONF="--disable-more-warnings
+		--localstatedir=/var
+		--with-distro=gentoo
+		--with-dbus-sys-dir=/etc/dbus-1/system.d
+		$(use_enable doc gtk-doc)
+		$(use_with doc docs)
+		$(use_with resolvconf)"
+
+	# default is dhcpcd (if none or both are specified), ISC dchclient otherwise
+	if use dhclient ; then
+		if use dhcpcd ; then
+			ECONF="${ECONF} --with-dhcp-client=dhcpcd"
+		else
+			ECONF="${ECONF} --with-dhcp-client=dhclient"
+		fi
+	else
+		ECONF="${ECONF} --with-dhcp-client=dhcpcd"
+	fi
+
+	# default is NSS (if none or both are specified), GnuTLS otherwise
+	if use gnutls ; then
+		if use nss ; then
+			ECONF="${ECONF} --with-crypto=nss"
+		else
+			ECONF="${ECONF} --with-crypto=gnutls"
+		fi
+	else
+		ECONF="${ECONF} --with-crypto=nss"
+	fi
+
+	econf ${ECONF}
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "emake install failed"
+
+	# Need to keep the /var/run/NetworkManager directory
+	keepdir /var/run/NetworkManager
+
+	# Need to keep the /etc/NetworkManager/dispatched.d for dispatcher scripts
+	keepdir /etc/NetworkManager/dispatcher.d
+
+	dodoc AUTHORS ChangeLog NEWS README TODO || die "dodoc failed"
+
+	# Add keyfile plugin support
+	keepdir /etc/NetworkManager/system-connections
+	insinto /etc/NetworkManager
+	newins "${FILESDIR}/nm-system-settings.conf" nm-system-settings.conf \
+		|| die "newins failed"
+	insinto /etc/udev/rules.d
+	newins callouts/77-nm-probe-modem-capabilities.rules 77-nm-probe-modem-capabilities.rules
+	rm -rf "${D}"/lib/udev/rules.d
+}
+
+pkg_postinst() {
+	elog "You will need to restart DBUS if this is your first time"
+	elog "installing NetworkManager."
+	elog ""
+	elog "To save system-wide settings as a user, that user needs to have the"
+	elog "right policykit privileges. You can add them by running:"
+	elog 'polkit-auth --grant org.freedesktop.network-manager-settings.system.modify --user "USERNAME"'
+}