Version bump.

(Portage version: 2.2.0_alpha20/cvs/Linux x86_64)

2 files changed, 119 insertions, 2 deletions

diff --git a/sys-apps/util-linux/ChangeLog b/sys-apps/util-linux/ChangeLog
index f17b31804d28..37e46f242f5f 100644
--- a/sys-apps/util-linux/ChangeLog
+++ b/sys-apps/util-linux/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for sys-apps/util-linux
-# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/util-linux/ChangeLog,v 1.323 2010/11/22 01:04:58 vapier Exp $
+# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/util-linux/ChangeLog,v 1.324 2011/02/10 16:24:27 vapier Exp $
+
+*util-linux-2.19 (10 Feb 2011)
+
+  10 Feb 2011; Mike Frysinger <vapier@gentoo.org> +util-linux-2.19.ebuild:
+  Version bump.
 
   22 Nov 2010; Mike Frysinger <vapier@gentoo.org> util-linux-2.18-r1.ebuild,
   util-linux-9999.ebuild, metadata.xml:
diff --git a/sys-apps/util-linux/util-linux-2.19.ebuild b/sys-apps/util-linux/util-linux-2.19.ebuild
new file mode 100644
index 000000000000..1b9f8f3ad07e
--- /dev/null
+++ b/sys-apps/util-linux/util-linux-2.19.ebuild
@@ -0,0 +1,112 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/util-linux/util-linux-2.19.ebuild,v 1.1 2011/02/10 16:24:27 vapier Exp $
+
+EAPI="2"
+
+EGIT_REPO_URI="git://git.kernel.org/pub/scm/utils/util-linux/util-linux.git"
+inherit eutils toolchain-funcs libtool flag-o-matic
+[[ ${PV} == "9999" ]] && inherit git autotools
+
+MY_PV=${PV/_/-}
+MY_P=${PN}-${MY_PV}
+S=${WORKDIR}/${MY_P}
+
+DESCRIPTION="Various useful Linux utilities"
+HOMEPAGE="http://www.kernel.org/pub/linux/utils/util-linux/"
+if [[ ${PV} == "9999" ]] ; then
+	SRC_URI=""
+	#KEYWORDS=""
+else
+	SRC_URI="mirror://kernel/linux/utils/util-linux/v${PV:0:4}/${MY_P}.tar.bz2
+		loop-aes? ( http://loop-aes.sourceforge.net/updates/util-linux-ng-2.18-20100706.diff.bz2 )"
+	KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="+cramfs crypt loop-aes nls old-linux perl selinux slang uclibc unicode"
+
+RDEPEND="!sys-process/schedutils
+	!sys-apps/setarch
+	>=sys-libs/ncurses-5.2-r2
+	!<sys-libs/e2fsprogs-libs-1.41.8
+	!<sys-fs/e2fsprogs-1.41.8
+	cramfs? ( sys-libs/zlib )
+	perl? ( dev-lang/perl )
+	selinux? ( sys-libs/libselinux )
+	slang? ( sys-libs/slang )"
+DEPEND="${RDEPEND}
+	nls? ( sys-devel/gettext )
+	virtual/os-headers"
+
+src_prepare() {
+	if [[ ${PV} == "9999" ]] ; then
+		autopoint --force
+		eautoreconf
+	else
+		use loop-aes && epatch "${WORKDIR}"/util-linux-ng-*.diff
+	fi
+	use uclibc && sed -i -e s/versionsort/alphasort/g -e s/strverscmp.h/dirent.h/g mount/lomount.c
+	elibtoolize
+}
+
+lfs_fallocate_test() {
+	# Make sure we can use fallocate with LFS #300307
+	cat <<-EOF > "${T}"/fallocate.c
+	#define _GNU_SOURCE
+	#include <fcntl.h>
+	main() { return fallocate(0, 0, 0, 0); }
+	EOF
+	append-lfs-flags
+	$(tc-getCC) ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} "${T}"/fallocate.c -o /dev/null >/dev/null 2>&1 \
+		|| export ac_cv_func_fallocate=no
+	rm -f "${T}"/fallocate.c
+}
+
+src_configure() {
+	lfs_fallocate_test
+	econf \
+		--enable-fs-paths-extra=/usr/sbin \
+		$(use_enable nls) \
+		--enable-agetty \
+		$(use_enable cramfs) \
+		$(use_enable old-linux elvtune) \
+		--disable-init \
+		--disable-kill \
+		--disable-last \
+		--disable-mesg \
+		--enable-partx \
+		--enable-raw \
+		--enable-rename \
+		--disable-reset \
+		--disable-login-utils \
+		--enable-schedutils \
+		--disable-wall \
+		--enable-write \
+		--without-pam \
+		$(use unicode || echo --with-ncurses) \
+		$(use_with selinux) \
+		$(use_with slang) \
+		$(tc-has-tls || echo --disable-tls)
+}
+
+src_install() {
+	emake install DESTDIR="${D}" || die "install failed"
+	dodoc AUTHORS NEWS README* TODO docs/*
+
+	if ! use perl ; then #284093
+		rm "${D}"/usr/bin/chkdupexe || die
+		rm "${D}"/usr/share/man/man1/chkdupexe.1 || die
+	fi
+
+	# need the libs in /
+	gen_usr_ldscript -a blkid uuid
+	# e2fsprogs-libs didnt install .la files, and .pc work fine
+	rm -f "${D}"/usr/$(get_libdir)/*.la
+
+	if use crypt ; then
+		newinitd "${FILESDIR}"/crypto-loop.initd crypto-loop || die
+		newconfd "${FILESDIR}"/crypto-loop.confd crypto-loop || die
+	fi
+}