[sys-cluster/maui] Add slurm || pbs support to maui

(Portage version: 2.2.0_alpha43/cvs/Linux x86_64)

1 files changed, 53 insertions, 0 deletions

diff --git a/sys-cluster/maui/maui-3.3.1-r2.ebuild b/sys-cluster/maui/maui-3.3.1-r2.ebuild
new file mode 100644
index 000000000000..1ef2aeb762fc
--- /dev/null
+++ b/sys-cluster/maui/maui-3.3.1-r2.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-cluster/maui/maui-3.3.1-r2.ebuild,v 1.1 2011/07/03 23:19:35 alexxy Exp $
+
+EAPI="4"
+
+inherit autotools eutils multilib
+
+DESCRIPTION="Maui Cluster Scheduler"
+HOMEPAGE="http://www.clusterresources.com/products/maui/"
+SRC_URI="http://www.adaptivecomputing.com/download/${PN}/${P}.tar.gz"
+
+LICENSE="maui"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux"
+IUSE="pbs slurm"
+
+REQUIRED_USE="^^ ( pbs slurm )"
+
+DEPEND="
+	pbs? ( sys-cluster/torque )
+	slurm? ( sys-cluster/slurm )"
+RDEPEND="${DEPEND}"
+
+RESTRICT="fetch mirror"
+
+src_prepare() {
+	epatch "${FILESDIR}"/3.2.6_p21-autoconf-2.60-compat.patch
+	sed -e "s:\$(INST_DIR)/lib:\$(INST_DIR)/$(get_libdir):" \
+		-i src/{moab,server,mcom}/Makefile || die
+	eautoreconf
+}
+
+src_configure() {
+	local myconf
+	use pbs && myconf="--with-pbs="${EPREFIX}"/usr"
+	use slurm && myconf="--with-wiki"
+	econf \
+		--with-spooldir="${EPREFIX}"/var/spool/${PN} \
+		${myconf}
+}
+
+src_install() {
+	emake BUILDROOT="${D}" INST_DIR="${ED}/usr" install || die
+	dodoc docs/README CHANGELOG || die
+	dohtml docs/mauidocs.html || die
+	newinitd "${FILESDIR}/${PN}.initd" ${PN} || die
+}
+
+pkg_nofetch() {
+	einfo "Please visit ${HOMEPAGE}, obtain the file"
+	einfo "${P}.tar.gz and put it in ${DISTDIR}"
+}