Version bump. TIFF formats now handled with an internal library

(Portage version: 2.2_rc33/cvs/Linux x86_64)

2 files changed, 79 insertions, 1 deletions

diff --git a/sci-visualization/gwyddion/ChangeLog b/sci-visualization/gwyddion/ChangeLog
index 8f555c913367..dbdaa93ae436 100644
--- a/sci-visualization/gwyddion/ChangeLog
+++ b/sci-visualization/gwyddion/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for sci-visualization/gwyddion
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-visualization/gwyddion/ChangeLog,v 1.17 2009/04/13 16:01:30 bicatali Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-visualization/gwyddion/ChangeLog,v 1.18 2009/07/16 07:44:45 bicatali Exp $
+
+*gwyddion-2.16 (16 Jul 2009)
+
+  16 Jul 2009; Sébastien Fabbro <bicatali@gentoo.org>
+  +gwyddion-2.16.ebuild:
+  Version bump. TIFF formats now handled with an internal library
 
 *gwyddion-2.14 (13 Apr 2009)
 
diff --git a/sci-visualization/gwyddion/gwyddion-2.16.ebuild b/sci-visualization/gwyddion/gwyddion-2.16.ebuild
new file mode 100644
index 000000000000..a9e90cbac4ca
--- /dev/null
+++ b/sci-visualization/gwyddion/gwyddion-2.16.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sci-visualization/gwyddion/gwyddion-2.16.ebuild,v 1.1 2009/07/16 07:44:45 bicatali Exp $
+
+EAPI=2
+inherit fdo-mime gnome2-utils
+
+DESCRIPTION="A software framework for SPM data analysis"
+HOMEPAGE="http://gwyddion.net/"
+SRC_URI="http://gwyddion.net/download/${PV}/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc fftw gnome kde nls opengl perl python ruby sourceview xml X"
+
+RDEPEND=">=x11-libs/gtk+-2.8
+	x11-libs/cairo
+	x11-libs/pango
+	x11-libs/libXmu
+	fftw? ( >=sci-libs/fftw-3 )
+	gnome? ( gnome-base/gconf )
+	kde? ( >=kde-base/kdelibs-4 )
+	opengl? ( virtual/opengl x11-libs/gtkglext )
+	perl? ( dev-lang/perl )
+	python? ( dev-python/pygtk )
+	ruby? ( dev-ruby/narray )
+	sourceview? ( >=x11-libs/gtksourceview-2 )
+	xml? ( dev-libs/libxml2 )"
+
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig
+	doc? ( dev-util/gtk-doc )"
+
+src_configure() {
+	econf \
+		--disable-desktop-file-update \
+		--disable-rpath \
+		--enable-library-bloat \
+		--enable-plugin-proxy \
+		$(use_enable doc gtk-doc) \
+		$(use_enable nls) \
+		$(use_enable python pygwy) \
+		$(use_with perl) \
+		$(use_with python) \
+		$(use_with ruby) \
+		$(use_with fftw fftw3) \
+		$(use_with opengl gl) \
+		$(use_with sourceview gtksourceview) \
+		$(use_with xml spml) \
+		$(use_with X x) \
+		$(use_with kde kde4-thumbnailer)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "emake install failed"
+	dodoc AUTHORS ChangeLog NEWS README THANKS TODO
+	use python && dodoc modules/pygwy/README.pygwy
+}
+
+pkg_postinst() {
+	use gnome && gnome2_gconf_install
+	fdo-mime_desktop_database_update
+}
+
+pkg_prerm() {
+	use gnome && gnome2_gconf_uninstall
+}
+
+pkg_postrm() {
+	fdo-mime_desktop_database_update
+}