Version bump for Gnome 3.16.

(Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key C6085806)

2 files changed, 86 insertions, 1 deletions

diff --git a/x11-libs/vte/ChangeLog b/x11-libs/vte/ChangeLog
index e4fe25738a2d..387f2a6ca147 100644
--- a/x11-libs/vte/ChangeLog
+++ b/x11-libs/vte/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for x11-libs/vte
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-libs/vte/ChangeLog,v 1.411 2015/06/07 10:46:36 maekke Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/vte/ChangeLog,v 1.412 2015/06/09 09:42:54 eva Exp $
+
+*vte-0.40.2 (09 Jun 2015)
+
+  09 Jun 2015; Gilles Dartiguelongue <eva@gentoo.org> +vte-0.40.2.ebuild:
+  Version bump for Gnome 3.16.
 
   07 Jun 2015; Markus Meier <maekke@gentoo.org> vte-0.38.3.ebuild:
   arm stable, bug #534012
diff --git a/x11-libs/vte/vte-0.40.2.ebuild b/x11-libs/vte/vte-0.40.2.ebuild
new file mode 100644
index 000000000000..d89866ab6bee
--- /dev/null
+++ b/x11-libs/vte/vte-0.40.2.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/vte/vte-0.40.2.ebuild,v 1.1 2015/06/09 09:42:54 eva Exp $
+
+EAPI="5"
+GCONF_DEBUG="no"
+VALA_USE_DEPEND="vapigen"
+
+inherit eutils gnome2 vala
+
+DESCRIPTION="Library providing a virtual terminal emulator widget"
+HOMEPAGE="https://wiki.gnome.org/action/show/Apps/Terminal/VTE"
+
+LICENSE="LGPL-2+"
+SLOT="2.91"
+IUSE="+crypt debug glade +introspection vala"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~arm-linux ~x86-linux ~x64-solaris ~x86-solaris"
+
+PDEPEND=">=x11-libs/gnome-pty-helper-${PV}"
+RDEPEND="
+	>=dev-libs/glib-2.40:2
+	>=x11-libs/gtk+-3.8:3[introspection?]
+	>=x11-libs/pango-1.22.0
+
+	sys-libs/ncurses
+	sys-libs/zlib
+	x11-libs/libX11
+	x11-libs/libXft
+
+	glade? ( >=dev-util/glade-3.9:3.10 )
+	introspection? ( >=dev-libs/gobject-introspection-0.9.0 )
+"
+DEPEND="${RDEPEND}
+	$(vala_depend)
+	>=dev-util/gtk-doc-am-1.13
+	>=dev-util/intltool-0.35
+	sys-devel/gettext
+	virtual/pkgconfig
+
+	crypt?  ( >=net-libs/gnutls-3.2.0 )
+"
+RDEPEND="${RDEPEND}
+	!x11-libs/vte:2.90[glade]
+"
+
+src_prepare() {
+	vala_src_prepare
+	gnome2_src_prepare
+}
+
+src_configure() {
+	local myconf=""
+
+	if [[ ${CHOST} == *-interix* ]]; then
+		myconf="${myconf} --disable-Bsymbolic"
+
+		# interix stropts.h is empty...
+		export ac_cv_header_stropts_h=no
+	fi
+
+	# Python bindings are via gobject-introspection
+	# Ex: from gi.repository import Vte
+	# Do not disable gnome-pty-helper, bug #401389
+	gnome2_src_configure \
+		--disable-deprecation \
+		--disable-test-application \
+		--disable-static \
+		$(use_enable debug) \
+		$(use_enable glade glade-catalogue) \
+		$(use_enable crypt gnutls) \
+		$(use_enable introspection) \
+		$(use_enable vala) \
+		${myconf}
+}
+
+src_install() {
+	DOCS="AUTHORS ChangeLog HACKING NEWS README"
+	gnome2_src_install
+	mv "${D}"/etc/profile.d/vte{,-${SLOT}}.sh || die
+}