version bump and add egl useflag

(Portage version: 2.2.0_alpha110/cvs/Linux x86_64)

1 files changed, 71 insertions, 0 deletions

diff --git a/x11-libs/libva/libva-1.1.0.ebuild b/x11-libs/libva/libva-1.1.0.ebuild
new file mode 100644
index 000000000000..b799ab52b0b1
--- /dev/null
+++ b/x11-libs/libva/libva-1.1.0.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/libva/libva-1.1.0.ebuild,v 1.1 2012/06/08 15:30:46 aballier Exp $
+
+EAPI="3"
+
+SCM=""
+if [ "${PV%9999}" != "${PV}" ] ; then # Live ebuild
+	SCM=git-2
+	EGIT_BRANCH=master
+	EGIT_REPO_URI="git://anongit.freedesktop.org/vaapi/libva"
+fi
+
+inherit autotools ${SCM} multilib
+
+DESCRIPTION="Video Acceleration (VA) API for Linux"
+HOMEPAGE="http://www.freedesktop.org/wiki/Software/vaapi"
+if [ "${PV%9999}" != "${PV}" ] ; then # Live ebuild
+	SRC_URI=""
+	S="${WORKDIR}/${PN}"
+else
+	SRC_URI="http://cgit.freedesktop.org/vaapi/libva/snapshot/${P}.tar.bz2"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+if [ "${PV%9999}" = "${PV}" ] ; then
+	KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+else
+	KEYWORDS=""
+fi
+IUSE="egl opengl"
+
+VIDEO_CARDS="dummy nvidia intel fglrx"
+for x in ${VIDEO_CARDS}; do
+	IUSE+=" video_cards_${x}"
+done
+
+RDEPEND=">=x11-libs/libdrm-2.4
+	video_cards_dummy? ( sys-fs/udev )
+	x11-libs/libX11
+	x11-libs/libXext
+	x11-libs/libXfixes
+	egl? ( media-libs/mesa[egl] )
+	opengl? ( virtual/opengl )"
+
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+PDEPEND="video_cards_nvidia? ( x11-libs/vdpau-video )
+	video_cards_fglrx? ( x11-libs/xvba-video )
+	video_cards_intel? ( x11-libs/libva-intel-driver )
+	"
+
+src_prepare() {
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--with-drivers-path="${EPREFIX}/usr/$(get_libdir)/va/drivers" \
+		$(use_enable video_cards_dummy dummy-driver) \
+		$(use_enable video_cards_dummy dummy-backend) \
+		$(use_enable opengl glx) \
+		$(use_enable egl)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die
+	dodoc NEWS || die
+	find "${D}" -name '*.la' -delete
+}