2.7 official release version bump

(Portage version: 2.2_rc67/cvs/Linux x86_64)

2 files changed, 78 insertions, 1 deletions

diff --git a/sys-devel/llvm-gcc/ChangeLog b/sys-devel/llvm-gcc/ChangeLog
index 351d1250449a..3623904c9213 100644
--- a/sys-devel/llvm-gcc/ChangeLog
+++ b/sys-devel/llvm-gcc/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for sys-devel/llvm-gcc
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-devel/llvm-gcc/ChangeLog,v 1.4 2010/01/05 10:19:26 voyageur Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-devel/llvm-gcc/ChangeLog,v 1.5 2010/04/27 12:44:37 voyageur Exp $
+
+*llvm-gcc-2.7 (27 Apr 2010)
+
+  27 Apr 2010; Bernard Cafarelli <voyageur@gentoo.org> +llvm-gcc-2.7.ebuild:
+  2.7 official release version bump
 
   05 Jan 2010; Bernard Cafarelli <voyageur@gentoo.org> llvm-gcc-2.6.ebuild:
   Add test depend on autogen, thanks to David Leverton
diff --git a/sys-devel/llvm-gcc/llvm-gcc-2.7.ebuild b/sys-devel/llvm-gcc/llvm-gcc-2.7.ebuild
new file mode 100644
index 000000000000..1e08a83339fe
--- /dev/null
+++ b/sys-devel/llvm-gcc/llvm-gcc-2.7.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-devel/llvm-gcc/llvm-gcc-2.7.ebuild,v 1.1 2010/04/27 12:44:37 voyageur Exp $
+
+EAPI=2
+inherit multilib
+
+LLVM_GCC_VERSION=4.2
+MY_PV=${LLVM_GCC_VERSION}-${PV/_pre*}
+
+DESCRIPTION="LLVM C front-end"
+HOMEPAGE="http://llvm.org"
+SRC_URI="http://llvm.org/releases/${PV}/${PN}-${MY_PV}.source.tgz"
+
+LICENSE="GPL-2"
+SLOT=0
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="bootstrap fortran multilib nls objc objc++ test"
+
+RDEPEND=">=sys-devel/llvm-$PV"
+DEPEND="${RDEPEND}
+	>=sys-apps/texinfo-4.2-r4
+	>=sys-devel/binutils-2.18
+	>=sys-devel/bison-1.875
+	test? ( dev-util/dejagnu
+		sys-devel/autogen )"
+
+S=${WORKDIR}/llvm-gcc-${MY_PV}.source/obj
+
+src_prepare() {
+	#we keep the directory structure suggested by README.LLVM,
+	mkdir -p "${S}"
+}
+
+src_configure() {
+	# Target options are handled by econf
+
+	EXTRALANGS=""
+	use fortran && EXTRALANGS="${EXTRALANGS},fortran"
+	use objc && EXTRALANGS="${EXTRALANGS},objc"
+	use objc++ && EXTRALANGS="${EXTRALANGS},obj-c++"
+
+	ECONF_SOURCE="${WORKDIR}"/llvm-gcc-${MY_PV}.source econf --prefix=/usr/$(get_libdir)/${PN}-${MY_PV} \
+		$(use_enable multilib) \
+		--program-prefix=${PN}-${MY_PV}- \
+		--enable-llvm=/usr --enable-languages=c,c++${EXTRALANGS} \
+		|| die "configure failed"
+}
+
+src_compile() {
+	BUILDOPTIONS="LLVM_VERSION_INFO=${MY_PV}"
+	use bootstrap && BUILDOPTIONS="${BUILDOPTIONS} bootstrap"
+	emake ${BUILDOPTIONS} || die "emake failed"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "installation failed"
+	rm -rf "${D}"/usr/share/man/man7
+	if ! use nls; then
+		einfo "nls USE flag disabled, not installing locale files"
+		rm -rf "${D}"/usr/share/locale
+	fi
+
+	# Add some symlinks
+	dodir /usr/bin
+	cd "${D}/usr/bin"
+	for X in c++ g++ cpp gcc gcov gccbug ; do
+		ln -s /usr/$(get_libdir)/${PN}-${MY_PV}/bin/${PN}-${MY_PV}-${X}  llvm-${X}
+	done
+	use fortran && \
+		ln -s /usr/$(get_libdir)/${PN}-${MY_PV}/bin/${PN}-${MY_PV}-gfortran llvm-gfortran
+}