Version bump.

(Portage version: 2.2_rc67/cvs/Linux x86_64)

2 files changed, 72 insertions, 1 deletions

diff --git a/sys-devel/prelink/ChangeLog b/sys-devel/prelink/ChangeLog
index 7bb68d65f080..159ace62a970 100644
--- a/sys-devel/prelink/ChangeLog
+++ b/sys-devel/prelink/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for sys-devel/prelink
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-devel/prelink/ChangeLog,v 1.67 2010/02/06 20:56:06 dirtyepic Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-devel/prelink/ChangeLog,v 1.68 2010/05/29 07:12:36 dirtyepic Exp $
+
+*prelink-20100413 (29 May 2010)
+
+  29 May 2010; Ryan Hill <dirtyepic@gentoo.org> +prelink-20100413.ebuild:
+  Version bump.
 
 *prelink-20100106 (06 Feb 2010)
 
diff --git a/sys-devel/prelink/prelink-20100413.ebuild b/sys-devel/prelink/prelink-20100413.ebuild
new file mode 100644
index 000000000000..db35d8537396
--- /dev/null
+++ b/sys-devel/prelink/prelink-20100413.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-devel/prelink/prelink-20100413.ebuild,v 1.1 2010/05/29 07:12:36 dirtyepic Exp $
+
+EAPI="2"
+
+inherit eutils
+
+DESCRIPTION="Modifies ELFs to avoid runtime symbol resolutions resulting in faster load times"
+HOMEPAGE="http://people.redhat.com/jakub/prelink"
+#SRC_URI="http://people.redhat.com/jakub/prelink/${P}.tar.bz2"
+# if not on http://people.redhat.com/jakub/prelink/, releases can usually be ripped from
+# http://mirrors.kernel.org/fedora/development/source/SRPMS/prelink-<blah>.src.rpm
+SRC_URI="mirror://gentoo/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="-arm ~alpha ~amd64 ~ppc ~ppc64 ~s390 ~sparc ~x86"
+IUSE=""
+
+DEPEND=">=dev-libs/elfutils-0.100
+	!dev-libs/libelf
+	>=sys-libs/glibc-2.8"
+RDEPEND="${DEPEND}
+	>=sys-devel/binutils-2.18"
+
+S=${WORKDIR}/${PN}
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-20061201-prelink-conf.patch
+
+	sed -i -e 's:undosyslibs.sh::' testsuite/Makefile.in #254201
+	sed -i -e '/^CC=/s: : -Wl,--disable-new-dtags :' testsuite/functions.sh #100147
+	sed -i -e '/^CC=/s: : -Wl,--add-needed :' testsuite/functions.sh #303797
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "Install Failed"
+
+	insinto /etc
+	doins doc/prelink.conf || die
+
+	exeinto /etc/cron.daily
+	newexe "${FILESDIR}"/prelink.cron prelink
+	newconfd "${FILESDIR}"/prelink.confd prelink
+
+	dodir /var/{lib/misc,log}
+	touch "${D}/var/lib/misc/prelink.full"
+	touch "${D}/var/lib/misc/prelink.quick"
+	touch "${D}/var/lib/misc/prelink.force"
+	touch "${D}/var/log/prelink.log"
+
+	dodoc TODO ChangeLog
+}
+
+pkg_postinst() {
+	echo
+	elog "You may wish to read the Gentoo Linux Prelink Guide, which can be"
+	elog "found online at:"
+	elog
+	elog "    http://www.gentoo.org/doc/en/prelink-howto.xml"
+	elog
+	elog "Please edit /etc/conf.d/prelink to enable and configure prelink"
+	echo
+	touch "${ROOT}/var/lib/misc/prelink.force"
+}