Version bump; qpdf subslot dependency

(Portage version: 2.2.0_alpha186/cvs/Linux x86_64, signed Manifest commit with key EBE6A336BE19039C!)

3 files changed, 117 insertions, 3 deletions

diff --git a/net-print/cups-filters/ChangeLog b/net-print/cups-filters/ChangeLog
index 6572d58e3678..07233edb76f4 100644
--- a/net-print/cups-filters/ChangeLog
+++ b/net-print/cups-filters/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for net-print/cups-filters
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-print/cups-filters/ChangeLog,v 1.64 2013/07/05 15:19:35 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-print/cups-filters/ChangeLog,v 1.65 2013/07/05 23:10:36 dilfridge Exp $
+
+*cups-filters-1.0.35 (05 Jul 2013)
+
+  05 Jul 2013; Andreas K. Huettel <dilfridge@gentoo.org>
+  +cups-filters-1.0.35.ebuild, cups-filters-9999.ebuild:
+  Version bump; qpdf subslot dependency
 
   05 Jul 2013; Jeroen Roovers <jer@gentoo.org> cups-filters-1.0.34-r1.ebuild:
   Stable for HPPA (bug #442926).
diff --git a/net-print/cups-filters/cups-filters-1.0.35.ebuild b/net-print/cups-filters/cups-filters-1.0.35.ebuild
new file mode 100644
index 000000000000..0ad574ac8d05
--- /dev/null
+++ b/net-print/cups-filters/cups-filters-1.0.35.ebuild
@@ -0,0 +1,108 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-print/cups-filters/cups-filters-1.0.35.ebuild,v 1.1 2013/07/05 23:10:36 dilfridge Exp $
+
+EAPI=5
+
+GENTOO_DEPEND_ON_PERL=no
+
+inherit base eutils perl-module autotools systemd
+
+if [[ "${PV}" == "9999" ]] ; then
+	inherit bzr
+	EBZR_REPO_URI="http://bzr.linuxfoundation.org/openprinting/cups-filters"
+	KEYWORDS=""
+else
+	SRC_URI="http://www.openprinting.org/download/${PN}/${P}.tar.xz"
+	KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd"
+fi
+DESCRIPTION="Cups PDF filters"
+HOMEPAGE="http://www.linuxfoundation.org/collaborate/workgroups/openprinting/pdfasstandardprintjobformat"
+
+LICENSE="MIT GPL-2"
+SLOT="0"
+IUSE="jpeg perl png static-libs tiff zeroconf"
+
+RDEPEND="
+	app-text/ghostscript-gpl
+	app-text/poppler:=[cxx,jpeg?,lcms,tiff?,xpdf-headers(+)]
+	>=app-text/qpdf-3.0.2:=
+	media-libs/fontconfig
+	media-libs/freetype:2
+	media-libs/lcms:2
+	>net-print/cups-1.5.9999
+	!<=net-print/cups-1.5.9999
+	sys-devel/bc
+	sys-libs/zlib
+	jpeg? ( virtual/jpeg )
+	perl? ( dev-lang/perl )
+	png? ( media-libs/libpng:0= )
+	tiff? ( media-libs/tiff )
+	zeroconf? ( net-dns/avahi )
+"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+	base_src_prepare
+	sed -e "s/AM_CONFIG_HEADER/AC_CONFIG_HEADERS/" -i configure.ac || die
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--docdir="${EPREFIX}/usr/share/doc/${PF}" \
+		$(use_enable zeroconf avahi) \
+		$(use_enable static-libs static) \
+		--with-fontdir="fonts/conf.avail" \
+		--with-pdftops=pdftops \
+		--enable-imagefilters \
+		$(use_with jpeg) \
+		$(use_with png) \
+		$(use_with tiff) \
+		--with-rcdir=no \
+ 		--with-browseremoteprotocols=DNSSD,CUPS \
+		--without-php
+}
+
+src_compile() {
+	default
+
+	if use perl; then
+		pushd "${S}/scripting/perl" > /dev/null
+		perl-module_src_prep
+		perl-module_src_compile
+		popd > /dev/null
+	fi
+}
+
+src_install() {
+	default
+
+	if use perl; then
+		pushd "${S}/scripting/perl" > /dev/null
+		perl-module_src_install
+		fixlocalpod
+		popd > /dev/null
+	fi
+
+	prune_libtool_files --all
+
+	cp "${FILESDIR}"/cups-browsed.init.d "${T}"/cups-browsed || die
+	cp "${FILESDIR}/cups-browsed.service" "${T}"/ || die
+
+	if ! use zeroconf ; then
+		sed -i -e 's:need cupsd avahi-daemon:need cupsd:g' "${T}"/cups-browsed || die
+		sed -i -e 's:cups\.service avahi-daemon\.service:cups.service:g' "${T}"/cups-browsed.service || die
+	fi
+
+	doinitd "${T}"/cups-browsed
+	systemd_dounit "${T}/cups-browsed.service"
+}
+
+pkg_postinst() {
+	perl-module_pkg_postinst
+
+	elog "This version of cups-filters includes cups-browsed, a daemon that autodiscovers"
+	elog "remote queues via avahi or cups-1.5 browsing protocol and adds them to your cups"
+	elog "configuration. You may want to add it to your default runlevel."
+}
diff --git a/net-print/cups-filters/cups-filters-9999.ebuild b/net-print/cups-filters/cups-filters-9999.ebuild
index 86843354c4a4..172bfc1b0511 100644
--- a/net-print/cups-filters/cups-filters-9999.ebuild
+++ b/net-print/cups-filters/cups-filters-9999.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-print/cups-filters/cups-filters-9999.ebuild,v 1.35 2013/05/15 20:00:28 dilfridge Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-print/cups-filters/cups-filters-9999.ebuild,v 1.36 2013/07/05 23:10:36 dilfridge Exp $
 
 EAPI=5
 
@@ -26,7 +26,7 @@ IUSE="jpeg perl png static-libs tiff zeroconf"
 RDEPEND="
 	app-text/ghostscript-gpl
 	app-text/poppler:=[cxx,jpeg?,lcms,tiff?,xpdf-headers(+)]
-	>=app-text/qpdf-3.0.2
+	>=app-text/qpdf-3.0.2:=
 	media-libs/fontconfig
 	media-libs/freetype:2
 	media-libs/lcms:2