Version bump. #459606. Thanks to Marcel Pennewiß <gentoo@pennewiss.de>

(Portage version: 2.1.11.53/cvs/Linux x86_64, signed Manifest commit with key C2BA7F3C!)

3 files changed, 83 insertions, 4 deletions

diff --git a/net-voip/homer/ChangeLog b/net-voip/homer/ChangeLog
index 0e38e443fb68..1e1dce443577 100644
--- a/net-voip/homer/ChangeLog
+++ b/net-voip/homer/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for net-voip/homer
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-voip/homer/ChangeLog,v 1.6 2013/03/02 23:11:25 hwoarang Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-voip/homer/ChangeLog,v 1.7 2013/03/03 21:44:16 hwoarang Exp $
+
+*homer-0.25 (03 Mar 2013)
+
+  03 Mar 2013; Markos Chandras <hwoarang@gentoo.org> +homer-0.25.ebuild,
+  homer-9999.ebuild:
+  Version bump. #459606. Thanks to Marcel Pennewiß <gentoo@pennewiss.de>
 
   02 Mar 2013; Markos Chandras <hwoarang@gentoo.org> homer-0.24.1.ebuild,
   homer-9999.ebuild:
diff --git a/net-voip/homer/homer-0.25.ebuild b/net-voip/homer/homer-0.25.ebuild
new file mode 100644
index 000000000000..4e3ff21bb62c
--- /dev/null
+++ b/net-voip/homer/homer-0.25.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-voip/homer/homer-0.25.ebuild,v 1.1 2013/03/03 21:44:15 hwoarang Exp $
+
+EAPI=4
+
+inherit eutils multilib
+
+DESCRIPTION="Homer Conferencing (short: Homer) is a free SIP softphone with advanced audio and video support."
+HOMEPAGE="http://www.homer-conferencing.com"
+
+MY_PN="Homer-Conferencing"
+MY_BIN="Homer"
+
+if [[ ${PV} == *9999* ]]; then
+	inherit git-2
+	EGIT_REPO_URI="git://github.com/${MY_PN}/${MY_PN}.git"
+	KEYWORDS=""
+else
+	SRC_URI="https://github.com/${MY_PN}/${MY_PN}/archive/V${PV}.tar.gz -> ${PN}-${PV}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="pulseaudio"
+
+DEPEND=">=dev-libs/openssl-1.0
+	media-libs/alsa-lib
+	media-libs/libsdl[X,audio,video,alsa]
+	media-libs/portaudio[alsa]
+	media-libs/sdl-mixer
+	media-libs/sdl-sound
+	media-libs/x264
+	media-video/ffmpeg[X]
+	net-libs/sofia-sip
+	dev-qt/qtcore:4
+	dev-qt/qtdbus:4
+	dev-qt/qtgui:4
+	dev-qt/qtmultimedia:4
+	dev-qt/qtwebkit:4
+	pulseaudio? ( media-sound/pulseaudio )"
+
+RDEPEND="${DEPEND}"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+src_prepare() {
+	if use pulseaudio; then
+		sed -i \
+			-e "/^set(FEATURE_PULSEAUDIO/s:OFF:ON:" \
+			HomerBuild/config/HomerFeatures.txt || die "sed failed"
+	fi
+}
+
+src_compile() {
+	emake -C HomerBuild default \
+		INSTALL_PREFIX=/usr/bin \
+		INSTALL_LIBDIR=/usr/$(get_libdir) \
+		INSTALL_DATADIR=/usr/share/${PN} \
+		VERBOSE=1
+}
+
+src_install() {
+	emake -C HomerBuild install \
+		DESTDIR="${D}" \
+		VERBOSE=1
+
+	# Create .desktop entry
+	doicon ${MY_BIN}/${MY_BIN}.png
+	make_desktop_entry "${MY_BIN}" "${MY_PN}" "${MY_BIN}" "Network;InstantMessaging;Telephony;VideoConference"
+}
diff --git a/net-voip/homer/homer-9999.ebuild b/net-voip/homer/homer-9999.ebuild
index 54aa87226d7a..6d8d5ce6ab5a 100644
--- a/net-voip/homer/homer-9999.ebuild
+++ b/net-voip/homer/homer-9999.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-voip/homer/homer-9999.ebuild,v 1.3 2013/03/02 23:11:25 hwoarang Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-voip/homer/homer-9999.ebuild,v 1.4 2013/03/03 21:44:16 hwoarang Exp $
 
 EAPI=4
 
@@ -32,9 +32,10 @@ DEPEND=">=dev-libs/openssl-1.0
 	media-libs/sdl-mixer
 	media-libs/sdl-sound
 	media-libs/x264
+	media-video/ffmpeg[X]
 	net-libs/sofia-sip
-	virtual/ffmpeg[X]
 	dev-qt/qtcore:4
+	dev-qt/qtdbus:4
 	dev-qt/qtgui:4
 	dev-qt/qtmultimedia:4
 	dev-qt/qtwebkit:4
@@ -48,7 +49,7 @@ src_prepare() {
 	if use pulseaudio; then
 		sed -i \
 			-e "/^set(FEATURE_PULSEAUDIO/s:OFF:ON:" \
-				HomerBuild/config/HomerFeatures.txt
+			HomerBuild/config/HomerFeatures.txt || die "sed failed"
 	fi
 }