Version bump (bug #502580).

(Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key 4AB3E85B4F064CA3)

2 files changed, 58 insertions, 1 deletions

diff --git a/net-proxy/mitmproxy/ChangeLog b/net-proxy/mitmproxy/ChangeLog
index 655247881407..4928519e3635 100644
--- a/net-proxy/mitmproxy/ChangeLog
+++ b/net-proxy/mitmproxy/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for net-proxy/mitmproxy
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-proxy/mitmproxy/ChangeLog,v 1.10 2014/01/30 06:37:22 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-proxy/mitmproxy/ChangeLog,v 1.11 2014/03/06 02:41:25 radhermit Exp $
+
+*mitmproxy-0.10.1 (06 Mar 2014)
+
+  06 Mar 2014; Tim Harder <radhermit@gentoo.org> +mitmproxy-0.10.1.ebuild:
+  Version bump (bug #502580).
 
 *mitmproxy-0.10 (30 Jan 2014)
 
diff --git a/net-proxy/mitmproxy/mitmproxy-0.10.1.ebuild b/net-proxy/mitmproxy/mitmproxy-0.10.1.ebuild
new file mode 100644
index 000000000000..a2538b9eed1c
--- /dev/null
+++ b/net-proxy/mitmproxy/mitmproxy-0.10.1.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-proxy/mitmproxy/mitmproxy-0.10.1.ebuild,v 1.1 2014/03/06 02:41:25 radhermit Exp $
+
+EAPI=5
+PYTHON_COMPAT=( python{2_6,2_7} )
+
+inherit distutils-r1 versionator
+
+DESCRIPTION="An interactive, SSL-capable, man-in-the-middle HTTP proxy"
+HOMEPAGE="http://mitmproxy.org/"
+SRC_URI="http://mitmproxy.org/download/${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc examples test"
+
+RDEPEND=">=dev-python/pillow-2.3.0[${PYTHON_USEDEP}]
+	dev-python/flask[${PYTHON_USEDEP}]
+	>=dev-python/lxml-2.3[${PYTHON_USEDEP}]
+	=dev-python/netlib-$(get_version_component_range 1-2)*[${PYTHON_USEDEP}]
+	>dev-python/pyasn1-0.1.2[${PYTHON_USEDEP}]
+	>=dev-python/pyopenssl-0.13[${PYTHON_USEDEP}]
+	>=dev-python/urwid-1.1[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	test? (
+		>=dev-python/mock-1.0.1[${PYTHON_USEDEP}]
+		>=dev-python/nose-1.3.0[${PYTHON_USEDEP}]
+		=www-servers/pathod-$(get_version_component_range 1-2)*[${PYTHON_USEDEP}]
+	)"
+
+PATCHES=( "${FILESDIR}"/${PN}-0.10-jsbeautifier-imports.patch )
+
+python_prepare_all() {
+	distutils-r1_python_prepare_all
+
+	# remove unwanted bytecode files
+	rm -r libmproxy/protocol || die
+}
+
+python_test() {
+	nosetests -v || die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	local DOCS=( CHANGELOG CONTRIBUTORS )
+	use doc && local HTML_DOCS=( doc/. )
+	use examples && local EXAMPLES=( examples/. )
+
+	distutils-r1_python_install_all
+}