Backport the python-any-r1 conversion from x11 overlay.

(Portage version: 2.2.8/cvs/Linux x86_64, signed Manifest commit with key EFB4464E!)

2 files changed, 56 insertions, 2 deletions

diff --git a/x11-libs/libxcb/ChangeLog b/x11-libs/libxcb/ChangeLog
index fa7940c5eed2..9414456b47b4 100644
--- a/x11-libs/libxcb/ChangeLog
+++ b/x11-libs/libxcb/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for x11-libs/libxcb
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-libs/libxcb/ChangeLog,v 1.127 2013/11/23 11:50:01 gienah Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/libxcb/ChangeLog,v 1.128 2014/01/11 11:15:20 mgorny Exp $
+
+*libxcb-1.9.3-r1 (11 Jan 2014)
+
+  11 Jan 2014; Michał Górny <mgorny@gentoo.org> +libxcb-1.9.3-r1.ebuild:
+  Backport the python-any-r1 conversion from x11 overlay.
 
 *libxcb-1.9.1-r1 (23 Nov 2013)
 
diff --git a/x11-libs/libxcb/libxcb-1.9.3-r1.ebuild b/x11-libs/libxcb/libxcb-1.9.3-r1.ebuild
new file mode 100644
index 000000000000..34d3f7094d26
--- /dev/null
+++ b/x11-libs/libxcb/libxcb-1.9.3-r1.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/libxcb/libxcb-1.9.3-r1.ebuild,v 1.1 2014/01/11 11:15:20 mgorny Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_6,2_7,3_2,3_3} )
+PYTHON_REQ_USE=xml
+
+XORG_DOC=doc
+XORG_MULTILIB=yes
+inherit python-any-r1 xorg-2
+
+DESCRIPTION="X C-language Bindings library"
+HOMEPAGE="http://xcb.freedesktop.org/"
+EGIT_REPO_URI="git://anongit.freedesktop.org/git/xcb/libxcb"
+[[ ${PV} != 9999* ]] && \
+	SRC_URI="http://xcb.freedesktop.org/dist/${P}.tar.bz2"
+
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="selinux xkb"
+
+RDEPEND="dev-libs/libpthread-stubs[${MULTILIB_USEDEP}]
+	x11-libs/libXau[${MULTILIB_USEDEP}]
+	x11-libs/libXdmcp[${MULTILIB_USEDEP}]"
+# Note: ${PYTHON_USEDEP} needs to go verbatim
+DEPEND="${RDEPEND}
+	dev-libs/libxslt
+	$(python_gen_any_dep \
+		">=x11-proto/xcb-proto-1.9-r1[${MULTILIB_USEDEP},\${PYTHON_USEDEP}]")"
+
+python_check_deps() {
+	has_version ">=x11-proto/xcb-proto-1.9[${MULTILIB_USEDEP},${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	python-any-r1_pkg_setup
+}
+
+src_configure() {
+	XORG_CONFIGURE_OPTIONS=(
+		$(use_enable doc build-docs)
+		$(use_enable selinux)
+		$(use_enable xkb)
+		--enable-sendfds
+		--enable-xinput
+	)
+	xorg-2_src_configure
+}