Version bump (bug #529390).

(Portage version: 2.2.14/cvs/Linux x86_64, signed Manifest commit with key 4AB3E85B4F064CA3)

2 files changed, 62 insertions, 1 deletions

diff --git a/net-proxy/mitmproxy/ChangeLog b/net-proxy/mitmproxy/ChangeLog
index d6d423fef54e..023d43d157f4 100644
--- a/net-proxy/mitmproxy/ChangeLog
+++ b/net-proxy/mitmproxy/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for net-proxy/mitmproxy
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-proxy/mitmproxy/ChangeLog,v 1.13 2014/10/08 01:09:11 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-proxy/mitmproxy/ChangeLog,v 1.14 2014/11/22 02:58:29 radhermit Exp $
+
+*mitmproxy-0.11.1 (22 Nov 2014)
+
+  22 Nov 2014; Tim Harder <radhermit@gentoo.org> +mitmproxy-0.11.1.ebuild:
+  Version bump (bug #529390).
 
   08 Oct 2014; Tim Harder <radhermit@gentoo.org> -mitmproxy-0.9.1.ebuild,
   -mitmproxy-0.9.2.ebuild, -mitmproxy-0.10.ebuild,
diff --git a/net-proxy/mitmproxy/mitmproxy-0.11.1.ebuild b/net-proxy/mitmproxy/mitmproxy-0.11.1.ebuild
new file mode 100644
index 000000000000..eb46e8295e38
--- /dev/null
+++ b/net-proxy/mitmproxy/mitmproxy-0.11.1.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-proxy/mitmproxy/mitmproxy-0.11.1.ebuild,v 1.1 2014/11/22 02:58:29 radhermit Exp $
+
+EAPI=5
+PYTHON_COMPAT=( python2_7 )
+
+inherit distutils-r1 versionator
+
+DESCRIPTION="An interactive, SSL-capable, man-in-the-middle HTTP proxy"
+HOMEPAGE="http://mitmproxy.org/"
+SRC_URI="http://mitmproxy.org/download/${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc examples test"
+
+RDEPEND=">=dev-python/pillow-2.3.0[${PYTHON_USEDEP}]
+	>=dev-python/flask-0.10.1[${PYTHON_USEDEP}]
+	>=dev-python/lxml-3.3.6[${PYTHON_USEDEP}]
+	=dev-python/netlib-$(get_version_component_range 1-2)*[${PYTHON_USEDEP}]
+	>dev-python/pyasn1-0.1.2[${PYTHON_USEDEP}]
+	>=dev-python/pyopenssl-0.14[${PYTHON_USEDEP}]
+	>=www-servers/tornado-4.0.2[${PYTHON_USEDEP}]
+	>=dev-python/urwid-1.1[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	test? (
+		>=dev-python/mock-1.0.1[${PYTHON_USEDEP}]
+		>=dev-python/nose-1.3.0[${PYTHON_USEDEP}]
+		=www-servers/pathod-$(get_version_component_range 1-2)*[${PYTHON_USEDEP}]
+	)"
+
+#PATCHES=( "${FILESDIR}"/${PN}-0.10-jsbeautifier-imports.patch )
+
+python_prepare_all() {
+	distutils-r1_python_prepare_all
+
+	# remove bundled netlib and pathod
+	rm -r libpathod netlib || die
+
+	# remove unused dep
+	sed -i '/sortedcontainers/d' setup.py || die
+}
+
+python_test() {
+	nosetests -v || die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	local DOCS=( CHANGELOG CONTRIBUTORS )
+	use doc && local HTML_DOCS=( doc/. )
+	use examples && local EXAMPLES=( examples/. )
+
+	distutils-r1_python_install_all
+}